Discussion :

[jeron]

Bonjour à tous,

je souhaite faire un script qui m'alerte par mail si plus de deux switch ont perdu la connexion. J'ai trouvé plusieurs code sur le net afin d'en faire un et je bloque à un endroit : lancer le script powershell script_envoimail.ps1 si le fichier resultat_des_pings.txt contient deux lignes avec "NE REPOND PAS"

Merci d'avance pour votre aide

Bonne fin de journée.

Jeron

==============================================

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
@echo off
Title PING VERS SWITCHS
 mode con cols=90 lines=8 & color 9B
@echo ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»
@echo º TEST PING EN COURS ... º
@echo ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍͼ
 
rem parametrage de l'endroit ou se trouve la liste des addresses ip des switchs
    set nomswitch=ip.txt
 
rem parametrage du fichier de resultat
    set result="resultat des pings.txt"
 
rem purge du fichier résultat
If exist %result% Del %result%
 
Setlocal EnableDelayedExpansion
 
rem  ping avec option -n 1 pour ne pinguer qu'une fois
 
for /f "delims=" %%i in (%nomswitch%) do    (  
    ping %%i -n 1 | FIND "TTL=" > nul
    if errorlevel 1 ( echo %%i NE REPOND PAS >> %result%
    ) else (
        echo %%i repond correctement >> %result%
    )
)
endlocal
 
@echo off
cls
@echo ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»
@echo º      FIN DE SCRIPT     º
@echo ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍͼ
timeout /t 5
 
Powershell.exe -executionpolicy remotesigned -File "script_envoimail.ps1"

[ericlm128]

J'éviterai de passer par un fichier intermédiaire (sauf si nécessaire on verra alors)

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
@echo off
Title PING VERS SWITCHS
 mode con cols=90 lines=8 & color 9B
@echo ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»
@echo º TEST PING EN COURS ... º
@echo ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍͼ
 
rem parametrage de l'endroit ou se trouve la liste des addresses ip des switchs
set nomswitch=ip.txt
 
set /a counterror=0
for /f "delims=" %%i in (%nomswitch%) do ping %%i -n 1 >nul||set /a counterror+=1
 
@echo off
cls
@echo ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»
@echo º      FIN DE SCRIPT     º
@echo ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍͼ
timeout /t 5
 
if %counterror% GEQ 2 Powershell.exe -executionpolicy remotesigned -File "script_envoimail.ps1"

[jeron]

Bonjour ericlm128,

merci pour votre retour rapide. C'est ce que je souhaitais, cependant, je voudrai que si deux switchs ne répondent pas, extraire le résultat des IP qui ne répondent pas dans erreur.txt.

Merci d'avance pour votre aide.

[ericlm128]

Ok

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
@echo off
Title PING VERS SWITCHS
 mode con cols=90 lines=8 & color 9B
@echo ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»
@echo º TEST PING EN COURS ... º
@echo ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍͼ
 
rem parametrage de l'endroit ou se trouve la liste des addresses ip des switchs
set nomswitch=ip.txt
set errorping="ErreurPing.txt"
set /a counterror=0
 
If exist %errorping% Del %errorping%
 
for /f "delims=" %%i in (%nomswitch%) do ping %%i -n 1 >nul||(set /a counterror+=1&echo %%i>>%errorping%)
 
@echo off
cls
@echo ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»
@echo º      FIN DE SCRIPT     º
@echo ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍͼ
timeout /t 5
 
if %counterror% GEQ 2 Powershell.exe -executionpolicy remotesigned -File "script_envoimail.ps1"

[jeron]

Bonjour,

merci beaucoup pour votre aide c'est exactement ça

Je mets en résolu la discussion.