Discussion :

[bastringue]

Bonjour,
Je suis assez étonné de ce dysfonctionnement :

On a une subroutine dans laquelle on fait une boucle sur un range, et dans lequel on cherche une certaine occurrence (dans la colonne A).

Et simplement, quand on trouve une occurence, on appelle une fonction qui rend un booléen (pour décider si on inscrit les données dans le ListBox) et on passe à l'occurrence suivante.

Le dysfonctionnement que je constate, c'est que selon la façon dont je code la fonction qui rend le booléen (IsDebiteur), VBA plante ou pas !

Pour bien le montrer, j'ai écrit 2 fonctions "identiques", du moins elles donnent le même résultat mais l'une est codée avec un Find, et l'autre avec une boucle For Next.

Et le dysfonctionnement est net:

Si on appelle la première fonction (IsDebiteur) la routine plante sur l'instruction

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Loop While Not C Is Nothing And C.Address <> premier

car C se retrouve bizarrement à Nothing (alors qu'on a mis une condition sur C not nothing et qu'on ne fait que des Findnext !)

Si on appelle la seconde (IsDebiteur2), alors ça fonctionne parfaitement, C n'est pas Nothing et le findNext fonctionne bien.

Tout a l'air de se passer comme si le Find qu'on est en train de faire dans la routine principale entrait en conflit avec le Find qui est dans la fonction IsDebiteur (interprétation personnelle!)

Voici la routine principale:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Private Sub TextNom_Change()
   nom = Me.TextNom
   Me.ListBox1.Clear
   Set rng = BaseTatoo.Worksheets("Clients").Range("B:B")
   With rng
     Set C = .Find(nom, LookIn:=xlValues, Lookat:=xlPart) 
     i = 0
     If Not C Is Nothing Then
       premier = C.Address
       Do
          ' C.offset(0, -1) -> Id du client:
          If IsDebiteur(BaseTatoo, CLng(C.offset(0, -1).Value)) Then
           Me.ListBox1.AddItem
           Me.ListBox1.List(i, 0) = C.offset(0, -1).Value
           Me.ListBox1.List(i, 1) = C.Value
           Me.ListBox1.List(i, 2) = C.offset(0, 1).Value
            i = i + 1
          End If
         Set C = .FindNext(C)
       Loop While Not C Is Nothing And C.Address <> premier
     End If
   End With
End Sub

Voici la fonction IsDebiteur qui provoque un plantage:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Public Function IsDebiteur(Book As Workbook, ByVal ClientId As Long) As Boolean
Dim LastLig As Long
Dim rng, C As Range
Dim Duduclient As Currency
Dim premier As Variant
 
IsDebiteur = False
Duduclient = 0
 
    Set rng = Book.Sheets("Actes").Range("C:C")
    With rng
        'cherche clientId dans la colonne C
        Set C = .Find(ClientId, LookIn:=xlValues, Lookat:=xlWhole)
        If Not C Is Nothing Then
           premier = C.Address
           Do
             'cumule le Dû de la colonne E
             Duduclient = Duduclient + CCur(C.offset(0, 2))
             If Duduclient > 0 Then
                IsDebiteur = True
                Exit Function
             End If
             Set C = .FindNext(C)
           Loop While C.Address <> premier
        End If
    End With
End Function

Voici la fonction IsDebiteur2 qui permet un fonctionnement correct. Cette deuxième fonction est pourtant totalement équivalente à la précédente (produit les mêmes valeurs), mais elle n'utilise pas de Find.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Public Function IsDebiteur2(Book As Workbook, ByVal ClientId As Long) As Boolean
Dim LastLig, L As Long
Dim C As Range
Dim Duduclient As Currency
Dim premier As Variant
Dim rng As Range
 
IsDebiteur2 = False
Duduclient = 0
 
    LastLig = Book.Sheets("Actes").Range("A1").End(xlDown).Row
 
    Set rng = Book.Sheets("Actes").Range("A:E")
    With rng
    For L = 2 To LastLig
      'cherche clientId dans la colonne C
      If CLng(.Cells(L, "C").Value) = ClientId Then
         'cumule le Dû de la colonne E
         Duduclient = Duduclient + CCur(.Cells(L, "E"))
         If Duduclient > 0 Then
           IsDebiteur2 = True
           Exit Function
         End If
      End If
    Next L
    End With
 
End Function

Quelqu'un a une idée de ce qui se passe ?
Merci d'avance...

[Menhir]

Si on appelle la première fonction (IsDebiteur) la routine plante sur l'instruction

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Loop While Not C Is Nothing And C.Address <> premier

car C se retrouve bizarrement à Nothing (alors qu'on a mis une condition sur C not nothing et qu'on ne fait que des Findnext !)

Ce type de condition est aberrante syntaxiquement.

VBA évalue une condition dans sa globalité. Il ne va pas se dire "je teste une partie et si cette partie est fausse, je ne regarde pas le reste".
Donc, si C est Nothing, il va quand même tester C.Address, ce qui va forcément provoquer un bug.

Pour y remédier, il faut séparer les deux tests en deux lignes de code : D'abord tester si C est Nothing et, si ce n'est pas le cas, tester son Address.

[bastringue]

Merci Menhir pour ta remarque qui est juste. j'ai donc rectifié la routine principale ainsi :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
Private Sub TextNom_Change()
 
Dim init As String, nom As String
Dim C, rng As Range
Dim premier As Variant
Dim i, premierId As Long
 'On précise qu'il y a 3 colonnes dans la liste et on fixe les largeurs
 '(on précise uniquement 2 largeurs, la 3° est déduite de la largeur totale)
 Me.ListBox1.ColumnCount = 3
 Me.ListBox1.ColumnWidths = "0;120;"
 Me.ListBox1.TextColumn = 2  'colonne choisie pour affichage
 nom = Me.TextNom
 Me.ListBox1.Clear
 
 Me.NumClientText = ""
 If nom <> "" Then
  'On prépare une liste dont chaque ligne contient les 3 champs:  n°, nom, prénom
   Set rng = BaseTatoo.Worksheets("Clients").Range("B:B")
   With rng
     Set C = .Find(nom, LookIn:=xlValues, Lookat:=xlPart)  'recherche approximative
     i = 0
     If Not C Is Nothing Then
       premier = C.Address
       Do
          ' C.offset(0, -1) -> Id du client:
          If IsDebiteur2(BaseTatoo, CLng(C.offset(0, -1).Value)) Then
           Me.ListBox1.AddItem
           Me.ListBox1.List(i, 0) = C.offset(0, -1).Value
           Me.ListBox1.List(i, 1) = C.Value
           Me.ListBox1.List(i, 2) = C.offset(0, 1).Value
            i = i + 1
          End If
         Set C = .FindNext(C)
         If C Is Nothing Then GoTo ArretIndu
       Loop While C.Address <> premier
     End If
   End With
 Else
  Call RAZacte
 End If
 
 Exit Sub
 
ArretIndu:
 MsgBox "On ne sait pas pourquoi mais Excel A une adresse C qui est nothing alors qu'on est supposé boucler sans fin par le find next. "
 
End Sub

En l'occurence, et malgré l'aberration syntaxique qu'il y avait, il se trouve que normalement l'adresse C ne doit JAMAIS être nulle en raison du FIndNext qui n'arrête pas de boucler, quitte à repasser par la première occurence (et c'est justement là qu'on sort). Mais tu as raison, la syntaxe est plus claire ainsi.... Par contre, ça ne change absolument rien !

Je répète donc, si j'appelle la fonction IsDebiteur (codée avec un find), il se trouve que dès son premier appel, l'adresse de C devient Nothing et je vais au message d'erreur en bas de la routine.
Et si par contre j'appelle la 2° fonction IsDebiteur2 (codée avec un For), l'adresse de C ne devient jamais nothing, ce qui est parfaitement normal, et je ne vais pas à l'erreur.

En cherchant sur le net, j'ai vu pas mal de forum parlant de conflits en cas de 'nested FindNext loops' : selon ces lectures, l'imbrication de 2 Find / FIndNext pose problème et je pense que dans mon cas, et même si le 2° find est dans la fonction que j'appelle, il y a un conflit sur ces 2 finds...En tous cas, le test est sans appel...
Merci quand même pour l'avis...

[pijaku]

Bonjour,

En effet, FindNext et Find se prennent les pieds dans le tapis.

Remplacez donc, dans la procédure principale :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Set C = .FindNext(C)
         If C Is Nothing Then GoTo ArretIndu
       Loop While C.Address <> premier

Par une subtile variante...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
'recherche après l'ancien C...
Set C = .Find(nom, After:=C, LookIn:=xlValues, Lookat:=xlPart)
         If C Is Nothing Then GoTo ArretIndu
       Loop While C.Address <> premier

[bastringue]

En effet, Merci bcp Franck.

Solution subtile en effet, en tous les cas elle rétablit la valeur de C qui avait été corrompue...

Cordialement
Pierre

[pijaku]

Bonjour,

En fait, on sait que certains arguments, même facultatifs, de la méthode Find sont enregistrés dans les paramètres.
C'est le cas des arguments LookIn, LookAt, SearchOrder et MatchCase.
Si tu ne spécifies aucune valeur pour ces arguments, lors du prochain appel à la méthode, les valeurs enregistrées sont utilisées.
Le fait de définir ces arguments modifie les paramètres de la boîte de dialogue Rechercher (suffit de tester en VBA et ensuite de faire Ctrl+F depuis une feuille pour s'en rendre compte), ce qui a pour effet de changer les paramètres enregistrés.

Find, de la même manière, conserve l'argument What.
Tout du moins, lors de son utilisation avec FindNext.
FindNext, comme tu l'auras constaté, ne comporte qu'un unique argument : After.
Par conséquent, il se base sur la précédente utilisation de la méthode Find pour les autres arguments.

Je vais continuer quelques tests les jours prochains car c'est intéressant...

A bientôt, sur ce sujet ou ailleurs...

EDIT :
Find + FindNext se comporte exactement comme la boîte de dialogue Rechercher/remplacer (Ctrl+H)
Lorsque tu lances un remplacement dans ta feuille, en cliquant sur "remplacer" (pas sur remplacer tout), il fait pas à pas la boucle FindNext.
Si, alors que tous tes remplacements ne sont pas terminés, tu changes la valeur du champs "rechercher", il sera bien incapable de revenir, seul, à ta première valeur...