Discussion :

[topanonga]

Bonjour

Pas assez bon en macro pour trouver la solution seul.
Je cherche à pré-remplir la boite de dialogue enregistrer sous de ma macro.
Je n'arrive pas à remplir le champs emplacement et format du fichier
J'ai besoin d'enregistrer le fichier avec :
nom: Sheets("F") Range("V10") (exemple: "Billetterie du 15 Novembre 2020.txt")
Lieu d'enregistrement: "/Users/utilisateur/Desktop/BILLETTERIES/"
Format du fichier : FileFormat:=xlText

Comment écrire ma macro
Chose importante, je travaille sous Mac

Application.Dialogs(xlDialogSaveAs).Show .... ?

Merci d'avance

[EricDgn]

Bonjour,

Une façon de faire, testé sur Windows:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Sub SaveSheetToTxt(sNomFeuille As String, sNomFichier As String, sDossier As String)
    Dim xRet As Long
    Dim xFileName As Variant
    xFileName = Application.GetSaveAsFilename(sDossier & "\" & sNomFichier, "Fichiers texte (*.txt), *.txt")
    If xFileName = False Then Exit Sub  '--- Annulé
    If Dir(xFileName) <> "" Then
        xRet = MsgBox("Le fichier '" & xFileName & "' existe déjà." & vbLf & "L'écraser ?", vbYesNo + vbExclamation, "A confirmer")
        If xRet <> vbYes Then
            Exit Sub
        Else
            Kill xFileName
        End If
    End If
    ActiveWorkbook.Sheets(sNomFeuille).Copy
    ActiveWorkbook.SaveAs xFileName, xlUnicodeText
    ActiveWorkbook.Close False
End Sub
 
Sub test()
    SaveSheetToTxt "F", "Billetterie du 15 Novembre 2020.txt", "C:\Users\utilisateur\Desktop\BILLETTERIES"
End Sub

Cordialement.