Discussion :

[Sebtien]

Bonjour à tout le forum
Je suis nouveau ici. Je vous ai souvent lu lors de mon apprentissage de VBA durant mon cursus universitaire.
Mais aujourd’hui pour une application professionnelle, je sèche sur un point, et j’aimerais savoir si quelqu’un pouvait m’aider svp ?
Voici le problème :
sur une feuille Excel, j'ai plusieurs valeurs dans la colonne A
pour chacune de ces valeurs je dois renseigner la valeur dans la zone de recherche d'une page web puis valider la recherche
j’arrive sur une nouvelle page web et c'est sur cette page que je dois récupérer une donnée
le problème est que que je n'arrive pas à pointer cette page web et à travailler dessus
Voici le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Sub extraction_Donnees()
 
Dim IE As New SHDocVw.InternetExplorer
Dim Doc As MSHTML.HTMLDocument
Dim Ele As MSHTML.IHTMLElement
 
IE.Visible = True
IE.navigate "https://geco.amf-france.org/Bio/rech_opcvm.aspx"
 
Do While IE.readyState <> READYSTATE_COMPLETE
Loop
'on attend
Set Doc = IE.document
'on pointe le document
Set Ele = Doc.getElementById("CodePart")
 
Ele.Value = "FR0007021670"
'le champs recherche est renseigné de la valeur FR0007021670
Set Ele = Doc.getElementById("valid_form")
Ele.Click
 
 
Do While IE.readyState <> READYSTATE_COMPLETE
Loop
 
 
'on lance la recherche et on arrive sur la page "https://geco.amf-france.org/Bio/info_opcvm.aspx?NumProd=19174"
'en gros j'aimerais trouver le moyen de redefinir IE sur cette nouvelle page
'or j'ai toujours IE.LocationURL qui vaut "https://geco.amf-france.org/Bio/rech_opcvm.aspx"
 
MsgBox IE.LocationURL
 
...
 
End Sub

Merci d'avance pour votre aide
Seb

[mercatog]

Bonjour

Repointe IE.document avec une attente pour laisser le temps à IE

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Sub Extraction_Donnees()
Dim IE As Object, Doc As Object, Ele As Object
Dim Url As String, Rep As String
 
 
Url = "https://geco.amf-france.org/Bio/rech_opcvm.aspx"
Set IE = CreateObject("InternetExplorer.application")
IE.Visible = True
IE.navigate Url
 
Do While IE.readystate <> 4
    DoEvents
Loop
 
Set Doc = IE.document
Set Ele = Doc.getElementById("CodePart")
Ele.Value = "FR0007021670"
Set Ele = Doc.getElementById("valid_form")
Ele.Click
 
Do Until IE.locationurl <> Url
    DoEvents
Loop
 
Application.Wait (Now + TimeValue("0:00:01"))
Set Doc = IE.document
Set Ele = Doc.getelementsbytagname("table")
'Ele(3) c'est notre résultat
Rep = Ele(3).innertext
IE.Quit
 
MsgBox Rep
End Sub

[Sebtien]

Bonsoir Mercatog
C'est impeccable, c'est exactement ce que je souhaitais
merci d'avoir pris le temps pour m'aider,
je vous souhaite une bonne soirée

Seb