Discussion :

[snooppy]

Bonjour à tous(tes)

Voilà j'ai un soucis dans le code que j'ai pu récupérer sur ce forum le voici ci dessous :

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
@echo off
setlocal EnableDelayedExpansion
echo.
set file_tmp="provFile.ini"
 
::::::::::::: VARIABLE A MODIFIER :::::::::::::
    REM Correspond au nom de fichier avec une ligne à modifier
    set file="srv_sll.ini"
 
    REM Correspond à la ligne recherchée (ligne entière)
    set file_line_word="MDP="
 
    REM Correspond à la nouvelle ligne
    set file_line_replace=MDP=%1
 
    REM Correspond au nom de fichier avec une ligne à modifier
    set file="srv_sll.ini"
 
    REM Correspond à la ligne recherchée (ligne entière)
    set file_line_word="Server1="
 
    REM Correspond à la nouvelle ligne
    set file_line_replace=Server1=%2
 
    REM Correspond au nom de fichier avec une ligne à modifier
    set file="srv_sll.ini"
 
    REM Correspond à la ligne recherchée (ligne entière)
    set file_line_word="SRV3:"
 
    REM Correspond à la nouvelle ligne
    set file_line_replace=SRV3:%3
 
 
::::::::::::: VARIABLE A MODIFIER :::::::::::::
 
If not exist %file% goto :file_notfound
If exist %file_tmp% del /f /q %file_tmp%
For /f "delims=" %%i in ('type %file%') do (
    set line=%%i
    set line="!line:"=!"
    If not !line!==%file_line_word% (
        echo %%i>>%file_tmp%
    ) else (
        echo %file_line_replace%>>%file_tmp%
    )
)
del /f /q %file%
ren %file_tmp% %file%
endlocal
echo Modification termin‚e !
goto :quit
 
:file_notfound
endlocal
echo Fichier introuvable !
 
:quit
echo.
pause>nul | echo Appuyez sur une touche pour quitter le script...
exit

Édition fonctionne que sur la variable %3 et non pas sur les autres, j'ai peut être zapper quelques choses dessus

Mon but et de lancer le bat comme ceci : test.bat %1 %2 %3

Voilà le hic dans cette exemple c'est que le %3 fonctionne mais pas ceux d'avant.

Édition de SRV3 fonctionne mais pourquoi il ne prend pas les variables %1 et %2

Merci pour vos éclaircissements.

Bien à vous

[barnabe0057]

Bonjour,

C'est bien, tu définis 3 jeux de variables mais tu ne passes qu'une seule fois dans la boucle FOR, chaque nouvelle variable écrasant la précédente il n'y a que la dernière qui marche.

Voilà une modification pour passer 3 fois dans la boucle :

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
@echo off
setlocal EnableDelayedExpansion
echo.
set file_tmp="provFile.ini"
set file="srv_sll.ini"
 
If not exist %file% goto :file_notfound
If exist %file_tmp% del /f /q %file_tmp%
 
::::::::::::: VARIABLE A MODIFIER :::::::::::::
 
call :edition "MDP=" "MDP=%1"
call :edition "Server1=" "Server1=%2"
call :edition "SRV3:" "SRV3:%3"
 
::::::::::::: VARIABLE A MODIFIER :::::::::::::
 
endlocal
echo Modification terminée !
goto :quit
 
:file_notfound
endlocal
echo Fichier introuvable !
 
:quit
echo.
pause>nul | echo Appuyez sur une touche pour quitter le script...
exit
 
:edition
 
For /f "delims=" %%i in ('type %file%') do (
    set line=%%i
    set line="!line:"=!"
    If not !line!==%1 (echo %%i) else (echo %~2)
)>>%file_tmp%
 
del /f /q %file%
ren %file_tmp% %file%
 
goto :eof

[snooppy]

Merci beaucoup c'est la bonne solution !
et ça fonctionne parfaitement !
Vous m'avez sauver ma journée barnabe0057 !!