Discussion :

[Quiro]

Bonjour, bonsoir,

Je vous contact ici car apres plusieurs recherches je n'arrive pas a trouver exactement comment resoudre mon probleme. Un probleme qui me paraissait simple au depart mais au final qui m'a bouffe toute mon apres midi.

j'ai un imput box qui me permet je renseigner une date.
Mon imputbox arrive a gerer losqu'on rentre une valeur, lorsqu'on appuie sur annuler mais pas lorqu'on appuie ok sans entrer de valeur. J'ai l'erreur d'execution '13' : Incompabilite de type qui s'affiche.

Voici mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Dim dat As Date
 
For k = 4 To Sheets("Planning").Range("U65536").End(xlUp).Row
    If Target.Column = 21 And Target.Row = k Then
       myvalk = Cells(k, 21)
       For Each cellulek In Target.Cells
            If cellulek.Value = "Yes" Then
                dat = Application.InputBox("Please enter the expiry date of your HSE document", , "DD/MM/YYYY")
                        If IsEmpty(dat) Then
                            Cells(k, 21).Value = "No"
                        Exit Sub
                        ElseIf dat = False Then
                            Cells(k, 21).Value = "No"
                        Else
                            Cells(k, 22).Value = dat
                        End If
            End If
        Next
    End If
 Next
End Sub

Quoi que je fasse ca me met une erreur a la ligne dat = Application.InputBox("Please enter the expiry date of your HSE document", , "DD/MM/YYYY")

[Invité]

Bonjour,

Votre variable Dat ne peut pas être de type Date car la valeur de la réponse peut être vide d'où l'erreur. InputBox est de type Variant : https://docs.microsoft.com/fr-fr/off...ation.inputbox

A tester :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
 
Option Explicit
 
Sub MiseAJourColonneU()
 
Dim I As Long, Derniereligne As Long
Dim dat As Variant
Dim AirePlanning As Range
 
    With Sheets("Planning")
 
         Derniereligne = .Cells(.Rows.Count, 21).End(xlUp).Row
         Set AirePlanning = .Range(.Cells(4, 21), .Cells(Derniereligne, 21))
 
         For I = 1 To AirePlanning.Count
 
             With AirePlanning(I)
                  If .Value = "Yes" Then
 
                        dat = Application.InputBox("Please enter the expiry date of your HSE document", , Format(Date, "DD/MM/YYYY"))
 
                      If IsDate(dat) Then
                         .Offset(0, 1).Value = Format(dat, "MM/DD/YYYY") ' A adapter si le le format ne convient pas. 
                      Else
                         .Offset(0, 1).ClearContents ' En toute logique
                      End If
                      .Value = "No"
                  End If
              End With
         Next I
         Set AirePlanning = Nothing
 
    End With
 
End Sub

[pijaku]

Bonjour,

En complément de la réponse d'Eric :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub essaidate()
Dim dat As Variant
    dat = InputBox("Please enter the expiry date of your HSE document", , "DD/MM/YYYY")
    If StrPtr(dat) = 0 Then
        MsgBox "Vous avez annulé", vbCritical + vbOKOnly, "Annulation utilisateur"
    ElseIf dat = vbNullString Then
        MsgBox "Aucune saisie", vbCritical + vbOKOnly, "Pas de saisie utilisateur"
    ElseIf IsDate(dat) Then
        MsgBox dat
    Else
        MsgBox "Mauvaise saisie", vbCritical + vbOKOnly, "L'utilisateur est un GROS BOULET"
    End If
End Sub

A noter l'utilisation de InputBox en lieu et place de Application.InputBox.
Cela permet de différencier l'appui sur "ANNULER"...

[Quiro]

Messieurs,
Je vous tire mon chapeau.

Un grand merci.
Ca marche parfaitement

Chapeau bas les artistes