Discussion :

[DPhBxl]

Bonjour à tous,

J'ai un problème

Lire la liste des catégories dans Outlook n'est pas compliqué…

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Private Sub ListCategoryIDs() 
 
 Dim objNameSpace As NameSpace 
 Dim objCategory as Category
 
 Set objNameSpace = Application.GetNamespace("MAPI")
 
 For Each objCategory In objNameSpace.Categories
    MsgBox objCategory.Name
 Next
 
End Sub

Mais comment lire la liste d'une boite autre ?
<objRecipient.Categories> ne fonctionne pas et donne les catégories de la boîte issue de <objNameSpace.Categories>

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Private Sub ListCategoryIDs() 
 
 Dim objNameSpace As NameSpace 
 Dim objRecipient as Recipient
 Dim objCategory as Category
 
 Set objNameSpace = Application.GetNamespace("MAPI")  
 Set objRecipient =  objNameSpace.CreateRecipient("Autre@boite.com")
 
 For Each objCategory In ??????????.Categories '  <objRecipient.Categories> ne marche pas et donne les catégories de la boîte issue de <objNameSpace.Categories>
    MsgBox objCategory.Name
 Next
 
End Sub

Merci pour votre aide.

[Oliv-]

Bonjour,

Si les bal sont paramétrées dans ton Outlook

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Private Sub EnumerateCategoriesForStores()
    Dim oStores As Outlook.Stores
    Dim oStore As Outlook.Store
    Dim oCategories As Outlook.Categories
    Dim oCategory As Outlook.Category
    Set oStores = Application.Session.Stores
 
    If MsgBox("Afficher uniquement le store par défaut ?", vbYesNo) = vbYes Then
 
        Set oStore = oStores.Session.DefaultStore
        Debug.Print oStore.displayName
        Debug.Print "--------------Categories-----------------"
        Set oCategories = oStore.Categories
        For Each oCategory In oCategories
            Debug.Print Chr(9) & oCategory.Name & vbTab & oCategory.color
        Next
        Debug.Print ""
    Else
        For Each oStore In oStores
            Debug.Print oStore.displayName
            Debug.Print "--------------Categories-----------------"
            Set oCategories = oStore.Categories
            For Each oCategory In oCategories
                Debug.Print Chr(9) & oCategory.Name & vbTab & oCategory.color
            Next
            Debug.Print ""
        Next
    End If
    MsgBox "le résultat est dans le fenêtre 'Exécution' de vbe"
End Sub

[DPhBxl]

Du retard pour mes remerciements, c'est vrai…
Solution très réussie.
Merci beaucoup Oliv.