Discussion :

[Nicalb]

Bonjour,
J'essaie simplement de tracer une courbe (x,y)
Lorsque les deux colonnes sont jointes : pas de Pb
lorsque les deux colonnes sont disjointes => erreur d'execution'1004' : Erreur définie par l'application ou par l'objet
à la ligne "ActiveSheet.Shapes.AddChart.Select" et même en supprimant la ligne précédente "Range("C1").Activate"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub Macro1()
'' Macro1 Macro
'
    Range("A1:B13").Select
    ActiveSheet.Shapes.AddChart.Select
    ActiveChart.ChartType = xlXYScatterLinesNoMarkers
    ActiveChart.SetSourceData Source:=Range("Feuil1!$A$1:$B$13")
    
    Range("A1:A13,C1:C13").Select
    Range("C1").Activate
    ActiveSheet.Shapes.AddChart.Select
    ActiveChart.ChartType = xlXYScatterLinesNoMarkers
    ActiveChart.SetSourceData Source:=Range("Feuil1!$A$1:$A$13;Feuil1!$C$1:$C$13")
End Sub

Quelqu'un à une solution ?

Merci

[halaster08]

Bonjour,

Essaye:

ActiveChart.SetSourceData Source:=Range("Feuil1!$A$1:$A$13 , Feuil1!$C$1:$C$13")

même en supprimant la ligne précédente "Range("C1").Activate"

A quoi te sert cette ligne ?
Si la réponse est à rien que fait-elle dans ton code ?

[Menhir]

A quoi te sert cette ligne ?
Si la réponse est à rien que fait-elle dans ton code ?

Je suis prêt à miser une pièce sur une réponse du style : "c'est l'enregistreur de macro qui l'a placée là et je ne me suis pas demandé pourquoi".
(vu que le code ressemble furieusement au résultat brut de ce que fait l'enregistreur)

[Nicalb]

Merci, mais j'ai toujours le Pb,
de la ligne 1 à 9 tout est OK,
A la ligne 9 les cases A1:A13 et C1:C13 sont bien sélectionnées mais à la ligne 10 ça se plante avec le message "erreur d'execution'1004' : Erreur définie par l'application ou par l'objet"

Effectivement la ligne "Range("C1").Activate" ne servait à rien

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub essai()

'' Essai Macro
'    Range("A1:B13").Select
    ActiveSheet.Shapes.AddChart.Select
    ActiveChart.ChartType = xlXYScatterLinesNoMarkers
    ActiveChart.SetSourceData Source:=Range("Feuil1!$A$1:$B$13")
    
    Range("A1:A13,C1:C13").Select
    ActiveSheet.Shapes.AddChart.Select
    ActiveChart.ChartType = xlXYScatterLinesNoMarkers
    ActiveChart.SetSourceData Source:=Range("Feuil1!$A$1:$A$13,Feuil1!$C$1:$C$13")

End Sub

Nota : La remarque de Menhir est très pertinente mais pas très constructive

[halaster08]

Merci, mais j'ai toujours le Pb
[...]
Nota : La remarque de Menhir est très pertinente mais pas très constructive

Désolé je n'avais pas vu que tu avais indiqué où se trouve le problème, j'en avais vu un plus loin mais pas le premier.

Au contraire la remarque de Menhir est tout a fait constructive, l'enregistreur de macro c'est très bien mais il ajoute des lignes inutiles voir parfois sources d'erreur, c'est ton cas ici.
La plupart des select sont inutile en VBA, le fait de sélectionner ta source avant de faire le graphe est inutile puis que tu la reprécise plus tard donc ceci:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
    ActiveSheet.Shapes.AddChart.Select
    ActiveChart.ChartType = xlXYScatterLinesNoMarkers
    ActiveChart.SetSourceData Source:=Range("Feuil1!$A$1:$A$13,Feuil1!$C$1:$C$13")

suffit à créer ton graphe, et ne génère pas d'erreur

[pijaku]

Bonjour à tous,

Sans vouloir défendre l'auteur du sujet, même l'exemple de la méthode AddChart de l'aide VBA sélectionne la plage avant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Range("A10:B14").Select
    ActiveSheet.Shapes.AddChart.Select
    ActiveChart.SetSourceData Source:=Range("Sheet1!$A$10:$B$14"), PlotBy:= _
        xlColumns
    ActiveChart.ChartType = xlCylinderColStacked

Cela dit, une variante du code d'Halaster08, avec les objets déclarés et le positionnement du second sous le premier, donne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Option Explicit
 
Sub essai()
Dim Sh As Shape, Chrt As Chart, WshSource As Worksheet, RngSource As Range
Dim Top As Long, Left As Long, Height As Long
 
   Set WshSource = Worksheets("Feuil1")
   With ActiveSheet
      'premier
      Set Sh = .Shapes.AddChart(xlXYScatterLinesNoMarkers)
      With Sh
         Set Chrt = .Chart
         Top = .Top + 5
         Left = .Left
         Height = .Height
      End With
      Set RngSource = WshSource.Range("$A$1:$B$13")
      Chrt.SetSourceData Source:=RngSource
 
      'second
      Set Sh = .Shapes.AddChart(xlXYScatterLinesNoMarkers, Left, Height + Top)
      Set Chrt = Sh.Chart
      Set RngSource = WshSource.Range("$A$1:$A$13,$C$1:$C$13")
      Chrt.SetSourceData Source:=RngSource
   End With
   Set Sh = Nothing
   Set Chrt = Nothing
   Set WshSource = Nothing
   Set RngSource = Nothing
End Sub

[Nicalb]

Merci beaucoup,
ça marche

pas évident de trouver quand on est pas expert et que l'on développe des macros ponctuellement

Cordialment