Discussion :

[patmicro]

Bonsoir à tous les lecteurs : Dans des fonctions Excel 2016 , Comment faire apparaitre le descriptif de chaque argument ? J'ai regardé dans l'explorateur d'objets et dans les propriétés de la fonction mais je n'ait rien trouvé qui correspond à ma recherche. J'aimerai que lorsque l'on click sur chaque argument il apparaisse le descriptif en face de l'argument comme les fonctions installées dans office.
Voir copie d'écran ci-joint (exemple d'une fonction) (En jaune descriptif de l'argument qui devrait s'afficher)
Par avance merci pour votre aide. :

[clementmarcotte]

Bonjour,

Une petite recherche: https://www.developpez.net/forums/d1.../#post10670598

[patmicro]

Bonjour : Merci pour votre participation. J'ai un peut compris les informations décrites dans les 2 liens fournis. Malheureusement je ne maitrise pas tout en matière de VBA et ne parle pas du tout l'Anglais.

A quel endroit doit je ajouter le ou les codes

Pourriez vous m'aider sur un simple code connu de tout le monde comme exemple (Calcul TTC que je voudrais placer par exemple en Finances (ce n'est pas la catégorie qui conviens mais c'est pour l'exemple)

Voici le code de ma macro

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
 
Function TTC(montant_HT As Single, Taux_TVA As Single) As Double
 
'Calcul du montant TTC
TTC = montant_HT * (1 + Taux_TVA)         'Taux de TVA au format % Cellule au format %
'TTC = montant_HT * (1 + Taux_TVA / 100)  'Taux de TVA au format standard Cellule au format standard
End Function

Par exemple à quel endroit doit je placer ce code ? si j'ai bien compris c'est pour classer la fonction dans un catégorie

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Application.MacroOptions Macro:="NomFonction", _
    Description:="La description pour ma fonction personnalisée.", Category:=5

L'autre code c'est pour le descriptif des arguments comme sur la copie d'écran souligné en jaune.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
 
Public Sub AjouterDescription()
 
    With Application
 
        Dim ArgumentDescription() As String
        ArgumentDescription(0) = "Argument 1"
        ArgumentDescription(1) = "Argument 2"
        '...
 
        'Pour avoir l'ensemble des éléments Utiliser l'aide et chercher MarcoOptions
        .MacroOptions "NomFonction", "Description", , , , , , , , , ArgumentDescriptions
 
    End With
 
End Sub

Pourriez vous m'aider à remettre les 2 codes dans leur contexte afin d'y voir plus clair pour l'exemple cité "Calcul du montant TTC"

Par avance je vous remercie.

[John Mc Evee]

Salut,

En réponse à ta question voici une proposition :

Pour activer la méthode MacroOptions, tu peux la placer dans un évènement Workbook_Open(). A chaque fois que tu ouvrira le classeur où se trouve ta fonction tu chargera tes éléments de description. L'inconvénient c'est que cette fonction est associé à un classeur. Si tu souhaite l'avoir à disposition pour plusieurs classeurs je te conseils de t'orienter vers un format .xlam et activer le complément via les options (Une petite recherche sur Google suffira).

Voici le code à placer dans l'objet ThisWorkbook

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Private Sub Workbook_Open()
 
    ReDim Arguments(1) As String
    'Saisir le libéllé de tes arguments
    Arguments(0) = "Sélectionner la cellule du montant HT"
    Arguments(1) = "Sélectionner la cellule du taux de TVA"
 
    With Application
 
        .MacroOptions Macro:="TTC", _
                      Description:="Calcul le TTC d'un montant HT", _
                      ArgumentDescriptions:=Arguments
    End With
 
End Sub

et voici le code de ta fonction qui gère à la fois les % et les nombres pour le Taux de TVA. J'y est rajouté une structure de commentaire utile si tu dois retravailler tes codes quelques temps après.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Option Explicit
'**************************************************************************************************
' NAME : TTC (FUNCTION)
' INPUT : montant_HT (single), Taux_TVA (single)
' OUTPUT : TTC (double)
' DESCRIPTION : Calcul le montant TTC
'**************************************************************************************************
Public Function TTC(montant_HT As Single, Taux_TVA As Single) As Double
 
    Select Case Taux_TVA
 
    Case Is < 1 'Taux de TVA au format % Cellule au format %
        TTC = montant_HT * (1 + Taux_TVA)
    Case Else  'Taux de TVA au format standard Cellule au format standard
        TTC = montant_HT * (1 + Taux_TVA / 100)
 
    End Select
 
End Function

Il te suffit d'enregistrer et fermer le classeur puis l'ouvrir et il y aura toutes tes infos dans l'assistant de saisie de la formule. Pour l'aide de la barre je n'ai pas trouver. Si quelqu'un sait comment le paramétrer ?

A+

[patmicro]

Bonjour : Un grand merci pour ton aide. J'eu un peut de mal à mettre en œuvre car je pense qu'il faut en premier tester en xlsm puis enregistrer ensuite en xlam. Tout fonctionne parfaitement.
Par contre je ne comprend pas pourquoi lorsque je veut activer le complément il s'affiche "Calcul du Ttc" alors que je voudrais "Calcul du TTC" TTC en majuscules. Voir copie d'écran.