Discussion :

[neflerine]

Bonjour,

J'ai une routine qui se lance quand je clique sur un userform, le code se trouve dans Private Sub CommandButton1_Click()

Un evenement se lance au moment de la fermeture du userform (qui fonctionne très bien)
Dans cet évènement, j'aimerais supprimer les onglets crée par la routine interrompue prématurément (sauf l'onglet menu)

La aussi tout fonctionne très bien sauf que je veux désactiver le message de confirmation de suppression pour la suppression de chaque onglet.

Le problème est que l'instruction Application.DisplayAlerts = False ne passe pas (message d'erreur La méthode de l'objet 'DisplayAlerts' de l'objet '_Application' à échoué

Merci d'avance pour vos lumières sur le sujet

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
 
 
Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
    If CloseMode = vbFormControlMenu Then
        Cancel = True
        MsgBox "Eh, Tu as interrompu la macro en plein milieu !" & Chr(13) & Chr(10) & _
               "Allez Hop retour à la Case départ !"
 
Application.DisplayAlerts = False
 
Dim Compteur As Integer, Nom As String
For Compteur = Worksheets.Count To 1 Step -1
        Nom = Sheets(Compteur).Name
        Select Case Nom
        Case "Menu"
 
        Case Else
            Sheets(Compteur).Delete
        End Select
    Next Compteur
 
Application.DisplayAlerts = True
 
 
 
        End
    End If
End Sub

[a_diard]

peut etre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Application.DisplayAlerts = False 
"""ton code"""
Application.DisplayAlerts = True

[neflerine]

Désolé je m'étais trompé dans mon post initial (que je viens de modifier)

Il s'agit bien de l’instruction Application.DisplayAlerts = False qui ne passe pas

EDIT :
Je viens d'essayer avec d'autres propriétés, rien ne passe (Application.AlertBeforeOverwriting = False , ScreenUpdating = False ....)

Ces propriétés sont-elles bloquées à l'intérieur de l’événement ? Aucune solution pour l'instant, je n'arrive à modifier aucune propriété Application.* à l'intérieur de mon événement

[neflerine]

Je n'ai pas le droit de modifier les propriété de Application comme Application.DisplayAlerts dans mon evenement.
Par contre si je modifie Application.DisplayAlerts dans ma macro, il est bien modifié dans mon evenement.

J'ai donc contourné le problème en mettant Application.DisplayAlerts = False dans ma macro au lancement.

Par contre Sheets(Compteur).Delete ne fonctionne pas (la methode Delete de l'objet Sheets à échoué)

Un indice qui me chiffone : Au moment ou l'erreur se produit, je clique sur Deboguage et a ce moment, les onglets ne sont pas encore crée, à ce moment je clique sur Stop dans l'éditeur, et la tous les onglets se libérent.

Il n'y aurait pas une histoire de d'empilage LIFO ? JE n'ai aucune idée de comment gérer le problème

[Philippe Tulliez]

Bonjour,
Voici un code qui fonctionne correctement.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
   Dim sht As Worksheet
   Application.DisplayAlerts = False
   For Each sht In Worksheets
     If sht.Name <> "Home" Then
        sht.Delete
     End If
   Next
   Application.DisplayAlerts = True
End Sub

Une autre solution plus propre est de placer la procédure de suppression les feuilles du classeur dans un module standard et d'appeler d'ailleurs le formulaire depuis un module standard
Exemple qui vérifie que la fermeture du formulaire s'est faites à l'aide du bouton nommé cmdExit

Code de module du UserForm

En tête de module

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Option Explicit
Public FlagExit As Boolean

Le code de la procédure événementielle

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Private Sub cmdExit_Click()
  FlagExit = True
  Me.Hide
End Sub

Les deux procédures dans un module standard

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub main()
  With UserForm1
  .Show
   If .FlagExit Then DeleteSheets Except:="Home"
   Unload UserForm1
  End With
End Sub

La procédure de suppression des feuilles (uniquement les feuilles de calculs)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub DeleteSheets(Except As String)
   Dim sht As Worksheet
   Application.DisplayAlerts = False
   For Each sht In Worksheets
     With sht
     If .Name <> Except Then .Delete
     End With
   Next
   Application.DisplayAlerts = True
End Sub

[EDIT]
Est-ce que l'instruction End placée ligne 26 du code publié dans le Fil #1 de cette discussion est voulue ?
Car évidemment, elle provoque l'arrêt de la procédure

[neflerine]

Merci beaucoup pour cette explication complète et concise.

Le code à l'air de fonctionner, je regarde ca de plus près demain. Bonne soirée