Discussion :

[quel29]

Bonjour,

Je suis débutant en vba et je voulais savoir si quelqu'un pouvais m'aider?
En effet j'ai essayer de réaliser une macro de suppression de ligne.
Malheureusement, ma macro supprime certaine ligne ou la cellule B est vide mais pas toute.
Je suis donc obliger de relancer plusieurs fois la macro pour qu'elle les supprimes entièrement.

Voici ma macro :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub supp()
 
Dim fl As Worksheet
Sheets("F203170862086_ZADVS02C-89.23505").Select
 
 
Dim cell As Range
 
For Each cell In Range("B1:B20000")
If cell.Value = "" Then
cell.EntireRow.Delete Shift:=xlUp
 
End If
 
Next cell
 
End Sub

Je vous remercie par avance de votre aide.

[mfoxy]

Bonjour,

Pour supprimer des lignes, tu dois faire une boucle incrémenté à l'inverse, du bas vers le haut.
Pour un nombre de ligne important , il voudrait mieux privilégié une méthode avec filtre.

1) Filtrer tout les "" de ta colonne B
2) Suppimer toutes les lignes de visible
3) Défiltrer

Ce qui donnerait :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
 
Sub Delete_Rows_Based_On_Value()
 
Dim ws As Worksheet
Dim filterRange As Range
 
 
  Set ws = ThisWorkbook.Worksheets("Sheet1") ' modifier par ton nom de feuille
  Set filterRange = ws.Range("B1:B2000")
 
  On Error Resume Next
  ws.ShowAllData
  On Error GoTo 0
  filterRange.AutoFilter Field:=1, Criteria1:="" '1)
 
  Application.DisplayAlerts = False
    filterRange.SpecialCells(xlCellTypeVisible).Delete '2
  Application.DisplayAlerts = True
 
 
  On Error Resume Next
    ws.ShowAllData '3
  On Error GoTo 0
 
  Set ws = Nothing
  Set filterRange = Nothing
 
 
End Sub

[Menhir]

En effet j'ai essayer de réaliser une macro de suppression de ligne.
Malheureusement, ma macro supprime certaine ligne ou la cellule B est vide mais pas toute.

Quand on fait des suppressions ou des insertions, il faut toujours aller de la dernière ligne à la première.

Je t'explique pourquoi.
Imaginons que tu ais à supprimer les lignes 2 et 3.
En arrivant sur la ligne 2, la suppression va se faire mais cette suppression va décaler toutes les lignes vers le haut. Ta ligne 3 va devenir la ligne 2. Et comme ta boucle va continué à la ligne suivante, cette ligne 2 (anciennement 3) sera ignorée puisqu'elle passera à la ligne 3 (anciennement 4).

Essaye ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub supp()
    Dim fl As Worksheet
    Dim Lig As Long
 
    Set fl = Sheets("F203170862086_ZADVS02C-89.23505")
 
    For Lig = fl.Cells(Rows.Count, "B").End(xlUp).Row To 1 Step -1
        If fl.Cells(Lig, "B").Text = "" Then fl.Rows(Lig).Delete
    Next Lig
End Sub

Je conserve un code assez proche du tien pour que tu comprennes bien mais il y a des méthodes qui permettent une exécution plus rapide pour faire ça.

[quel29]

Bonjour mfoxy,

Je te remercie pour ton aide malheureusement en essayant ton code j'ai remarqué que cela ne supprimer pas les cellules vides mais la première ligne du tableau.

Bonjour Menhir,

Merci pour ton aide, j'ai également essayé ton code et il fonctionne a merveille merci beaucoup.

[Menhir]

Si tu veux aller plus vite, ceci devrait fonctionner (j'insiste sur le "devrais" car je n'ai pas testé :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Sub supp()
    Sheets("F203170862086_ZADVS02C-89.23505").Select
    Range("B1", Cells(Rows.Count, "B").End(xlUp)).SpecialCells(xlCellTypeBlanks).EntireRow.Delete
End Sub

[quel29]

Bonjour Menhir,

Désoler de répondre aussi tardivement.

Ton code marche a merveille merci !!