Discussion :

[Malick]

Bonjour,

J'ai ce macro qui me permet de faire la somme des colonnes Montant1 et Montant2, et une petite mise en forme.

Je suis preneur pour des idées afin de le rendre plus propre.

Merci d'avance

Code vba :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Sub SommeDebCred()
Dim DernLigne As Long, MaPlage1 As Range, MaPlage2 As Range
 
    DernLigne = Range("A1048576").End(xlUp).Row
    Set MaPlage1 = Range("F5:F" & DernLigne)
    Set MaPlage2 = Range("G5:G" & DernLigne)
    Range("A" & DernLigne + 1).Select
    ActiveCell = "TOTAL"
    ActiveCell.Font.Bold = True
    ActiveCell.HorizontalAlignment = xlCenter
    ActiveCell.Offset(0, 5) = Application.WorksheetFunction.Sum(MaPlage1)
    ActiveCell.Offset(0, 5).Font.Bold = True
    ActiveCell.Offset(0, 5).NumberFormat = "#,##0"
    ActiveCell.Offset(0, 6) = Application.WorksheetFunction.Sum(MaPlage2)
    ActiveCell.Offset(0, 6).Font.Bold = True
    ActiveCell.Offset(0, 6).NumberFormat = "#,##0"
    ActiveSheet.Range("A" & DernLigne + 1, "D" & DernLigne + 1).MergeCells = True 'Fusion de la ligne Total de A à D
 
End Sub

[ARTURO83]

Bonjour,

Ceci par exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub SommeDebCred()
    Dim DerLig As Long, i As Long
    DerLig = Range("A" & Rows.Count).End(xlUp).Row + 1
    With Range("A" & DerLig)
        .Value = "TOTAL"
        .HorizontalAlignment = xlCenter
    End With
    For i = 1 To 2
        With Cells(DerLig, i + 5)
            .Value = Application.WorksheetFunction.Sum(Range(Cells(5, i + 5), Cells(DerLig - 1, i + 5)))
            .NumberFormat = "#,##0"
        End With
    Next i
    Range("A" & DerLig, "G" & DerLig).Font.Bold = True
    Range("A" & DerLig, "D" & DerLig).MergeCells = True  'Fusion de la ligne Total de A à D
 End Sub

Cdlt

[mfoxy]

Bonjour Malick,

Il n'y a pas réellement de nécessité de coder pour ce cas.

Il te suffit de passer ton tableau en tableaux structurés et d'ajouter, dans les options de ton tableau, la ligne totaux qui peut contenir : une moyenne, somme, médiane, Count,...

Et ce sans une ligne de code juste un clic sur une check box du bandeaux et le choix du type de calcul dans la ligne total.

Bien à toi,

MFoxy

[Malick]

Bonjour,

Bonjour,

Ceci par exemple

Merci ARTURO83, je teste cela et te reviens

Bonjour Malick,

Il n'y a pas réellement de nécessité de coder pour ce cas.

Il te suffit de passer ton tableau en tableaux structurés et d'ajouter, dans les options de ton tableau, la ligne totaux qui peut contenir : une moyenne, somme, médiane, Count,...

MFoxy

Merci pour ce retour Je connais l'existence des tableaux structurés et je les utilise avec Power Query aussi. Sauf que pour ce cas, c'est plusieurs feuilles qui sont générées par code, et je dois intégrer la mise en forme et les calculs automatiquement lors de la génération. Ce ce qui justifie le codage.

encore

[Malick]

Salut,

@ARTURO83, ta proposition fonctionne nickel.

et bon weekend