Discussion :

[texas2607]

Bonjour à tous,
- Je dispose d'un tableau 'T_Donnees' qui est en A:G
Sur ce tableau j'ai en colonne B les dates sous la forme JJ/MM/AAAA (elles commencent au 01/01/2016 pour être aujourd'hui au 22/05/2020)
Ensuite pour les autres colonnes j'ai des cellules remplies manuellement.

- Je fais omission des colonnes H:J car ce sont d'autres calculs qui sont intégrés et elles ne font pas parties de mon tableau 'T_Donnees'.

- J'ai donc ensuite la colonne L (Nommée 'Gains' et qui ne fait pas partie du tableau non plus) que je rempli manuellement avec des sommes en €

Ce que je voudrais sur une nouvelle feuille c'est une somme de ma colonne 'Gains' en fonction de la date de mon tableau T_Donnees (addition par mois et par années)
savoir combien de gains pour janvier 2020, Février 2020, Mars 2020, etc.
Je tourne en rond avec la formule SommeProd qui me semblais être celle qui fallait.

Merci pour votre aide

[Menhir]

Il suffit de faire un Tableau Croisé Dynamique.

Si tu veux le faire par fonction, utilise une SOMME.SI.ENS() avec deux critère de date, un >= début de mois et un < début de mois suivant.

[mikhaelN]

Hello,

Par formule, je vois trois possibilités

Si les dates de gains sont en colonne B (B3:B100), les gains en colonne C (C3:C100) et les entêtes de mois de consolidation (Format date MM/AAAA) en colonne E (E3:Ex), la formule en consolidation en colonne F3 pourrait être

FORMULE SOMME.SI ENS

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME.SI.ENS($C$3:$C$100;$B$3:$B$100;">=" & DATE(ANNEE(E3);MOIS(E3);1);$B$3:$B$100;"<" & DATE(ANNEE(E3);MOIS(E3)+1;1))

FORMULE SOMMEPROD

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD(($B$3:$B$100>=DATE(ANNEE(E3);MOIS(E3);1))*($B$3:$B$100<DATE(ANNEE(E3);MOIS(E3)+1;1))*$C$3:$C$100)

FORMULE MATRICIELLE

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

={SOMME(SI($B$3:$B$100>=DATE(ANNEE(E3);MOIS(E3);1);1;0)*SI($B$3:$B$100<DATE(ANNEE(E3);MOIS(E3)+1;1);$C$3:$C$100;0))}