Discussion :

[sweetty]

Bonjour,

J'ai un petit soucis avec le code ci dessous: il ne veut pas m'enregistrer les factures sous format PDF sur une clé USB, tandis que l'enregistrement dans l'onglet marche nickel. Je voudrais que lors de l'enregistrement, dans la clé USB, dossier Fromagerie, puis dossier Facture VE puis sous dossier 2019, il m'enregistre les factures au format: Facture_num facture
Je ne si pas si ça vient de mon num facture mais même avec une autre case au format texte standard, rien. Mon numéro de facture est au format 2019/VE/00180 par exemple, qui se modifie à chaque VALIDATION de facture avec le code dessous. Merci pour votre aide.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
Sub VALIDER()
 
'ENREGISTREMENT DE LA FACTURE EN PDF SUR CLE USB DOSSIER Facture VE 2019
 
 'Déclaration des variables
    Dim NomDossier As String
    Dim CheminDossier As String
 
    On Error GoTo 1
 
    'Nom de dossier et le chemin du dossier de sauvegarde
     NomDossier = Application.InputBox("Dossier Enregistrement :", "Année")
     CheminDossier = "f:\FROMAGERIE\Facture VE\" & NomDossier & "\"
 
    If NomDossier = "" Then Exit Sub
 
    'Enregistrement au format PDF
    ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
    CheminDossier & "Facture_" & Range("C12").Value & ".pdf", quality:= _
    xlQualityStandard, includedocproperties:=True, ignoreprintareas:=False, _
    from:=1, to:=1, openafterpublish:=False
 
1
 
'ENREGISTREMENT DU CONTENU DE LA FACTURE DANS L'ONGLET VE
 
    Dim Titres(), Dic As New Dictionary, C As Long, TFact(), L As Long, TRés(), item
    Titres = Feuil4.[A2:AS2].Value     'fait correspondre entêtes de VE avec produits Feuil2
    TFact = Feuil1.[A12:J44].Value
 
    ReDim TRés(1 To 1, 1 To UBound(Titres, 2))
    TRés(1, 1) = TFact(1, 3)    'n° de facture
    TRés(1, 2) = TFact(1, 1)    'date
    TRés(1, 3) = TFact(1, 5)    ' N° client
    TRés(1, 4) = NomClient(TFact(1, 5))    ' Nom client
    TRés(1, 5) = TFact(31, 10)    ' TTC
    TRés(1, 6) = TFact(29, 10)    'HT
    TRés(1, 7) = TFact(30, 5)    'TVA 5.5%
    TRés(1, 8) = TFact(31, 5)    'TVA 7%
    TRés(1, 9) = TFact(32, 5)    'TVA 10%
    TRés(1, 10) = TFact(33, 5)    'TVA 20%
 
    For C = 11 To 45 'produits ligne 2 VE
        For L = 4 To 28    'lignes 15 to 39 de factures
            If TFact(L, 2) = Titres(1, C) Then
                TRés(1, C) = TRés(1, C) + TFact(L, 10)
            End If
        Next
    Next C
 
    Feuil4.Cells(&H100000, 1).End(xlUp).Offset(1).Resize(, 45).Value = TRés
 
    Dim N
 
    On Error GoTo NuméroUn
    N = Right(Range("C12").Value, 5)
    Range("C12").Value = "" & Year(Date) & "/" & "VE" & "/" & Format(N + 1, "00000")
    MsgBox "facture " & Range("C12").Value & " archivée"
    Exit Sub
NuméroUn:
    Range("C12").Value = "" & Year(Date) & "/" & "VE" & "/" & Format(1, "00000")
    Resume Next
 
End Sub

[Menhir]

Commence par supprimer tes On Error et peut-être VBA t'expliquera-t-il où se trouve ton erreur et quel est sa nature.

[halaster08]

Mon numéro de facture est au format 2019/VE/00180

"/" fait partie des caractères interdits pour un nom de fichier.

[sweetty]

Merci à tous pour vos conseils.

Exactement, le format de facture n'était pas bon, il ne lui fallait que des chiffres. J'ai du modifier mes formats en le découpant en 2 pour garder le même modèle.
Maintenant ça marche Nickel.
Merci