Discussion :

[gefriche]

Pour une association, je dispose d'un classeur de plusieurs onglets qui regroupent, pour chaque onglet (U7, U9, U11, U13, U15, U17, U19, senior, Dirigeants et bénévoles, staffs), les informations (nom, prénom, téléphone, e-mail, date de naissance, notamment) des personnes présentes dans l'onglet.

Je souhaite modifier la macro ci-dessous, qui fournit, sur une ou plusieurs lignes, le résultat, à l'intérieur d'une MsgBox, avec le nom de l'onglet et l'adresse de la cellule.

Cela fonctionne très bien. Cependant il faut ensuite se rendre sur l'onglet et l'adresse pour voir les renseignements utiles ce qui compte tenu du nombre d'articles trouvés peut être fastidieux.

Je souhaiterais, si cela est possible, atteindre la première occurrence pour noter le ou les éléments utiles présents sur la ligne, puis atteindre la seconde occurrence, etc... OU faire cette même recherche depuis un onglet nommé "Recherche" et recevoir dans cet onglet, la copie de la ou des lignes des différents onglets concernés par la valeur recherchée.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Sub Recherche()
Dim MaRecherche
Dim Ws As Worksheet
Dim c As Range
Dim Message As String, firstAddress As String, trouve As String
    MaRecherche = InputBox("Saisir la valeur à rechercher", "Recherche")
    Message = "La valeur " & MaRecherche & " a été trouvée :" & Chr(10)
        For Each Ws In Worksheets
        With Ws
            Set c = .Columns("A:Z").Find(What:=MaRecherche, LookIn:=xlValues, LookAt:=xlPart)
                If Not c Is Nothing Then
                firstAddress = c.Address
                  Do
                    Message = Message & "- dans la feuille " & Ws.Name & ", cellule " & c.Address & Chr(10)
                    Set c = .Columns("A:Z").FindNext(c)
                Loop While Not c Is Nothing And c.Address <> firstAddress
            End If
        End With
    Next Ws
    MsgBox Message
End Sub

Par avance Merci !

[njhub]

Bonjour gefriche,

Voyez si la solution, sans macro, proposée dans le fichier joint vous convient

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=INDIRECT(ADRESSE(PETITE.VALEUR($U7.$A:$A;1);COLONNE();4;1;$A3);1)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=INDIRECT(ADRESSE(PETITE.VALEUR($U9.$A:$A;1);COLONNE();4;1;$A4);1)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(ESTERREUR(TROUVE($Recherche.A$1;B3));"";LIGNE())

Etc..

gefriche.xlsx

[gefriche]

Merci pour votre réponse. Cependant, comme cette base de données est destinée à être partagée entre dirigeants qui disposent de niveaux très différents en matière d'utilisation des outils informatiques, il est préférable d'utiliser une feuille vierge.

En conséquence, je recherche plutôt une macro transparente pour les utilisateurs qui après avoir cliqué sur un bouton et saisi l'objet de leur recherche, la visualise immédiatement. Un bouton RaZ venant éventuellement compléter la fin avant une nouvelle recherche.

Merci.

[Zekraoui_Jakani]

Avec une feuille "Recherche" contenant impérativement les titres "Feuille, Nom, Prénom, Tel, eMail, Cellule" commençant en A2:

Utiliser ce code (vous devez prévoir le cas où le texte recherché n'existe pas!"):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
Sub Recherche()
 
    Dim MaRecherche
    Dim Ws As Worksheet
    Dim c As Range
    Dim Message As String, firstAddress As String, trouve As String
 
    MaRecherche = InputBox("Saisir la valeur à rechercher", "Recherche")   'Je suppose que la recherche se fait que sur le NOM uniquement !!
    Sheets("Recherche").Cells(1, 1) = UCase(MaRecherche)
    Message = "La valeur " & MaRecherche & " a été trouvée :" & Chr(10) & Chr(10)
 
    Sheets("Recherche").Range("A3:G1000").ClearContents
 
    For Each Ws In Worksheets
        If Not Ws.Name Like "Recherche" Then
            With Ws
                Set c = .Columns("A:A").Find(What:=MaRecherche, LookIn:=xlValues, LookAt:=xlPart)
                    If Not c Is Nothing Then
                    firstAddress = c.Address
                      Do
                        Message = Message & "- dans la feuille " & Ws.Name & ", cellule " & c.Address & Chr(10)
                        With Sheets("Recherche")
                            .Cells(Rows.Count, 1).End(xlUp).Offset(1, 0) = Ws.Name
                            .Cells(Rows.Count, 2).End(xlUp).Offset(1, 0) = c.Value  'nom
                            .Cells(Rows.Count, 3).End(xlUp).Offset(1, 0) = c.Offset(0, 1).Value 'prénom
                            .Cells(Rows.Count, 4).End(xlUp).Offset(1, 0) = c.Offset(0, 2).Value 'Tel
                            .Cells(Rows.Count, 5).End(xlUp).Offset(1, 0) = c.Offset(0, 3).Value 'eMail
                            .Cells(Rows.Count, 6).End(xlUp).Offset(1, 0) = c.Offset(0, 4).Value 'Dt naissance
                            .Cells(Rows.Count, 7).End(xlUp).Offset(1, 0) = c.Address
                        End With
                        Set c = .Columns("A:A").FindNext(c)
                        Loop While Not c Is Nothing And c.Address <> firstAddress
                    End If
            End With
        End If
    Next Ws
 
    MsgBox Message & vbLf & vbLf & "Voir plus de détails sur la feuille 'Recherche'", vbInformation + vbOKOnly, "Résultat de la recherche"
    DoEvents
    Sheets("Recherche").Select: Range("A1").Select
 
End Sub

[Igloobel]

Bonjour à tous

... Cependant, comme cette base de données est destinée à être partagée entre dirigeants qui disposent de niveaux très différents en matière d'utilisation des outils informatiques, il est préférable d'utiliser une feuille vierge...

Je pense qu'un simple tableau croisé dynamique (TCD) suffit

Et du coup l'utilisation devient plus simple pour tous