Discussion :

[Wanny_56]

Bonjour à tous,
Je développe sur Excel un formulaire dans lequel les utilisateurs devront renseigner différents champs dans une première feuille. A partir de là, le fichier saura dire à l'utilisateur la liste des documents qu'il convient de joindre à sa demande. J'avais imaginé que l'utilisateur insérerait directement ces pièces jointes dans les différentes cellules appropriées de la 2e feuille Excel. A partir de là, j'aurais aimé que l'outil compte le nombre de pièces réclamées d'une part et le nombre de pièces jointes d'autre part et en fonction du résultat de ce calcul, une macro autoriserait (ou pas) l'utilisateur initial à transmettre par mail le fichier au contrôleur chargé d'instruire la demande.
Malgré plusieurs recherches sur différents forums dont celui-ci, malgré l'appel à différents utilisateurs expérimentés autour de moi, je n'ai trouvé aucun moyen pour que Excel compte le nombre de pièces jointes... D'où mon présent post.
Voir exemple en pièce jointe.
Merci d'avance pour votre aide.

[BENNASR]

Bonjour
Au départ je ne suis qu'un autodidacte et ma réponse peut être HORS JEU
mais pour faire bouger cette discussion ... à mon modeste avis il est préférable de penser à un serveur pour collecter les pièces jointes et insérer que des lien hypertexte
puis compter le nombre des liens sur la feuille à envoyer et si est inférieur à 5 ou 6 l'email ne sera pas envoyé
code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Sub test()
Dim h As Object
Set h = ActiveSheet.Hyperlinks
If h.Count = 0 Then MsgBox "Il manque le lien du fichier Word !"
End Sub

J'espère que ça t'aide à avancer

[ARTURO83]

Bonjour,

Autre proposition, compte le nombre d'objet dans la feuille:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub Nbre_Pieces_Jointes()
    Dim f1 As Worksheet
    Dim n As Long
    Application.ScreenUpdating = False
    Set f1 = Sheets("Pièces")
 
    'compte le nombre de pièces jointes -1 à cause du logo qui est considéré comme un objet
    n = f1.Shapes.Count - 1
    MsgBox "Nombre de pièces réclammées: " & f1.Range("I7").Value & Chr(10) & "Nombre de pièces jointes: " & n
 
    If n > 0 Then
        'écrire ici la macro qui autorise l'envoi du mail
    End If
 
    Set f1 = Nothing
End Sub

Cdlt

[Wanny_56]

Bonsoir à tous,
Merci pour votre aide. J'ai pu ainsi construire mon code ci-dessous :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
Sub Nbr_Pieces()
'
' Macro permettant de calculer le nombre de pièces jointes à la demande de financement
' Puis d'adresser la demande au contrôleur pour qu'il prenne le relais
'
 
Dim F1 As Worksheet
Dim N As Long
Application.ScreenUpdating = False
 
Set F1 = Sheets("Pièces")
N = F1.Shapes.Count - 1
 
MsgBox "Nombre de pièces demandées : " & Range("Nbr_Pièces") & Chr(10) & "Nombre de pièces jointes : " & N
 
If N < Range("Nbr_Pièces").Value Then
    If MsgBox("Le nombre de pièces jointes est inférieur au nombre attendu" & Chr(10) _
    & "Voulez-vous tout de même envoyer le document à votre correspondant ?", _
    vbYesNo + vbQuestion, "Demande de confirmation") = vbNo Then
        Exit Sub
    End If
End If
 
Destinataire = Range("Mail_CtrlDest")
Expéditeur = InputBox("Veuillez indiquer vos Prénom et NOM (pour signature du message)")
 
Set olApp = CreateObject("Outlook.application")
Set olMail = olApp.CreateItem(olMailItem)
 
With olMail
    .To = Destinataire
    .Subject = "Demande de financement Speed Prêt " & Range("NomEnseigne") & ", " & Range("Ville")
    .Body = Range("Mail_ctrl1") & Range("Mail_ctrl2") & Range("Mail_ctrl3") & Range("Mail_ctrl4") & Expéditeur
    .attachments.Add ThisWorkbook.FullName
    .send
End With
 
Set F1 = Nothing
Application.ScreenUpdating = True
 
End Sub

La Macro vérifie le nombre de pièces jointes et demande à l'utilisateur s'il souhaite tout de même envoyer le document à la personne qui sera chargée de l'utiliser par la suite pour réaliser les étapes suivantes du processus.

Encore un grand merci pour votre aide.