Discussion :

[TabbHonmin]

Bonjour à tous,

J'ai creusé pas mal sur internet mais je ne trouve pas de solution qui me convienne pour ce que je souhaite faire.

J'ai un tableau excel avec une liste de numéros de téléphone. Chaque cellule peut contenir un ou deux numéros :

Exemple : 0676408490
Autre exemple : 0688143742/0564475389



Je voudrait que les numéros soit affichés comme ceci :

05 12 45 89 56
ou
05 12 45 89 56 / 05 45 78 23 56

Je n'ai pas envie d'utiliser les fonctions excel car je veux que les utilisateurs puissent entrer directement les numéros dans les cellules sans réfléchir.
D'autant qu'il y a une longue liste existante qu'il faut traiter, et j'anticipe les prochains ajouts.

Du coup, la solution qui me semble idéale est de passer par le format de cellule.
Les numéros sont sous forme de texte, donc je n'ai pas réussi avec les mise en forme du type : 00" "00" "00" "00" "00 ou autres variantes.

Merci pour votre aide.

[Pierre Fauconnier]

Salut.

Les formats Excel ne sont utilisables que pour les valeurs numériques. La mise en format TEXTE ne permet aucune fioriture.

La seule solution serait pour moi de passer par du vba après modification de la valeur de la cellule (évènement Worksheet_Change).

[EDIT]
Une fonction perso dans un module standard (parmi d'autres écritures possibles), qui omet de vérifier que la saisie initiale correspond aux attentes

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Function PhoneNumbersFormatted(Value As String) As String
  Dim Counter As Long
  Dim RetVal As String
 
  For Counter = 1 To 10 Step 2
    RetVal = RetVal & IIf(RetVal = "", "", " ") & Mid(Value, Counter, 2)
  Next Counter
  If Len(Value) > 10 Then
    For Counter = 12 To 21 Step 2
      RetVal = RetVal & IIf(RetVal = "", "", " ") & Mid(Value, Counter, 2)
    Next Counter
    RetVal = Left(RetVal, 14) & "/" & Right(RetVal, 14)
  End If
 
  PhoneNumbersFormatted = RetVal
End Function

Dans le module de la feuille

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Private Sub Worksheet_Change(ByVal Target As Range)
  On Error GoTo EndHandler
 
  If Not Intersect(Target, Range("a1:a10")) Is Nothing Then
    Application.EnableEvents = False
    Target.Value = PhoneNumbersFormatted(Target.Value)
  End If
 
EndHandler:
  Application.EnableEvents = True
End Sub

[TabbHonmin]

Merci pour cette réponse.

J'ai pondu ceci vite fait avant de voir ton code. C'est pas optimisé mais ça fonctionne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Private Sub Worksheet_Change(ByVal Target As Range)
    Dim str As String
    If Selection.Count = 1 Then
        If (Target.Column = 4 And Len(Target.Value) <> 0) Then
            If Len(Target.Value) = 10 Then
                str = Target.Value
                For i = 2 To 8
                    y = 10 - i
                    If 1 - (y Mod 2) = 1 Then
                        str = Left(str, y) & " " & Mid(str, y + 1)
                    End If
                Next i
                Target.Value = str
            ElseIf Len(Target.Value) = 21 Then
                str = Target.Value
                For i = 0 To 10
                    y = 20 - i
                    If 1 - (y Mod 2) = 0 Then
                        str = Left(str, y) & " " & Mid(str, y + 1)
                    End If
                Next i
                Target.Value = str
 
                str = Target.Value
                For i = 0 To 9
                    y = 10 - i
                    If 1 - (y Mod 2) = 1 Then
                        str = Left(str, y) & " " & Mid(str, y + 1)
                    End If
                Next i
                Target.Value = str
            End If
        End If
    End If
End Sub

[Pierre Fauconnier]

Bien. Il y a plusieurs chemins pour aller à Rome...

Cependant, je préfère ne pas mettre le traitement dans l'évènement, mais le déporter dans une fonction spécifique "qui ne fait que ça" comme je l'ai développé dans mon architecture. Si tu as d'autres traitements à réaliser sur modification dans la feuille pour d'autres plages, ton code évènementiel va vite devenir un foutoir. De plus, avec ton architecture "tout dans l'évènement", tu ne peux tester ton code que sur modif d'une cellule. En séparant les traitements, tu travailleras plus simplement sur la maintenance et l'évolution de ton code.

Sortir le traitement de l'évènement te permet aussi d'utiliser la fonction pour les données déjà encodées et que tu souhaiterais traiter de façon identique. Tu pourrais alors effectuer le traitement au sein d'une boucle qui traiterait chaque cellule d'une plage... En incluant le code de traitement directement dans l'évènement, tu vas rendre cette manip plus compliquée et lourde, voire impossible.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub UpdateCells()
  Dim rng As Range
 
  For Each rng In Range("a1:a10")
    rng.Value = PhoneNumbersFormatted(rng.Value)
  Next rng
End Sub

Attention aussi que ton code s'applique à toutes les cellules de ta feuille. Tu aurais intérêt à circonscrire le traitement à la plage dans laquelle les utilisateurs vont saisir des numéros de téléphone. Regarde comment j'ai isolé la plage grâce au test If Intersect...

Enfin, pense à désactiver tes évènements, car tu risques de boucler longtemps...