Navigation

Inscrivez-vous gratuitement
pour pouvoir participer, suivre les réponses en temps réel, voter pour les messages, poser vos propres questions et recevoir la newsletter

Scripts/Batch Discussion :

script pour scanner les périphériques d'un laptop


Sujet :

Scripts/Batch

  1. #1
    Membre à l'essai
    script pour scanner les périphériques d'un laptop
    Bonjour

    Je suis a la recherche d'un script qui permet de faire un scanne d'un laptop recherchant les périphériques qu'il y a dessus ( écran externe / imprimante etc ... )
    et surtout qui envoi le résultat par mail via Outllook

    Merci d'avance pour votre aide.

  2. ###raw>post.musername###
    Expert éminent
    SysInfo.bat

    Voici un début de script batch intitulé comme : SysInfo.bat
    Code BAT :Sélectionner tout -Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    29
    30
    31
    32
    33
    34
    35
    36
    37
    38
    39
    40
    41
    42
    43
    44
    45
    46
    47
    48
    49
    50
    51
    52
    53
    54
    55
    56
    57
    58
    59
    60
    61
    62
    63
    64
    65
    66
    67
    68
    69
    70
    71
    72
    73
    74
    75
    76
    77
    78
    79
    80
    81
    82
    @Echo Off
    chcp 65001>nul & color 0A & Mode 80,5
    Title Get System Information on Computer name: %computername%
    :::::::::::::::::::::::::::::::::::::::::
    :: Automatically check & get admin rights
    :::::::::::::::::::::::::::::::::::::::::
    REM  --> Check for permissions
    Reg query "HKU\S-1-5-19\Environment" >nul 2>&1
    REM --> If error flag set, we do not have admin.
    if '%errorlevel%' NEQ '0' (
    Echo.
    ECHO                    ***************************************
    ECHO                      Running Admin shell... Please wait...
    ECHO                    ***************************************
     
        goto UACPrompt
    ) else ( goto gotAdmin )
     
    :UACPrompt
        echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
        set params = %*:"=""
        echo UAC.ShellExecute "cmd.exe", "/c ""%~s0"" %params%", "", "runas", 1 >> "%temp%\getadmin.vbs"
     
        "%temp%\getadmin.vbs"
        del "%temp%\getadmin.vbs"
        exit /B
     
    :gotAdmin
    ::::::::::::::::::::::::::::
    ::START
    ::::::::::::::::::::::::::::
    SetLocal EnableDelayedExpansion
    set "Log=%~dp0Log_%~n0.txt"
    If exist "%Log%"  Del "%Log%" 
    Call :GET_CPU name CPU_Name
    Set "WMIC_Antivirus=wmic /node:localhost /namespace:\\root\SecurityCenter2 path AntiVirusProduct Get DisplayName ^| findstr /V /B /C:displayName"
    @For /F "delims=" %%I in ('%WMIC_Antivirus%') do ( 
        for /f "delims=" %%A IN ("%%I") DO SET "Antivirus=%%A"
    )
     
    (
        Echo.
        Echo ***************************** General infos ***********************************
        Echo.
        Echo Running under: %username% on profile: %userprofile%
        Echo Computer name: %computername%
        Echo.
        systeminfo
        Echo Operating System:
        Echo PROCESSOR ARCHITECTURE : %PROCESSOR_ARCHITECTURE%
        echo NUMBER_OF_PROCESSORS : %NUMBER_OF_PROCESSORS%
        echo PROCESSOR_IDENTIFIER : %PROCESSOR_IDENTIFIER%
        echo PROCESSOR_LEVEL : %PROCESSOR_LEVEL%
        echo PROCESSOR_REVISION : %PROCESSOR_REVISION%
        echo OS TYPE : %OS%
        echo(
        echo Program files path : %Programfiles%
        echo Program files(86^) path  : %Programfiles(86^)%
        echo ProgramW6432 path : %ProgramW6432%
        echo PSModulePath : %PSModulePath%
        echo SystemRoot : %SystemRoot%
        echo Temp Folder : %Temp%
        echo CPU       :   !CPU_Name!
        echo Antivirus :   !Antivirus!
        Echo.
        Echo **************************** Drives infos *************************************
        Echo.
        Echo Listing currently attached drives:
        wmic logicaldisk get caption,description,volumename | find /v ""
        Echo.
        Echo Physical drives information:
        for /F "tokens=1-3" %%A in ('fltmc volumes^|find ":"') do echo %%A %%B %%C
    )>>"%Log%"
    Start "" "%Log%" & exit
    ::----------------------------------------------------
    :GET_CPU 
    Set "WMIC_CPU=wmic cpu get name /Value"
    FOR /F "tokens=2 delims==" %%I IN (
      '%WMIC_CPU% ^| find /I "%~1" 2^>^nul'
    ) DO FOR /F "delims=" %%A IN ("%%I") DO SET "%2=%%A"
    Exit /b
    ::----------------------------------------------------
      0  0

###raw>template_hook.ano_emploi###