Discussion :

[Passepartout007]

Bonjour,
Je souhaiterais faire un tris en ordre alphabétique avec un tableau nommé "Tableau1" et une colonne variable,
j'ai réaliser ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub TriAlphaUM()
Nomcolonne = [A1].Value
 'Met un autofiltre dans la premieres colonne, Pour la colonne concenrnée
    ThisWorkbook.Worksheets("Base de données").ListObjects("Tableau1").Sort. _
        SortFields.Clear
    ThisWorkbook.Worksheets("Base de données").ListObjects("Tableau1").Sort. _
        SortFields.Add Key:=Range("Tableau1[[#All], Nomcolonne]"), SortOn:= _
        xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
    With ThisWorkbook.Worksheets("Base de données").ListObjects("Tableau1").Sort
        .Header = xlYes
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
    End With
End Sub

Cependant la ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

SortFields.Add Key:=Range("Tableau1[[#All], Nomcolonne]"), SortOn:= _

Ne prend pas la variable Nomcolonne, j'ai bien tenté de jouer avec les " et le ) et les ] mais je n'ai pas réussi.
Avez vous des solution ?
Cordialement,
Passepartout007

[Menhir]

Cependant la ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

SortFields.Add Key:=Range("Tableau1[[#All], Nomcolonne]"), SortOn:= _

Ne prend pas la variable Nomcolonne

C'est normal puisque tu l'as mis à l'intérieur des guillemets. VBA la considère donc comme une chaine de caractère et non pas comme un nom de variable.

[Passepartout007]

Bonjour Menhir,

Je sais bien, c'est bien cela le problème j'ai essayer d'enlever les " et de les placer correctement mais je n'ai pas réussi, à tu une solution ?

Cordialement,
Passepartout007

[joe.levrai]

Bonjour,

avec un ListObject, il est préférable de l'utiliser en tant qu'objet
une colonne d'un ListObject est matérialisée par la propriété ListColum de la collection ListColumns

exemple d'une boucle sur toutes les colonnes

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub toto()
Dim MonTablo As ListObject, MaColonne As ListColumn
Set MonTablo = Feuil3.ListObjects("Tableau1")
    For Each MaColonne In MonTablo.ListColumns
        MsgBox MaColonne.Range.Address
    Next MaColonne
End Sub

exemple à adapter d'un tri variable
une procédure reçois deux arguments : le tableau où faire le tri et le nom de la colonne
et une autre procédure se charge de l'appeler ... c'est dans celle-ci qu'on peut faire une boucle
en cas de tri multiples ou de tris ascendant/descendant, il conviendra d'ajouter d'autres paramètres à la procédure pour piloter le comportement souhaité

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub toto()
Dim MonTablo As ListObject, MaColonne As ListColumn
Set MonTablo = Feuil3.ListObjects("Tableau1")
    TriColonneDefinie MonTablo, "PRIX"
End Sub
 
 
Sub TriColonneDefinie(MonTablo As ListObject, NomColonne As String)
    With MonTablo
        .Sort.SortFields.Clear
        .Sort.SortFields.Add Key:=.ListColumns(NomColonne).Range, SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        With .Sort
            .Header = xlYes
            .MatchCase = False
            .Orientation = xlTopToBottom
            .SortMethod = xlPinYin
            .Apply
        End With
    End With
End Sub

[Passepartout007]

Bonjour Joe,
merci de ta réponse grâce a toi j'ai réussi a faire ce que je voulais faire.
Voici mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
 
Public MaColonne As String
 
Public Sub TriAlpha()
Dim MonTablo As ListObject
 
With Sheets("Base de données")
Set MonTablo = .ListObjects("Base_Donnees")
End With
With MonTablo
    .Sort.SortFields.Clear
    .Sort.SortFields.Add Key:=.ListColumns(MaColonne).Range, SortOn:= _
        xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
    With .Sort
        .Header = xlYes
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
    End With
End With
End Sub

Encore merci je te met un pouce vert !

[boisgontierjacques]

Bonjour,

Une autre syntaxe (le nom d'onglet n'est pas spécifié)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Sub TriTableau1()
  ColTri = 1
  NomTableau = "Tableau1"
  Range(NomTableau).Sort Key1:=Range(NomTableau).Cells(1, ColTri), Order1:=xlAscending, Header:=xlGuess
End Sub

Boisgontier