Discussion :

[Sigma13]

Bonsoir à tous,

Grâce à l'aide précieuse de plusieurs internautes et experts en excel, j'ai pu créer un fichier pour répartir des montants en fonction de date de contrat. (factures pour abonnements annuels). Tout fonctionne à merveille sauf 1 point: lorsque la date de la facture est antérieure au contrat, la répartition ne se fait pas correctement, par exemple:

Un contrat à répartir uniquement sur 1 mois postérieur à la date de la facture (ex: facture du 01.01.19 mais contrat du 01.02.19 au 28.02.19), j'ai un total en négatif sur le mois de la facture puis la différence entre ce montant et le montant de la facture dans le mois du contrat.

J'ai fait plusieurs essai pour modifier le code mais malheureusement je n'y arrive pas. La personne qui m'a aidée et qui a créé le code, me dit que c'est contraire à l'hypothèse de base (Invoice date doit être supérieure ou égale à la date du début du contrat Sub Start Date //Invoice date doit être inférieure ou égale à la date de fin de fin du contrat Sub End Date).

Malgré cette information, je n'arrive pas à modifier l'erreur.
Est-ce que quelqu'un pourrait m'aider à trouver la solution? Merci d'avance pour vos réponses!Sigma13- Rmbt mensuel- anomalies- v2.xlsm

[EricDgn]

Bonjour,

Faut-il vraiment s'occuper de la date de signature du contrat? Les montants me semblent uniquement dépendre des dates de début et fin d'abonnement.
Si c'est le cas, alors ceci devrait convenir (et inutile d'ajouter des conditions et arrondis dans les cellules, la seule fonction suffit):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Function RmbtMensuel(ThisMonth As Date, SubStartDate As Date, SubEndDate As Date, TotalSub As Currency) As Currency
    Dim nbrMoisComplet&, nbrJour1&, nbrJour2&, parJour@, parMois@, Avant@, Apres@
    nbrMoisComplet = DateDiff("m", SubStartDate, SubEndDate + 1)
    If Day(SubStartDate) > 1 Then
        nbrJour1 = Application.WorksheetFunction.EoMonth(SubStartDate, 0) - SubStartDate + 1
        nbrMoisComplet = nbrMoisComplet - 1
    Else
        nbrJour1 = 0
    End If
    If Day(SubEndDate) = Day(Application.WorksheetFunction.EoMonth(SubEndDate, 0)) Then
        nbrJour2 = 0
    Else
        nbrJour2 = Day(SubEndDate)
    End If
    parJour = TotalSub / (nbrJour1 + nbrJour2 + 30 * nbrMoisComplet)
    parMois = Round(30 * parJour, 2)
    Avant = Round(nbrJour1 * parJour, 2)
    Apres = TotalSub - nbrMoisComplet * parMois - Avant
    'Debug.Print nbrMoisComplet, nbrJour1, nbrJour2
 
   If Format(ThisMonth, "yymm") = Format(SubStartDate, "yymm") Then
      RmbtMensuel = IIf(nbrJour1 = 0, parMois, Avant)
   ElseIf Format(ThisMonth, "yymm") = Format(SubEndDate, "yymm") Then
      RmbtMensuel = IIf(nbrJour2 = 0, parMois, Apres)
   Else
      If (Format(ThisMonth, "yymm") >= Format(SubStartDate, "yymm")) And (Format(ThisMonth, "yymm") <= Format(SubEndDate, "yymm")) Then RmbtMensuel = parMois
   End If
End Function

Comme toujours, vérifier avec des valeurs simples que l'on peut calculer soi-même!
Cordialement.