Discussion :

[triope]

Bonjour à tous,

Voilà je travaille sur EXCEL 2013 , j'ai un fichier qui comporte un TCD par onglet (8 onglets donc 8 TCD). Ce que je souhaite obtenir c'est le même fichier avec les données mais plus de lien TCD avec une simple manip.

La raison : je dois fournir à chaque utilisateur les données qui le concerne (filtre préalable dans les TCD)sans qu'il ne puisse accéder aux données des autres.

Vœu pieux : trouver une méthode qui me permette de garder le format de mes différents tableaux mais couper le lien avec la source , pour le moment je n'ai rien trouvé de mieux qu'un simple copier coller valeurs . Le souci c'est que je perds le format et les fonctions de somme des TCD et j'ai surtout plus de 130 utilisateurs.....

Merci pour votre aide

[catapoulpe]

Bonjour

Dans le genre bricolage... Si les tableaux ont tous exactement la même structure (nombre de lignes, de colonnes...), tu peux mettre en forme une zone dans laquelle tu viendras coller tes valeurs.

Sinon, au lieu de copier le tcd, tu copies les valeurs du tableau source, filtrées pour n'avoir que celles qui concernent l'utilisateur. Copier ces valeurs dans un nouveau tableau, et créer le tcd utilisateur à partir du tableau.

Édit : euh pour la pratique regarde plutôt la proposition de 78chris ci-dessous !

[78chris]

Bonjour à tous

Depuis un TCD filtré, en double cliquant sur le total général tu générez un tableau des données sources correspondantes.

Reste à changer la source du TCD pour ce tableau puis exporter les deux onglets dans un classeur pour l'utilisateur..

Automatisable par VBA.

[triope]

Merci merci merci beaucoup pour cette solution qui fonctionne parfaitement.

Par contre je ne suis vraiment pas doué question VBA, et utiliser cette solution sans mécanisation vu le nombre d'onglets et de fichiers c'est juste colossale....donc je suis preneur de toutes aides pouvant m'aider à transcrire cette manip en VBA.

[78chris]

Bonjour

Si le champ filtré est en zone page du TCD, et tous les TCD concernés code à adapter (suppose 1 seul TCD par page)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Sub export()
Dim Chemin As String, Champ As String, Nom As String
Dim TBas As Long, TDroite As Integer
Dim WS As Worksheet, WS2 As Worksheet

    Chemin = "t:\Temp\" ' A adapter
    Champ = "Produit" 'A adapter
    
    For Each WS In ThisWorkbook.Worksheets
    If Not WS.PivotTables.Count = 0 Then
        WS.Activate
        With WS.PivotTables(1)
            Nom = .PivotFields(Champ).CurrentPage
            TBas = .TableRange1.Row + .TableRange1.Rows.Count - 1
            TDroite = .TableRange1.Column + .TableRange1.Columns.Count - 1
            WS.Cells(TBas, TDroite).Select
            Selection.ShowDetail = True
            Set WS2 = ActiveSheet
            WS2.Name = Nom
        End With
        ActiveWorkbook.Worksheets(Array(WS.Name, Nom)).Copy
        With ActiveWorkbook
            .Worksheets(WS.Name).PivotTables(1).SourceData = .Worksheets(Nom).ListObjects(1)
            .SaveAs Chemin & Nom
            .Close
        End With
        Application.DisplayAlerts = False
        WS2.Delete
        Application.DisplayAlerts = True
    End If
    Next WS
End Sub