Discussion :

[Halcodeur]

Bonjour,

Je n'ai pas l'habitude d'utiliser QtQuick, je le fais un peu par obligation car je dois utiliser une carte pour mon programme.
Je cherche à afficher des éléments dessus (des icônes), qui bougeront au fur et à mesure du temps.
J'ai suivi le tutoriel de Qt pour afficher un cercle vert (on verra les images après), mais rien ne s'affiche... Voici mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
import QtQuick 2.0
import QtQuick.Window 2.0
import QtLocation 5.6
import QtPositioning 5.6
 
Window {
    width: 1024
    height: 1024
    visible: true
 
    Plugin {
        id: mapPlugin
        name: "osm"
    }
 
    PositionSource {
        id: positionSource
    }
 
    Map {
        id: map
        anchors.fill: parent
        plugin: mapPlugin
        center: QtPositioning.coordinate(47.08, 2.40)
        zoomLevel: 6.5
 
        property MapCircle circle
 
        Component.onCompleted: {
            circle = Qt.createQmlObject('import QtLocation 5.3; MapCircle {}', page)
            circle.center = positionSource.position.coordinate
            circle.radius = 5000.0
            circle.color = green
            circle.border.width = 10
            map.addMapItem(circle)
        }
    }
}

Merci beaucoup d'avance
Cordialement

[baliloo]

Bonsoir, je crois que tu dois utiliser un MapItemView sur lequel tu va afficher les icons soit manuellement soit a partir d'un modele.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
 
import QtQuick 2.11
import QtQuick.Controls 2.4
import QtPositioning 5.8
import QtLocation 5.9
 
Item {
    width: 400
    height: 400
 
    ListModel {
        id: locationModel
        ListElement {lat: 36.688089; lon: 3.034564; color: "orange"; radius:600}
        ListElement {lat: 36.692111; lon: 3.028278; color: "green"; radius:400}
        ListElement {lat: 36.693239; lon: 3.029731; color: "orange"; radius:500}
        ListElement {lat: 36.693444; lon: 3.029972; color: "red"; radius:300}
        ListElement {lat: 36.693472; lon: 3.042250; color: "green"; radius:200}
        ListElement {lat: 36.691561; lon: 3.043039; color: "orange"; radius:450}
        ListElement {lat: 36.691250; lon: 3.042861; color: "red"; radius:200}
    }
 
    Plugin {
        id: mapPlugin
        name: "osm" // "mapboxgl" "osm" , "esri", ...
    }
 
 
    Map {
        anchors.fill: parent
        plugin: mapPlugin
        center: QtPositioning.coordinate(36.00000, 3.00000)
        zoomLevel: 14
 
        MapItemView {
            model: locationModel
 
            delegate: MapCircle {
                center: QtPositioning.coordinate(lat, lon) // lat et lon depuis le modele
                radius: model.radius
                opacity: 0.35
                color: model.color
                border.color: model.color
            }
        }
 
        MapItemView {
            model: locationModel
 
            delegate: MapQuickItem {
                coordinate: QtPositioning.coordinate(lat, lon)
                anchorPoint: Qt.point(10,30) // les coordonnées locale de l'icon a centées sur les coordonnées géographique
 
                sourceItem: Image {
                    source: "qrc:/images/images/marker.png"
                    height: 30
                    width: 20
                }
            }
        }
    }
}

Je suis aussi débutant en Qt Quick et QML mais j'espère que ça va vous aider a trouvé une solution a votre probleme