Discussion :

[wolfazer]

Voila, j'ai un gros problème avec la mise en place d'un tampon pour stocker des caractère, mais quand je lance l'aplication, elle plante sans message d'erreur, voila le code, si quelqu'un peut m'aider, merci d'avance!!

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Const REG_MULTI_SZ As Long = 7
Const BUFFER_SIZE As Long = 255:aie:
Dim Handle As Long
Dim DonneesValeur As String
Dim NBCaratères As Long
Dim Test As Long
If RegOpenKeyEx(HKEY_LOCAL_MACHINE, "HARDWARE\DESCRIPTION\system", 0, KEY_ALL_ACCESS, Handle) = 0 Then
 
 NomValeur = Space(BUFFER_SIZE):aie:
 NBCaratères = BUFFER_SIZE:aie:
 
Test = RegQueryValueEx(Handle, "SystemBiosVersion", 0, REG_MULTI_SZ, DonneesValeur, NBCaratères)
MsgBox ("Votre version du Bios est: " & DonneesValeur)
RegCloseKey (Handle)
End If

[Delbeke]

Heu, tu es sur qu'il s'agit bien de code vb5/6, ca n'y ressemble pas(c'est quoi ces aie ?), peut être du vb.net, auquel cas tu n'est ppas dans le bon forum

En regle générale il faut initialiser les variables string avant de les utiliser comme argument pour un appel a des Api
Exemple :
Mavalueur = string(255,0)

[wolfazer]

c'est bien du vb6, mais j'utilise une api windows "advapi32.dll", c'est pour sa que s'est un peut bizare

[Delbeke]

Voila ton code corrigé

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
 
Option Explicit
Const HKEY_LOCAL_MACHINE = &H80000002
Const REG_MULTI_SZ = 7
Const BUFFER_SIZE = 255
Const READ_CONTROL = &H20000
Const KEY_QUERY_VALUE = &H1
Const KEY_SET_VALUE = &H2
Const KEY_CREATE_SUB_KEY = &H4
Const KEY_ENUMERATE_SUB_KEYS = &H8
Const KEY_NOTIFY = &H10
Const KEY_CREATE_LINK = &H20
Const KEY_READ = KEY_QUERY_VALUE + KEY_ENUMERATE_SUB_KEYS + KEY_NOTIFY + READ_CONTROL
Const KEY_WRITE = KEY_SET_VALUE + KEY_CREATE_SUB_KEY + READ_CONTROL
Const KEY_EXECUTE = KEY_READ
Const KEY_ALL_ACCESS = KEY_QUERY_VALUE + KEY_SET_VALUE + _
                       KEY_CREATE_SUB_KEY + KEY_ENUMERATE_SUB_KEYS + _
                       KEY_NOTIFY + KEY_CREATE_LINK + READ_CONTROL
 
Private Declare Function RegCloseKey Lib "advapi32" (ByVal hKey As Long) As Long
Private Declare Function RegOpenKeyEx Lib "advapi32" Alias "RegOpenKeyExA" (ByVal hKey As Long, ByVal lpSubKey As String, ByVal ulOptions As Long, ByVal samDesired As Long, ByRef phkResult As Long) As Long
Private Declare Function RegQueryValueEx Lib "advapi32" Alias "RegQueryValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal lpReserved As Long, ByRef lpType As Long, ByVal lpData As String, ByRef lpcbData As Long) As Long
 
Private Sub Command1_Click()
  Dim Handle As Long
  Dim DonneesValeur As String
  Dim NBCaratères As Long
  Dim Test As Long
  If RegOpenKeyEx(HKEY_LOCAL_MACHINE, "HARDWARE\DESCRIPTION\system", 0, KEY_ALL_ACCESS, Handle) = 0 Then
    DonneesValeur = Space(BUFFER_SIZE)
    NBCaratères = BUFFER_SIZE
    Test = RegQueryValueEx(Handle, "SystemBiosVersion", 0, REG_MULTI_SZ, DonneesValeur, NBCaratères)
    MsgBox ("Votre version du Bios est: " & DonneesValeur)
    RegCloseKey (Handle)
  End If
End Sub

Ta variable NomValeur etait initialisé, mais tu en as utilisé une autre : DonneesValeur dans l'apel de la fonction
Je conseille de commencer tous tes programme par un Option Explicit qui oblige vb a vérifier que toute variable utilisé a bien été dimensionnée. Ca evite ce genre de bévue

[wolfazer]

merci pour l'aide rapide