Discussion :

[taz devil]

Bonjour
je voudrais decompresser un fichier zip sans avoir a installer les logiciels winzip etc.... j ai vu sur le faq une réponse mais aucun dll ne marche

https://access.developpez.com/faq/?page=ActionsRep#zip

Le code à écrire en VB pour la manipuler étant assez conséquent, nous allons aussi importer les classes VB d'Andrew McMillan disponibles dans les fichiers zipclass.zip et ZipExtractionClass.zip (la zlib est aussi dans ces zips).

c est 2 liens ne marche plus



merci

[Invité]

bonsoir,

à tester :

Code VBA :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
 
Public Function UnzipTo(ByVal zipFile As String, ByVal unzipPath As String) As Boolean
    On Error GoTo catch
    Dim oShell As Object, bExist As Boolean, sErr As String
 
    If zipFile <> vbNullString And Right$(zipFile, 1) <> "\" Then bExist = (Dir(zipFile) <> vbNullString)
    If Not bExist Then
        sErr = "le fichier '" & zipFile & "' est introuvable..."
    ElseIf unzipPath <> vbNullString And _
           Dir(unzipPath & "\", vbDirectory) <> vbNullString Then
        Set oShell = CreateObject("Shell.Application")
        oShell.Namespace(CVar(unzipPath)).CopyHere oShell.Namespace(CVar(zipFile)).items
        UnzipTo = True
    Else
        sErr = "Le répertoire '" & unzipPath & "' n'existe pas..."
    End If
fin:
    If Not oShell Is Nothing Then Set oShell = Nothing
    If UnzipTo Then
        MsgBox "Décompression réussie du fichier '" & zipFile & _
               "' dans le répertoire '" & unzipPath & "'", vbInformation, "UnzipTo"
    Else
        MsgBox sErr, vbExclamation, "UnzipTo"
    End If
    Exit Function
catch:
    sErr = "Une erreur s'est produite..." & vbCrLf & "Erreur n°" & Err.Number & vbCrLf & "Description" & Err.Description
    Resume fin
End Function

Exemple d'utilisation : UnzipTo("c:\Doc\monzip.zip","c:\Doc\tmp\")

[taz devil]

salut galoir

[Invité]

Dans vbe, menu debogage -> compiler