Discussion :

[Menalm11]

Bonjour Community,

Je cherche à écrire une code qui demande d'un premier temps à l'utilisateur de rentrer le Numéro d'offre, après il cherche ce numéro d'offre dans une feuille Excel et si le numéro est trouvé envoie une autre InputBox s'affiche pour que l'utilisateur saisie le numéro d'installation correspondant. J'ai bricolé ce code qui marche mais le seul problème que le deuxième InputBox s'affiche dans tous les cas (Num offre non trouvé, on appui sur annuler dans le premier InputBox)!
Qqn peux m'aider SVP.

Merci et bon début de la semaine

Voici mon code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub NumInstallation()
Dim NumeroInstallation As Long
Dim NumOffre As Variant
Dim R As Range, LI As Integer
deb: 'étiquette
NumOffre = InputBox("Saisie le N° d'offre: ", "Numéro d'offre")
Set R = Sheets("Clients Gagnés 2021").Columns(1).Find(NumOffre, , xlValues, xlWhole)
If NumOffre = False Then Exit Sub 'si bouton "Annuler", sort de la procédure
If Not R Is Nothing Then 'condition : si il existe au moins une occurrence trouvée
    LI = R.Row 'définit la ligne LI de la première occurrence trouvée
Numeronstallation = InputBox("Saisie le N° d'installation: ", "Numéro d' installation")
Sheets("Clients Gagnés 2021").Range("AI" & LI) = Numeronstallation
Else 'sinon
    'si "Oui" au message, relance la boîte d'entrée C via l'étiquette "deb"
    If MsgBox("Saisie erronée ! Voulez-vous recommencer ?", vbYesNo, "ATTENTION") = vbYes Then GoTo deb
End If 'fin de la condition
End Sub

[Pierre Fauconnier]

Salut.

Je ne suis vraiment pas fan des EXIT SUB et des GOTO...

Voilà comment j'écrirais le code, sur base d'un tableau structuré:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub Test()
  Dim ID
  Dim Target As Range
  Dim Numero
 
  ID = InputBox("ID svp" & vbLf & "Laissez vide pour sortir", "Saisie de l'ID")
  Do While ID <> ""
    Set Target = Range("tableau1[ID]").Find(ID)
    If Not Target Is Nothing Then
      Numero = InputBox("Numéro d'installation svp")
      If Numero <> "" Then Target(1, 2).Value = Numero
    Else
      MsgBox "L'ID n'a pas été trouvé"
    End If
    ID = InputBox("ID svp" & vbLf & "Laissez vide pour sortir", "Saisie de l'ID")
  Loop
End Sub

Perso, je ne travaillerais pas avec FIND, mais avec la fonction EQUIV (MATCH en VBA) pour exploiter au mieux les tableaux structurés:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub Test()
  Dim ID
  Dim Index
  Dim Numero
 
  ID = InputBox("ID svp" & vbLf & "Laissez vide pour sortir", "Saisie de l'ID")
  Do While ID <> ""
    Index = Application.Match(ID, Range("tableau1[ID]"), 0)
    If Not IsError(Index) Then
      Numero = InputBox("Numéro d'installation svp")
      If Numero <> "" Then Range("tableau1[Valeur]")(Index).Value = Numero
    Else
      MsgBox "L'ID n'a pas été trouvé"
    End If
    ID = InputBox("ID svp" & vbLf & "Laissez vide pour sortir", "Saisie de l'ID")
  Loop
End Sub

[Menalm11]

Merci Pierre.

Ton code marche très bien