Discussion :

[modus57]

Bonsoir à toutes et à tous.

Dans un classeur qui comporte plusieurs UserForm et plusieurs objets LlistBox, TexBbox, Label, CommandButton …), je souhaiterai lister tous les UseForm et tous ses contrôle dans une feuille.

J'arrive à créer cette liste sur une seule colonne voici mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub ListeUSF_Controle()
    Dim VBCmp As VBComponent
    Dim Ctrl As Control
    i = 2
    For Each VBCmp In ThisWorkbook.VBProject.VBComponents
        If VBCmp.Type = 3 Then
            Cells(i - 1, 1) = VBCmp.Name
            ActiveCell.Interior.Color = 49407
            For Each Ctrl In clients.Controls
                Worksheets("Liste contrôles").Cells(i, 1).Value = Ctrl.Name
                i = i + 1
            Next Ctrl
        End If
    Next VBCmp
    Activesheet. Cells.EntireColumn.AutoFit 
End Sub

Mais j'aimerai lister dans la première colonne le nom du premier UserForm et les noms de ses contrôles, dans la deuxième colonne le nom du deuxième UserForm et les noms de ses contrôles, ainsi de suite …

Je n'y arrive pas, cela ne doit pas être très compliqué pour les experts de ce forum.

Merci d'avance pour votre aide.

[ARTURO83]

Bonjour,

Ceci, non testé

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Sub ListeUSF_Controle()
    Dim VBCmp As VBComponent
    Dim Ctrl As Control
    i = 2
    Col = 1
    For Each VBCmp In ThisWorkbook.VBProject.VBComponents
        If VBCmp.Type = 3 Then
            Cells(i - 1, Col) = VBCmp.Name
            ActiveCell.Interior.Color = 49407
            For Each Ctrl In clients.Controls
                Worksheets("Liste contrôles").Cells(i, Col).Value = Ctrl.Name
                i = i + 1
            Next Ctrl
            Col = Col + 1
        End If
    Next VBCmp
    ActiveSheet.Cells.EntireColumn.AutoFit
End Sub

Cdlt

[modus57]

Bonjour ARTURO83.

Merci pour ta réponse.

Petite remarque les listes se mettent bien dans les colonnes suivantes mais pas à la première ligne.

J'ai une petite coquille dans mon code il faut remplacer :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

For Each Ctrl In clients.Controls

Par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

For Each Ctrl In VBCmp.Designer.Controls

[ARTURO83]

Petite remarque les listes se mettent bien dans les colonnes suivantes mais pas à la première ligne.

il faut réinitialiser la variable i

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
    For Each VBCmp In ThisWorkbook.VBProject.VBComponents
        If VBCmp.Type = 3 Then
            Cells(i - 1, Col) = VBCmp.Name
            ActiveCell.Interior.Color = 49407
            For Each Ctrl In VBCmp.Designer.Controls
                Worksheets("Liste contrôles").Cells(i, Col).Value = Ctrl.Name
                i = i + 1
            Next Ctrl
            Col = Col + 1
            i = 2
        End If

Cdlt

[modus57]

Re.

Je suis pas à l'aise avec les boucles un peu complexe.

Et pour faire un simple tri ascendant de toutes les colonnes ?

[ARTURO83]

Bonsoir,

Votre code complet

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Sub ListeUSF_Controle()
    Dim VBCmp As VBComponent
    Dim Ctrl As Control
    Dim f1 As Worksheet
 
    Set f1 = Sheets("Liste contrôles")
    i = 2
    Col = 1
    For Each VBCmp In ThisWorkbook.VBProject.VBComponents
        If VBCmp.Type = 3 Then
            f1.Cells(i - 1, Col) = VBCmp.Name
            f1.Cells(i - 1, Col).Interior.Color = 49407
            For Each Ctrl In VBCmp.Designer.Controls
                f1.Cells(i, Col).Value = Ctrl.Name
                i = i + 1
            Next Ctrl
            Col = Col + 1
            i = 2
        End If
    Next
    DerCol = f1.Range("XFD1").End(xlToLeft).Column
    For c = 1 To DerCol
        DerLig = f1.Cells(1, c).End(xlDown).Row
        f1.Range(Cells(2, c), Cells(DerLig, c)).Sort Cells(1, c), 1
    Next c
    f1.Cells.EntireColumn.AutoFit
End Sub

Cdlt