Discussion :

[ness-u]

Bonjour à tous,

j'essaie de convertir 3 onglets (en masquant les mêmes lignes sur chaque onglet) en pdf.
La macro convertit bien en pdf avec lignes masquées uniquement pour le 1er onglet.
Les onglets 2 et 3 ont toutes les lignes non masquées.
J'ai fait plusieurs tentatives mais sans succès.

Si quelqu'un a la solution cela serait sympa

Merci et bonne journée

[Menhir]

Comme beaucoup de participants, je n'ouvre pas les fichiers joints.
Il serait préférable que tu présentes ton code (entouré de balises CODE) dans un message.

Je suppose que pour faire ce que tu souhaites, il suffirait d'appliquer aux deux autres onglets le même traitement de masquage que tu appliques à l'onglet qui fonctionne.

[ness-u]

Bonjour,
désolé mais entouré de balise code ?

voici mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
Sub PlanningPdf()
 
Application.ScreenUpdating = False
Dim i As Integer
Dim NbOnglets As Long
NbOnglets = ActiveWorkbook.Sheets.Count
 
    'Pour chaque onglet concerné
    For i = NbOnglets - 1 To NbOnglets - 3 Step -1
        With ThisWorkbook.Worksheets(i)
            .Activate
 
            .Rows("2:2").EntireRow.Hidden = True
            .Rows("17:25").EntireRow.Hidden = True
            .Rows("61:70").EntireRow.Hidden = True
            .Rows("91:99").EntireRow.Hidden = True
            .Rows("147:154").EntireRow.Hidden = True
            .Rows("172:265").EntireRow.Hidden = True
 
            Application.PrintCommunication = False
            .PageSetup.Zoom = 55
            Application.PrintCommunication = True
 
            .ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
            "C:\Users\xxx\Documents\Planning test.pdf", Quality:=xlQualityStandard _
            , IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:= _
            True
 
 
            .Rows("1:280").EntireRow.Hidden = False
        End With
    Next i
'
    Application.ScreenUpdating = True

[Menhir]

Ton Activate est inutile (étant donné le With de la ligne précédente) mais ce n'est pas ça qui pose problème.

Es-tu sûr que les onglets que tu veux traiter sont l'avant dernier et les deux précédents ?
Pour le vérifier, place cette ligne à la place de ton Activate et regarde les noms qui sortent dans la fenêtre d'exécution.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

   Debug.Print .Name

[ness-u]

c'est bon j'ai trouvé de l'aide. voici le code au cas où certains en auraient besoin.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
Sub planningPdf()
    Dim i As Integer
    Dim NbOnglets As Integer
    Dim TabFeuilles() As String
    Const LignesMasquées = "2:2,17:25,61:70,91:99,147:154,172:265"
    Const NomFichierPDF = "C:\Users\UR11725797\Documents\Planning test.pdf"
 
 
    Application.ScreenUpdating = False
    NbOnglets = ActiveWorkbook.Sheets.Count
 
    'Pour chaque onglet concerné, masquer les lignes
    For i = NbOnglets - 1 To NbOnglets - 3 Step -1
        With ThisWorkbook.Worksheets(i)
            ReDim Preserve TabFeuilles(1 To NbOnglets - i)
            TabFeuilles(NbOnglets - i) = .Name
            .Activate
 
            .Range(LignesMasquées).EntireRow.Hidden = True
 
            Application.PrintCommunication = False
            .PageSetup.Zoom = 55
            Application.PrintCommunication = True
        End With
    Next i
 
    'Export PDF des feuilles en 1 seul fichier
    ThisWorkbook.Worksheets(TabFeuilles).Select
    ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, _
    Filename:=NomFichierPDF, _
    Quality:=xlQualityStandard, _
    IncludeDocProperties:=True, _
    IgnorePrintAreas:=False, _
    OpenAfterPublish:=True
 
    'Pour chaque onglet concerné, démasquer les lignes
    For i = NbOnglets - 1 To NbOnglets - 3 Step -1
        With ThisWorkbook.Worksheets(i)
            .Range(LignesMasquées).EntireRow.Hidden = False
        End With
    Next i
 
    Application.ScreenUpdating = True
End Sub