Discussion :

[bambambigolo22]

Bonjour,

J'ai un combobox2, je souhaiterai qu'a l'évènemen ( change), la combobox3 affiche les valeurs conditionelles..Tout fonctionne bien. Mais quand j'ai la valeur ( 4ème Année) et combobox1 a la valeur ( ADULTE), la combobox3 affiche correctement " CONFIRMATION"...le problème survient si au prochaint évènement change de ma combobox2, sa valeur est ( 4ème Année) et que la combobox1 a pour valeur ( ENFANTS OU JEUNES), la combobox3 affiche " CONFIRMATION' au lieu de ( 5ème Année).

Quelqu'un pourrait il bien apporter une correction à mon code....

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
 
 
Private Sub ComboBox2_Change()
 
 Me.ComboBox3.Value = ""
 If ComboBox2.Value = "PréCatéchuménat" Then
       ComboBox3.Value = "1ère  Année"
       CommandButton5.Enabled = True
       CommandButton3.Enabled = False
       Exit Sub
       End If
 
       If ComboBox2.Value = "1ère  Année" Then
       ComboBox3.Value = "2ème  Année"
       CommandButton5.Enabled = True
       CommandButton3.Enabled = False
       Exit Sub
       End If
 
       If ComboBox2.Value = "2ème  Année" Then
       ComboBox3.Value = "3ème  Année"
       CommandButton5.Enabled = True
       CommandButton3.Enabled = False
       Exit Sub
       End If
 
       If ComboBox2.Value = "3ème  Année" Then
       ComboBox3.Value = "BAPTÊME"
       CommandButton3.Enabled = True
       CommandButton5.Enabled = False
       Exit Sub
       End If
 
       If ComboBox1.Value = "ENFANTS" And ComboBox2.Value = "4ème  Année" Then
       ComboBox3.Value = "5ème  Année"
        CommandButton5.Enabled = True
        CommandButton3.Enabled = False
        Exit Sub
       End If
       If ComboBox1.Value = "JEUNES" And ComboBox2.Value = "4ème  Année" Then
       ComboBox3.Value = "5ème  Année"
        CommandButton5.Enabled = True
        CommandButton3.Enabled = False
        Exit Sub
       End If
        If ComboBox2.Value = "5ème  Année" Then
       ComboBox3.Value = "CONFIRMATION"
        CommandButton3.Enabled = True
        CommandButton5.Enabled = False
        Exit Sub
       End If
       If ComboBox1.Value = "ADULTES" And ComboBox2.Value = "4ème  Année" Then
        ComboBox3.Value = "CONFIRMATION"
        CommandButton3.Enabled = True
        CommandButton5.Enabled = False
        Else
        If ComboBox2.Value = "4ème  Année" Then
       ComboBox3.Value = "5ème  Année"
        CommandButton5.Enabled = True
        CommandButton3.Enabled = False
       End If
        Exit Sub
       End If
       ComboBox3.Locked = False
End Sub

[unparia]

Bonjour
Je ne cesserai personnellement jamais de répéter le caractère assez abusif - et on en paye quelquefois le prix - de l'utilisation de l'évènement Change d'une combobox en lieu et place de l'évènement click. S'il est vrai qu'une corrélation existe entre la sélection faite et l'intitulé de la zone d'édition (seule concernée par l'évènement Change) d'une combobox, il n'en demeure pas moins vrai qu'il convient de ne pas se servir de l'effet d'une cause comme la cause elle-même. Cet évènement Change ne devrait être utilisé qu'aux fins de contrôle de saisie (en cours de saisie) de la zone d'édition de la combobox.
Quant à la détermination de l'article sélectionné, elle se fait de manière orthodoxe au clic (évènement Click) ainsi

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Combobox1.Listindex ' retourne l'index de l'article sélectionné

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Combobox1.List(combobox1.listindex) ' retourne donc la valeur de l'article sélectionné

[Pierre Fauconnier]

Salut.

D'accord avec Jacques sur le choix de l'évènement.

Pour résoudre ton problème (en ne comprenant pas bien pourquoi un combobox3 puisqu'apparemment, il ne s'agit pas d'y choisir une valeur mais simplement d'y inscrire une valeur), je te propose de sortir la logique du code, de travailler avec des tableaux structurés dans Excel et de t'appuyer dessus pour trouver la bonne valeur.

Sur click du combobox2, on recherche la bonne valeur dans le tableau grâce à la combinaison des valeurs des combobox2 et combobox1 grâce à EVALUATE qui teste un INDEX/EQUIV matriciel.

Tu vois ainsi que le code qui cherche la valeur n'imbrique pas des IF et des EXIT dans tous les sens. Si d'autres cas devaient être créés, il suffirait de compléter le(s) tableau(x) sans toucher au code (pour autant que la logique de dépendance des combo soit respectée, évidemment).



Dans un module standard

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub Test()
  With UserForm1
    .ComboBox1.List = Range("t_cb1[cb1]").Value
    .ComboBox2.List = Range("t_cb2[cb2]").Value
    .ComboBox3.List = Range("t_cb3[cb3]").Value
    .Show
  End With
  Unload UserForm1
End Sub

Dans le userform

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Private Sub ComboBox2_Click()
  Dim Value As String
 
  Value = getCb3Value()
  If Value <> "N/A" Then
    ComboBox3.Value = Value
  Else
    MsgBox "Choix impossible"
  End If
End Sub
 
Function getCb3Value()
  Dim Formula As String
  Dim Search As String
 
  Formula = "iferror(index(t_choix[cb3],match(""[search]"",t_choix[cb2] & ""-"" & t_choix[cb1],0)),""N/A"")"
  Search = ComboBox2.Value & "-" & ComboBox1.Value
  Formula = Replace(Formula, "[search]", Search, , , vbTextCompare)
  getCb3Value = Evaluate(Formula)
End Function

PS: Nomme tes contrôles. C'est beaucoup plus simple pour écrire, lire et comprendre le code...

[bambambigolo22]

Bonjour, merci à vous. Monsieur Pierre, votre proposition me convient. je l'ai testé et ça marche. Merci