Combobox en cascade

**yalefe** · 14/12/2020, 15h23

Envoyé par Vba14

Bonjour,

J'ai ce fichier qui m'a été utile pour mes applications.
Pièce jointe 580996
Bon courage

Merci pour ce fichier.

j'ai un premier combobox sur un usf qui est alimenté par des valeurs uniques d'une feuille.

ce que j'ai du mal à faire , c'est alimenter le deuxième combobox , mais avec des valeurs multiples qui se trouvent sur une autre feuille

par exemple
en colonne A de ma première feuille , j'ai les valeurs bleu, blanc, verte, jaune
et en colonne Y de ma deuxième feuille, j'ai les valeurs Bleu, jaune, verte, blanc, verte, bleu,
et en colonne Z, les valeurs correspondant que je voudrais retrouver dans mon comboBox2 en fonction de la couleur sélectionnée dans le combobox1
Faut il que je passe par un recherchev dans la formule ?

je bloque un peu

merci

**Pierre Fauconnier** · 14/12/2020, 16h07

Salut.

Pourrais-tu donner ta version d'Excel?

Si c'est Excel365, tu pourrais t'inspirer de mon billet qui illustre comment utiliser les nouvelles fonctions 365 pour réaliser ce que tu souhaites.

**yalefe** · 14/12/2020, 16h37

Pardon, j'ai oublié de l'indiquer c'est fait...

xl 2016

**Pierre Fauconnier** · 14/12/2020, 16h40

Pour d'autres versions que 365, voici comment je procéderais, en m'appuyant bien entendu sur des tableaux structurés. L'idée est de trier les valeurs sur base de la couleur puis d'extraire la plage correspondante à la couleur choisie:

Dans un module standard, j'initialise le userform avec la liste triée des couleurs grâce à une fonction
A la modification du combobox des couleurs dans le userform, on adapte la liste des valeurs liées à la couleur choisie grâce à une fonction du module standard qui trie les valeurs sur base des couleurs et qui extrait celles qui correspondent au choix.

Sur base d'un tableau des couleurs t_Couleurs et d'un tableau des valeurs t_Valeurs

Nom : 2020-12-14_163621.png
Affichages : 118
Taille : 5,9 Ko

Nom : 2020-12-14_163621.png
Affichages : 118
Taille : 5,9 Ko

La fonction d'un module standard qui renvoie un array VBA avec les couleurs triées

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Function getColors()
  With Range("t_Couleurs").ListObject.Sort
    .SortFields.Clear
    .SortFields.Add Key:=Range("t_Couleurs[couleur]")
    .Apply
  End With
  getColors = Range("t_Couleurs[Couleur]")
End Function

La fonction d'un module standard qui renvoie les valeurs triées pour une couleur donnée. On doit un peu finasser sur la fin car il faut traiter le cas d'une couleur sans valeur ou d'une seule valeur pour la couleur choisie, car List impose un tableau et Range.Value ne renvoie pas un tableau pour un range monocellule.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Function getValues(Color As String)
  Dim Values As Range
  Dim Pos, CountOf As Long, t()
 
  With Range("t_Valeurs").ListObject.Sort
    .SortFields.Clear
    .SortFields.Add Range("t_Valeurs[Couleur]")
    .SortFields.Add Range("t_Valeurs[Valeur]")
    .Apply
  End With
  CountOf = Application.CountIfs(Range("t_Valeurs[Couleur]"), Color)
  If CountOf > 0 Then
    Pos = Application.Match(Color, Range("t_Valeurs[Couleur]"), 0)
    Set Values = Range("t_Valeurs[Valeur]")(Pos).Resize(CountOf)
    If Values.Cells.Count = 1 Then
      ReDim t(1 To 1, 1 To 1)
      t(1, 1) = Values.Value
    Else
      t = Values.Value
    End If
    getValues = t
    Erase t
  End If
End Function

Le code d'amorçage du userform dans un module standard

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Sub Test()
  With UserForm1
    .cboColors.List = getColors()
    .Show
  End With
End Sub

Le code du userform qui gère le choix d'une couleur

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Private Sub cboColors_Change()
  SetValues
End Sub
 
Sub SetValues()
  Dim Values
 
  Values = getValues(cboColors.Value)
  If Not IsEmpty(Values) Then
    cboValues.List = Values
  Else
    cboValues.Clear
  End If
End Sub