Discussion :

[ziisman]

Bonjour à tous !

Je reviens vers vous car j'ai besoin d'aide sur un problème qui je pense est tout bête...

Lorsqu'on rempli le champ du CP dans mon Userform (textbox6) à la saisie de la 6ième valeur, la combobox1 se rempli des villes qui correspondent au CP saisi. Le problème c'est que quand le CP commence par un 0 (exemple 09320), le additem ne fonctionne pas car ne prend visiblement pas en compte le premier 0.

Dans mon code j'ai essayé de remplacer TextBox6.Text par TextBox6.Value mais le problème persiste.

En sachant que mes cellules sont en format CP dans la base_communes donc au format "00000" comme dans mon VBA d'où mon incompréhension

Est-ce que l'un d'entre vous a une idée ?

Voici mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Private Sub TextBox6_Change()
    If Not IsNumeric(TextBox6) Then
    MsgBox "Merci de noter le Code Postal au format 00000.", vbOKOnly + vbCritical, "Erreur de format"
    Exit Sub
    End If
    Application.ScreenUpdating = False
    If TextBox6.Text = Format(TextBox6.Text, "00000") Then
    ComboBox1.Clear
    Dim I As Long
    With Sheets("base_communes")
    For I = 1 To .Range("C" & Rows.Count).End(xlUp).Row
        If .Range("C" & I) = TextBox6.Text Then
            UserForm1.ComboBox1.AddItem .Range("F" & I).Value
        End If
        Next I
    End With
    Application.ScreenUpdating = True
    End If
End Sub

[Theze]

Bonjour,

Une piste mais sans message demandant la saisie du code postal sous la forme "00000", tout le monde sait qu'un CP en France métropolitaine comporte 5 chiffres. Sitôt qu'une valeur est trouvée et entrée dans le ComboBox, sa liste se déroule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
 
Private Sub TextBox6_Change()
 
    Dim PlgCP As Range
    Dim Cel As Range
    Dim Adr As String
 
    ComboBox1.Clear
 
    'commence la recherche seulement à partir de 5 chiffres
    If Len(TextBox6.Text) < 5 Then Exit Sub
 
    'plage de recherche sur la colonne C
    With Worksheets("base_communes"): Set PlgCP = .Range(.Cells(2, 3), .Cells(.Rows.Count, 3).End(xlUp)): End With
 
    'recherche
    Set Cel = PlgCP.Find(TextBox6.Text, , xlValues, xlWhole)
 
    'si trouvé, boucle...
    If Not Cel Is Nothing Then
 
        Adr = Cel.Address
 
        Do
 
            'popule en récupérant les agglomérations en colonne F
            ComboBox1.AddItem Cel.Offset(, 3).Value
            Set Cel = PlgCP.FindNext(Cel)
 
        Loop While Cel.Address <> Adr
 
        'ouvre la liste
        ComboBox1.DropDown
 
    End If
 
End Sub
 
'seulement numérique
Private Sub TextBox6_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
 
    Select Case KeyCode
 
        Case 96 To 105
        Case Else: KeyCode = 0
 
    End Select
 
End Sub

[ziisman]

Le code fonctionne parfaitement c'est top !

Juste à mettre un clear si aucune valeur n'est sélectionnée, j'ai essayé de mettre par exemple 860000 et impossible d'effacer un caractère...

Mais merci vraiment ça marche au poil !

J'ai quand même gardé mon code, car j'ai été un peu plus loin pour voir la valeur cherchée par mon formulaire, je cherchais "09320" mais dans ma base, la valeur était 9320 au format CP donc ça risquait malheureusement pas de fonctionner... J'ai alors mis un = 0 & "Cellule" pour ajouter le 0 à toutes les valeurs entre 01000 et 09999 et miracle !

[Theze]

Re,

Tu autorises les touches Suppr et <-- :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
Private Sub TextBox6_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
 
    Select Case KeyCode
 
        Case 96 To 105, 8, 46
        Case Else: KeyCode = 0
 
    End Select
 
End Sub