Discussion :

[PLH81]

Bonjour,

Un tableau structuré est nommé Txl_TabStruct (c'est pour l'exemple hein...) avec trois colonnes ayant pour entête Nom, Prénom, Âge

Y a t-il moyen de faire quelque chose du genre :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
 
Sub Ecrire_dans_le_Txl()
 
dim n as integer
 
n = 3
with [Txl_TabStruct]
          .cells(n,[@Nom]) = "Tartagueu"
end with
 
n=5
with [Txl_TabStruct]
        .cells(n,[@Prénom]) = "Alain"
End sub

Bref, aller à une cellule précise en nommant l'entête de la colonne.

Merci.

PLH81

[Philippe Tulliez]

Bonjour,
Exemple de l'écriture sur la ligne 3 de la colonne dont l'en-tête est "Client" du tableau de la feuille active (ici le tableau est seul)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub t()
  Dim oList As ListObject
  Set oList = ActiveSheet.ListObjects(1)
  With oList
  .DataBodyRange.Cells(3, .ListColumns("Client").Index).Value = "Ma Petite Entreprise"
  End With
  Set oList = Nothing
End Sub

[PLH81]

Bonsoir Mr Tulliez,

Alors ça, je vais le graver en rouge et noir.

Question subsidiare :
J'ai vu qu'il n'était pas nécessaire de déclarer le tableau structurée en ListObject
Qu'en pensez-vous ?

PLH81

[Patrice740]

Bonjour,

J'ai vu qu'il n'était pas nécessaire de déclarer le tableau structurée en ListObject

C'est pas qu'il n'est pas nécessaire de déclarer le tableau, c'est qu'on peut référencer le tableau structuré directement par son nom, c'est à dire qu'on peut remplacer

Code VBA :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Set Tableau = ThisWorkbook.Worksheets("Base").ListObjects("Base_donnees").Range
With Tableau
...

Par

Code VBA :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
With [Base_donnees]
...

[PLH81]

Bonjour Patrice,

ok. De directement appeler par les [ ] simplifie le codage, mais ensuite, est ce qu'on peut faire exactement les mêmes choses, y a-t-il des restrictions ou des inconvénients à déclarer ainsi [ ] ?

Cordialement

PLH81

[Philippe Tulliez]

Bonjour,

est ce qu'on peut faire exactement les mêmes choses, y a-t-il des restrictions ou des inconvénients à déclarer ainsi [ ] ?

Aucune restriction. Lorsque l'on déclare une variable objet (Workbook, Worksheet, Range, ListObject, PivotTable, etc.), celle-ci hérite des méthodes et des propriétés de cet objet.

[EDIT]
Donc dans cet exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Dim oList As ListObject
Set oList = shtDb.ListObjects(1)
oList.Name = "MonTableau"

L'instruction de la dernière ligne donne le même résultat que

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

shtDb.ListObjects(1).Name = "MonTableau"

[PLH81]

ok.

Par contre, ceci ne fonctionne pas :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
[MonTableau].name = "MonReTableau"

C'est cela que je ne comprends pas.
Est ce que [MonTableau] est considéré comme un listObject ? Parce que si oui, alors il devrait hériter des méthodes et propriétés de cet objet ?

PLH81

[Philippe Tulliez]

Bonjour,

Est ce que [MonTableau] est considéré comme un listObject ? Parce que si oui, alors il devrait hériter des méthodes et propriétés de cet objet ?

Pourquoi veux-tu utiliser les crochets, tu es fâché avec les variables objets ?
Personnellement, je n'utilise jamais les références entre crochets

En revanche tu peux utiliser Range("MonTableau")

Exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

 MsgBox Range("MonTableau").Cells(2, 1).Value

[PLH81]

Pourquoi veux-tu utiliser les crochets...

Bâh, parce que, en tant que grosse feignasse que je suis, je trouvais plus court, pardon, plus simple (et plus claire) d'écrire :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

[MonTableau].name

que

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

shtDb.ListObjects(1).Name = "MonTableau"

Je viens de découvrir, après quelques recherches, que je m'étais royalement planté sur la signification des [].
Je croyais que c'était comme cela qu'on appelait un tableau structuré. Mais en fait, si j'ai bien compris, c'est une variable (quelle qu'elle soit) qui est appelée ainsi. Me trompe-je ?
Et que cela n'est pas forcément utile, voire même conseillé. Me retrompe-je ?


Donc, Mr Tulliez, si vous n'y voyez pas d'inconvénient, je vais suivre vos conseils.

Merci.

PLH81

[Philippe Tulliez]

Bonjour,

Plutôt que

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

shtDb.ListObjects(1).Name = "MonTableau"

J'utiliserais directement une variable typée ListObject comme ci-dessous

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Dim oList As ListObject
Set oList = shtDb.ListObjects(1)
oList.Name = "MonTableau"

Quelques exemples d'utilisation de la variable objet oList typée comme ListObject

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub Test_ObjectTable()
  Dim oList As ListObject
  Set oList = shtDb.ListObjects(1)
  oList.Range.Select          ' Sélection du tableau complet
  oList.HeaderRowRange.Select ' Sélection des en-têtes du tableau
  oList.DataBodyRange.Select  ' Sélection des données du tableau
  ' Afficher la deuxième colonne de la ligne titre
  MsgBox oList.HeaderRowRange.Cells(2).Value
  ' Ecrire dans la deuxième colonne de la ligne titre
  oList.HeaderRowRange.Cells(2).Value = "Libellé"
  ' Afficher la neuvième ligne de la colonne dont l'étiquette est "Libellé"
  With oList
    MsgBox .DataBodyRange.Cells(9, .ListColumns("Libellé").Index).Value
  End With
End Sub

Si tu dois travailler surtout sur la zone des données de la table structurée, tu pourrais utiliser une variable de type Range
Exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub Test_ObjectTable()
 Dim oList As ListObject
 Dim oRng As Range
 Dim ColumnNumber As Integer
 Set oList = shtDb.ListObjects(1)
 Set oRng = oList.DataBodyRange  '
 oRng.Select  ' Sélection des données du tableau
 ' Afficher la neuvième ligne de la colonne dont l'étiquette est "Libellé"
 ColumnNumber = oList.ListColumns("Libellé").Index
 MsgBox oRng.Cells(9, ColumnNumber).Value
End Sub

[OrDonc]

Bonjour

N’aimant pas les noms à rallonge qui souvent n'ont de sens que pour celui qui les a crées, avec le Tableau nommé Tbo tu as propositions :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub Ecrire_dans_Tblo1()
    [Tbo[Nom]].Rows(3) = "Tartagueu"
    [Tbo[PréNom]].Rows(5) = "Alain"
End Sub
'avec la possibilté des changer les titres sans influence sur ces 2 macros
Sub Ecrire_dans_Tblo2()
    [Tbo].Columns(1).Rows(3) = "Leconte"
    [Tbo].Columns(2).Rows(5) = "Adrien"
End Sub
Sub Ecrire_dans_Tblo3()
    [Tbo].Item(3, 1) = "Oups"
    [Tbo].Item(5, 2) = "Machin"
End Sub

Remarque : où qu’elles soient écrites, tu n’as pas besoin de citer la feuille de référence (celle contenant le tableau).

Pour les [ ] je ne vais pas relancer un vieux débat !

Edit :
j'aurais pu te proposer aussi

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Sub Ecrire_dans_Tblo4()
    [Tbo].Cells(3, 1) = "Truc0"
    [Tbo].Cells(5, 2) = "chose0"
End Sub

mais 4 lettres de Item, cest plus court que 5 lettres de Cells

[PLH81]

Bonjour,

Merci pour toutes vos réponses. Vous m'avez bien éclairé sur le sujet. Je pense avoir suffisamment matière à creuser maintenant tout en étant dans la bonne direction.

mais 4 lettres de Item, cest plus court que 5 lettres de Cells

Certes, je suis feignasse, mais quand même...

PLH81