Discussion :

[kookyzzz]

Bonjour, je galère avec Find pour l'utiliser dans une boucle...
Voilà en détail ce que je souhaite faire :
J'ai 2 colonnes sur ma feuille, la 1ere est une liste de valeurs et la seconde contient les valeurs que je souhaite rechercher dans la liste (1ere colonne). Je souhaite colorer les caractères de la valeur en rouge si la valeur n'est pas trouvée dans la liste...
voici mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub controle()
Set rgFound = Range("A1:A30")
 
For i = 1 To 30
 
    rgFound.Find what:=Cells(i, 4).Value
 
    If rgFound Is Nothing Then
        MsgBox "Name was not found."
        Range("D" & i).Font.Color = -16776961
    Else
        MsgBox "Name found in :" & rgFound.Address
    End If
 
Next i
 
End Sub

j'ai l'impression que je n'arrive pas à faire en sorte que Find recherche toutes les valeurs de ma seconde colonne...
Merci d'avance pour votre aide, je galère là dessus depuis 2 jours maintenant
ci-joint ma feuille excel

[Philippe Tulliez]

Bonjour,
Est-ce qu'une simple mise en forme conditionnelle dont la formule serait le résultat renvoyé par la fonction EQUIV ne conviendrait pas ?
Deux minutes à mettre en place

[kookyzzz]

merci Philippe pour ta réponse, ce que tu me prose marcherai surement mais je souhaite pourvoir maîtriser find car je vais surement avoir a l'utiliser prochainement dans de nombreux projet que j'ai en cours et je comprends vraiment pas pourquoi je ne peut pas lancer des recherches en boucle ...
Il s'agit peut être d'un simple problème de codage, j'ai arrêté la programmation pendant 10 ans je viens tout juste de m'y remettre, j'ai oublié plein de chose même si cela semble me revenir petit à petit

[Philippe Tulliez]

Bonjour,
Petite procédure rapide. Testée mais peut-être pas tous les cas.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Sub TestFind()
  Dim rngData_1 As Range
  Dim rngData_2 As Range
  Dim Cell As Range
  Dim C As Range
  Dim msg As String
  With ThisWorkbook.Worksheets("Feuil5")
    Set rngData_1 = .Range("A2:A25")
    Set rngData_2 = .Range("E2:E9")
  End With
  ' Boucle de recherche
  For Each Cell In rngData_1
    Set C = rngData_2.Find(What:=Cell.Value, MatchCase:=False, LookAt:=xlWhole)
    If Not C Is Nothing Then
      msg = msg & vbCrLf & Cell.Value & " trouvé à l'adresse " & C.Address
    End If
  Next
  MsgBox msg
 End Sub

[kookyzzz]

Merci Philippe, j'ai adapté et cela marche nickel

[Patrice740]

Bonjour,

Sans find :

Code VBA Excel :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Option Explicit
Sub controle()
Dim rngTest As Range    'zone à tester
Dim tbT As Variant      'valeurs à tester
Dim tbR As Variant      'valeurs recherchées
Dim tbC() As Variant    'couleurs
Dim ix1 As Long         'index 1
Dim ix2 As Long         'index 2
 
  With Worksheets("Feuil1")
    Set rngTest = .Range("A2:A" & .Cells(.Rows.Count, "A").End(xlUp).Row)
    With .Range("D1").CurrentRegion
      tbR = Application.Transpose(.Resize(.Rows.Count - 1).Offset(1).Value)
    End With
  End With
  tbT = Application.Transpose(rngTest.Value)
  ReDim tbC(LBound(tbT) To UBound(tbT))
  For ix1 = LBound(tbC) To UBound(tbC)
    tbC(ix1) = rgbRed
  Next ix1
  For ix1 = LBound(tbR) To UBound(tbR)
    For ix2 = LBound(tbT) To UBound(tbT)
      If tbT(ix2) = tbR(ix1) Then tbC(ix2) = rgbBlack
    Next ix2
  Next ix1
  For ix1 = LBound(tbC) To UBound(tbC)
    rngTest.Cells(ix1, 1).Font.Color = tbC(ix1)
  Next ix1
 
End Sub

[kookyzzz]

Merci Patrice, j'avais pensé faire un truc comme ca, mais Find reste plus lisible je trouve et plus simple à mettre en place.