Créer un listobject à partir d'un listobject ?

**Patoche90** · 19/12/2019, 09h15

Bonjour,

Tous est dans l'intitulé.....

Je m'explique :
1/ J'ai un tableau structuré qui contient plusieurs colonnes & lignes -> Set Mon_Tableau = worksheets("Ma_Feuille").listobjects("Table").
2/ j'aimerais avoir un objet de type ListObject -> Dim Ma_Colonne as Listobject.
3/ qui contienne une colonne de "Mon_Tableau" -> Set Ma_Colonne = Mon_Tableau.Listcolumns("Ref").Range.listobject.

Ce qui ne marche pas ici car Ma_Colonne.Range.Address = l'adresse de Mon_Tableau.

D'où ma question est-il possible de créer un un objet de type ListObject qui soit une extraction d'un autre ListObject ?

Merci d'avance.

**Philippe Tulliez** · 19/12/2019, 09h38

Bonjour,
La colonne d'un objet ListObject est un objet Range
Si maintenant on exporte l'objet Range on peut bien entendu, le convertir ensuite en objet ListObject.
Exactement comme on le ferait manuellement

**Patoche90** · 19/12/2019, 09h46

Envoyé par Philippe Tulliez

Bonjour,
La colonne d'un objet ListObject est un objet Range
Si maintenant on exporte l'objet Range on peut bien entendu, le convertir ensuite en objet ListObject.
Exactement comme on le ferait manuellement

Et comment on fait ?

**Philippe Tulliez** · 19/12/2019, 09h55

Bonjour,

Et comment on fait ?

Voici un exemple de la conversion en tableau structuré (ListObject) d'une colonne copiée (ici Logement) de l'unique tableau se trouvant dans la feuille nommée db vers une nouvelle feuille

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Sub T()
  ' Déclaration
  Dim oList As ListObject
  Dim rngColumn As Range
  Dim NewSheet As Worksheet
  ' Assignation
  Set oList = ThisWorkbook.Worksheets("db").ListObjects(1)
  Set rngColumn = oList.ListColumns("Logement").Range
  ' Start
  Set NewSheet = ThisWorkbook.Worksheets.Add       ' Insère une nouvelle et l'assigne à la variable objet
  rngColumn.Copy Destination:=NewSheet.Range("A1") ' Copie de la colonne nommée "Logement" à partir de la cellule A1 de la nouvele feuille
  ' Conversion de la colonne exportée en objet ListObject
  With NewSheet
  .ListObjects.Add SourceType:=xlSrcRange, Source:=.Range("A1").CurrentRegion, xlListObjectHasHeaders:=xlYes
  End With
  ' Fin
  Set oList = Nothing: Set rngColumn = Nothing: Set NewSheet = Nothing
End Sub

**Patoche90** · 19/12/2019, 10h32

Bonjour,

Merci pour ces éclaircissements....
En gros je suis obligé de faire une copie de la zone qui m'interresse et d'y affecter un listobject.

Si je comprends bien un listobject est un objet qui doit pointer sur une zone d'une feuille d'un classeur et non un objet qui peut-être mis en mémoire comme un Array par exemple.

Merci.