Discussion :

[gnuminux]

Bonjour ,

j'ai un fichier xml dans lequel je dois remplacer une partie d'une chaîne de caractères par une valeur incrémentale:

Fichier xml:

Code XML :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
<balise>testbla032</balise>
<balise>testbla012</balise>
<balise>testbla043</balise>

résultat que j'attends :

Code XML :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
<balise>testbla001</balise>
<balise>testbla002</balise>
<balise>testbla003</balise>

ce que j'ai pour l'instant qui ne fonctionne pas :

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
@echo off&cls
set fichier=test1.txt
set chaine= testbla
 
if exist output.txt del output.txt
setlocal EnableDelayedExpansion
for /f "delims=" %%a in ('type %fichier%') do (
    set $ligne=%%a
	echo %%a
	PAUSE
    set $ligne=!$ligne:%chaine%=%001%!
    echo !$ligne!>>output.txt)
PAUSE
echo OK

Merci de votre aide

[ericlm128]

Ton testbla est il toujours suivi de 3 caractères ?

[gnuminux]

oui toujours

[ericlm128]

Je te propose quelque chose de simple par rapport à ton exemple

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
@echo off&cls
set fichier=test1.txt
set chaine=testbla
 
if exist output.txt del output.txt
setlocal EnableDelayedExpansion
 
set /a idx=0
for /f "tokens=1,2 delims=<>" %%a in (%fichier%) do (
	set /a idx+=1
	set ids=00!idx!
	set ids=!ids:~-3!
	echo ^<%%a^>%chaine%!ids!^</%%a^>
)>>output.txt
 
pause

[ericlm128]

Mais peut être que ton xml est plus compliqué que tu ne le dit.

[gnuminux]

Super merci la solution marche top, mais en effet mon fichier est un peu plus complexe
puisque j'ai aussi des valeurs différentes:

Code XML :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
<balise>testbko032</balise>
<balise>testblo012</balise>
<balise>testbre043</balise>

j'aurais dû faire une recherche plutôt sur la fermeture de la balise '<\balise>'
et changer juste les trois chiffres avant

Code XML :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
<balise>testbko001</balise>
<balise>testblo002</balise>
<balise>testbre003</balise>

je suis en train d'essayer si j'y arrive avec ta solution

[gnuminux]

Merci Eric avec quelques modifications sur ton code j'obtiens ce que je veux !

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
@echo off&cls
set fichier=test1.txt
set chaine=/balise
 
if exist output.txt del output.txt
setlocal EnableDelayedExpansion
 
set /a idx=0
for /f "tokens=1,2 delims=/" %%a in (%fichier%) do (
	set ligne=%%a
	set /a idx+=1
	set ids=00!idx!
	set ids=!ids:~-3!
	echo !ligne:~0,15!!ids!^<%chaine%^>
)>>output.txt
 
pause

Merci encore,
J'ai une autre petite question toujours sur le même sujet est il aussi possible d'appliquer la modification que quand on tombe sur la chaîne de caractères qu'on recherche
exemple:

Code XML :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
<balise>testbla023</balise>
<balise>testblo032</balise>
       <test>testbre053</test>
<balise>testbla043</balise>

résultat:

Code XML :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
<balise>testbla001</balise>
<balise>testblo002</balise>
       <test>testbre053</test>
<balise>testbla003</balise>

[ericlm128]

Petite adaptation

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
@echo off&cls
set fichier=test1.txt
 
if exist output.txt del output.txt
setlocal EnableDelayedExpansion
 
set /a idx=0
for /f "tokens=1,2 delims=<>" %%a in (%fichier%) do (
	set /a idx+=1
	set ids=00!idx!
	set ids=!ids:~-3!
	set chaine=%%~b
	set chaine=!chaine:~,-3!
	echo ^<%%a^>!chaine!!ids!^</%%a^>
)>>output.txt
 
pause