Discussion :

[tifou_oufti]

Bonjour,

Un peu novice dans ce langage, j'aurai besoin de votre aide pour optimiser mon code

Voici l'explication de mon de code:
J'ai une liste de fichiers pdf (ListeDocMove.txt) à copier dans un répertoire (C:\Users\XXXXX\Desktop\PRO\ZZ_File).
Les fichiers pdf se trouvent dans une multitude de dossier sous-dossier.

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
@ECHO off
	SET "srclist=F:\ListeDocMove.txt"
	SET "targetdir=C:\Users\XXXXX\Desktop\PRO\ZZ_File"
	SET "srcdir=F:\Projet\"
 
FOR /f "delims=" %%f in ('type "%srclist%"') DO (
  	ECHO * Recherche du fichier "%%f", parcours des dossiers :
  	ECHO - "%srcdir%"
	IF EXIST "%srcdir%\%%f" (
	    ECHO Trouvé : "%srcdir%\%%f"
	    COPY /y "%srcdir%\%%a" "%targetdir%"
   	) ELSE (
   		FOR /f "delims=*" %%d in ('dir /b /a:d /s "%srcdir%"') DO (
		     ECHO - %%d
		     IF EXIST "%%d\%%f" (
		       ECHO Trouvé : %%d\%%f
		       COPY /y "%%d\%%f" "%targetdir%">NUL
		       IF ERRORLEVEL 1 (
		         ECHO ECHEC !
		       )
		     )
   		)
  	)
)
 
Pause

Pour optimiser mon code je voudrais que lorsqu'il trouve un fichier, il le copie et passe à un autre fichier sans continuer de parcourir tous les dossiers...
J'ai tenté avec un goto :next mais je pense ne pas bien utilisé cette commande

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
@ECHO off
	SET "srclist=F:\ListeDocMove.txt"
	SET "targetdir=C:\Users\XXXXX\Desktop\PRO\ZZ_File"
	SET "srcdir=F:\Projet\"
 
FOR /f "delims=" %%f in ('type "%srclist%"') DO (
  	ECHO * Recherche du fichier "%%f", parcours des dossiers :
  	ECHO - "%srcdir%"
	IF EXIST "%srcdir%\%%f" (
	    ECHO Trouvé : "%srcdir%\%%f"
	    COPY /y "%srcdir%\%%a" "%targetdir%"
            GOTO :Next
   	) ELSE (
   		FOR /f "delims=*" %%d in ('dir /b /a:d /s "%srcdir%"') DO (
		     ECHO - %%d
		     IF EXIST "%%d\%%f" (
		       ECHO Trouvé : %%d\%%f
		       COPY /y "%%d\%%f" "%targetdir%">NUL
                       GOTO :Next
		       IF ERRORLEVEL 1 (
		         ECHO ECHEC !
		       )
		     )
   		)
  	)
:NEXT
echo "suivant"
)
 
Pause

[ericlm128]

Voici quelque chose de beaucoup plus optimiser mais ça reste très lent :

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
cls
@echo off
 
SETLOCAL ENABLEDELAYEDEXPANSION
 
SET "srclist=F:\ListeDocMove.txt"
SET "targetdir=C:\Users\XXXXX\Desktop\PRO\ZZ_File"
SET "srcdir=F:\Projet\"
 
 
FOR /f "usebackq delims=" %%f in ("%srclist%") DO (
  	ECHO * Recherche du fichier "%%f", parcours des dossiers :
  	ECHO - "%srcdir%"
 
	set fpath=
	FOR /f "delims=" %%d in ('dir /b /a:-d /s "%srcdir%%%f" 2^>nul') do set "fpath=%%~d"
 
	if defined fpath (
		echo Trouve : !fpath!
		COPY /y "!fpath!" "%targetdir%" >NUL
	) else (echo ECHEC !)
	echo.
)
pause

[ericlm128]

Si tu veux quelques chose de beaucoup plus optimisé je te conseil ceci, mais tu n'aura plus les erreurs.

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
cls
@echo off
 
SET "srclist=F:\ListeDocMove.txt"
SET "targetdir=C:\Users\XXXXX\Desktop\PRO\ZZ_File"
SET "srcdir=F:\Projet\"
 
FOR /f "delims=" %%d in ('dir /b /a:-d /s "%srcdir%"^| findstr /E /I /G:"%srclist%"') do (
	echo Trouve : %%~d
	COPY /y "%%~d" "%targetdir%" >NUL
)
pause

[ericlm128]

Tout ceci reste du batch donc tu ne fera pas les 24 heures du mans avec ta twingo

[tifou_oufti]

Merci beaucoup pour votre aide, je vais tester ça cette après-midi!
Il y a vachement moins de code déjà!

Cette partie de code pourra déjà me faire gagner un peu de temps, celui qu'il parcourait pour rien car il avait déjà trouvé le fichier

[ericlm128]

celui qu'il parcourait pour rien

Pas forcement, tu peux avoir plusieurs fichiers avec le même nom à des endroits différents