Discussion :

[mike6889]

Bonjour,

Je souhaite renommer tous les fichiers *.jpg contenus dans un répertoire et tous ces sous répertoires en convertissant le chemin en un nom de fichier.
Avec un exemple ce sera plus explicite:

Le répertoire Toto contient les dossiers Tutu TITI et TATA et chacun contient des fichiers nommés 1.jpg 2.jpg 3.jpg
Et je souhaite avoir comme résultat:
Un répertoire Toto contenant les fichiers Tutu_1.jpg Tutu_2.jpg Tutu_3.jpg TITI_1.jpg TITI_2.jpg TITI_3.jpg TATA_1.jpg TATA_2.jpg TATA_3.jpg.

J'ai essayé plein de chose pour y arriver mais sans succès. Est ce bien réalisable avec un Batch?

Merci d'avance pour votre aide

[barnabe0057]

Bonsoir,

Un batch est tout à fait adapté pour cette tâche, voilà un exemple :

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
@echo off
setlocal enableextensions enabledelayedexpansion
ver | find "10.0." >nul && chcp 65001 >nul || chcp 28591 >nul
 
set "source=Toto"
 
cd /d %source% || exit /b 1
 
for /f "delims=" %%A in ('2^>nul dir /b /s *.jpg') do (
 
	set "string=%%~dpA"
	set "string=!string:\=.!"
	for /f "delims=" %%E in ("!string!") do set "parent=%%~xE"
 
	move "%%~fA" "%source%\!parent:~1!_%%~nxA"
 
)
 
pause
exit

Le script est testé et fonctionnel, tu auras juste à indiquer le chemin vers le dossier Toto dans la variable nommée "source" au début du script.

[ericlm128]

@barnabe

Je vois que tu fait souvent ceci cd /d %source% || exit /b 1, personnellement j'évite cela car tu auras tôt ou tard des problèmes avec les chemins unc

[mike6889]

Merci pour cette réponse très rapide.

Le Batch fait presque ce que j'attendais mais je me suis mal exprimé dans mon premier message et je n'arrive pas à modifier le batch tout seul pour y arriver.

Mon dossier contient plusieurs sous dossiers qui eux même contiennent des sous dossiers et je souhaite que le nom du fichier contienne le nom du dossiers et du sous dossier et du sous sous dossier et ceux de la "racine" jusqu'au fichier *.jpg

2 exemples :
TOTO/TUTU/TITI/TATA/1.jpg devient TOTO/TUTU_TITI_TATA_1.jpg
TOTO/TRILI/TUTU/1.jpg devient TOTO/TRILI_TUTU_1.jpg

Je pensais qu'avec le batch d'origine j'arriverais à mes fins mais j'ai encore besoin de vote aide.

[barnabe0057]

Est-ce que c'est mieux comme ça :

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
@echo off
setlocal enableextensions enabledelayedexpansion
ver | find "10.0." >nul && chcp 65001 >nul || chcp 28591 >nul
 
set "source=Toto"
 
if "%source:~-1%"=="\" (set "source=%source:~0,-1%")
 
for /f "delims=" %%A in ('2^>nul dir /b /s %source%\*.jpg') do (
 
	set "chemin=%%~dpA"
	set "relatif=!chemin:%source%\=!"
	set "relatif=!relatif:\=_!"
 
	move "%%~fA" "%source%\!relatif!%%~nxA"
 
)
 
pause
exit

[mike6889]

Exactement ce que je voulais faire.

Merci beaucoup