Discussion :

[arguitxu]

Bonjour,

Excel n’est vraiment pas mon quotidien et j’essaie dans un tableau de récupérer des données pour alimenter un autre petit tableau. Pour le moment le tableau n’est pas très gros et je fais les taches manuellement.
Je souhaiterai récuperer les date de création des achats, les additionner et les classer par durée. Je ne sais pas si je suis très clair dans mes explications alors je vous joins un exemple.

Feuille de départ

Dossier Création TYPE
N2456 2018-01-23 12:58:33 Achat
N6743 2018-01-19 13:20:27 Achat
N2345 2018-03-11 10:14:13 Vente
N2345 2018-02-16 10:14:13 Vente
N2345 2018-02-12 10:14:13 Vente


Feuille d’arrivée


de 0 jour à -de 5 jours de 5 jour à -de 11 jours de 11 jour à -de 16 jours de 16 jour à +de 30 jours
Achat
Vente
Total

[78chris]

Bonjour

Tes dates et tes heures sont bien reconnues en tant que telles ? Vu le format il y a un risque que cela soit considéré comme texte.

Je pense que tu confonds compter et additionner...

Dans ton exemple les numéros de dossier n'étant pas les mêmes, d'où tires-tu la durée ?

[arguitxu]

Bonjour

Tes dates et tes heures sont bien reconnues en tant que telles ? Vu le format il y a un risque que cela soit considéré comme texte.

Je pense que tu confonds compter et additionner...

Dans ton exemple les numéros de dossier n'étant pas les mêmes, d'où tires-tu la durée ?

Bonjour 78chris

les dates sont bien reconnues comme le format ci joint 2018-03-19 14:34:27 effectivement il s'agit d'additionner les dates qui sont dans dans les plages indiquées. Peux importe les numéro de dossier. L'idéee de voir les achats / ventes par plage. ex : de 0 à moins de 5 jour.

[catapoulpe]

Bonjour

Lorsque tu parles de durée, veux-tu dire intervalle de temps dans lequel s'est produit l'acte d'achat ou de vente ?
A quelle date te réfères-tu ? A une date fixe ou à la date présente ?
Donc l'intervalle "0 à -de 5 jours" signifie-t-il par exemple entre aujourd'hui le 5 avril (inclus) et le 1er avril (inclus) ?

Est-ce que tu souhaites :
compter les actes d'achat et de vente qui ont eu lieu dans chaque intervalle (0-5j ; 5-10j etc) ?
afficher dans la ligne "total" le nombre d'achats + le nombre de ventes dans l'intervalle ?

[arguitxu]

Bonjour

Lorsque tu parles de durée, veux-tu dire intervalle de temps dans lequel s'est produit l'acte d'achat ou de vente ?
A quelle date te réfères-tu ? A une date fixe ou à la date présente ?
Donc l'intervalle "0 à -de 5 jours" signifie-t-il par exemple entre aujourd'hui le 5 avril (inclus) et le 1er avril (inclus) ?

Est-ce que tu souhaites :
compter les actes d'achat et de vente qui ont eu lieu dans chaque intervalle (0-5j ; 5-10j etc) ? Absolument.
afficher dans la ligne "total" le nombre d'achats + le nombre de ventes dans l'intervalle ?

Ouf ..je me rends compte a quel point j'ai du mal a expliquer mais tu as parfaitement compris le besoin.
Je preferre me referer a une date fixe. la durée est effectivement toujours aujourd'hui. c'est bien entre aujourd'hui le 5 avril (inclus) et le 1er avril (inclus).
compter les actes d'achat et de vente qui ont eu lieu dans chaque intervalle (0-5j ; 5-10j etc) ? Absolument.
afficher dans la ligne "total" le nombre d'achats + le nombre de ventes dans l'intervalle ? Absolument

[catapoulpe]

Alors si tu te réfères toujours à la date d'aujourd'hui, ce n'est pas une date fixe, mais elle change tous les jours... c'est bien cela ?

Si tes dates sont dans la colonne B et que l'indication "achat" ou "vente" est dans la colonne C, en faisant des intervalles de cinq jour à partir de la date du jour :
voici des formules à mettre dans la ligne "Achat" de ton tableau de destination :
=NB.SI.ENS($B:$B;"<"&AUJOURDHUI()+1;$B:$B;">="&AUJOURDHUI()-4;$C:$C;"Achat") pour l'intervalle 0 à -de 5j
=NB.SI.ENS($B:$B;"<"&AUJOURDHUI()-4;$B:$B;">="&AUJOURDHUI()-9;$C:$C;"Achat") pour l'intervalle 5j à -de 10j
=NB.SI.ENS($B:$B;"<"&AUJOURDHUI()-9;$B:$B;">="&AUJOURDHUI()-14;$C:$C;"Achat") pour l'intervalle 10j à -de 15j
=NB.SI.ENS($B:$B;"<"&AUJOURDHUI()-14;$C:$C;"Achat") pour l'intervalle 15j et plus

dans la ligne "Vente", il suffit de mettre les mêmes formules en remplaçant le mot "Achat" par le mot "Vente".

dans la ligne "Total", une fonction SOMME pour additionner les deux nombres...

[arguitxu]

Super. Je vais commencer par comprendre ces formules 😂 et ensuite j’essai De les mettre en application dans mon tableau. Merci pour votre aide et réactivité 😉

[arguitxu]

Alors j'affine encore un peu :
Si je veux avoir les informations chaque semaine pour comparer l'évolution. je revoisaussi mais intervalles


=NB.SI.ENS($B:$B;"<"&AUJOURDHUI()+1;$B:$B;">="&AUJOURDHUI()-1;$C:$C;"Achat") pour l'intervalle 0 et 2 jours (0j - <= 2j)
=NB.SI.ENS($B:$B;"<"&AUJOURDHUI()-1;$B:$B;">="&AUJOURDHUI()-4;$C:$C;"Achat") pour l'intervalle 3 jours et 5 jours ( >2j - <= 5j)
=NB.SI.ENS($B:$B;"<"&AUJOURDHUI()-4;$B:$B;">="&AUJOURDHUI()-9;$C:$C;"Achat") pour l'intervalle 6 jours et 10 jours ( >5j - <= 10j)
=NB.SI.ENS($B:$B;"<"&AUJOURDHUI()-9;$B:$B;">="&AUJOURDHUI()-19;$C:$C;"Achat") pour l'intervalle 11 jours et 20 jours ( >11j - <= 20j)
=NB.SI.ENS($B:$B;"<"&AUJOURDHUI()-19;$C:$C;"Achat") pour l'intervalle 20j et plus

Vois tu une erreur ?

[catapoulpe]

Il faut nous mettre d'accord sur les bornes des intervalles

J'avais interprété ta formulation ainsi :
0 à moins de 5 jours : intervalle de moins de 5j (donc de 4j) qui comprend aujourd'hui. Par exemple aujourd'hui nous sommes le 9 avril, on compte tous les actes survenus les 6, 7, 8 et 9 avril.

Si je comprends bien ton dernier message avec des "inférieur ou égal" tu voudrais (toujours en partant d'aujourd'hui 9 avril) :
9, 8, 7 avril (0j - <= 2j)
6, 5, 4 avril (>2j - <= 5j)
3, 2, 1er avril, 31, 30 mars (>5j - <= 10j)
etc...

=NB.SI.ENS($B:$B;"<"&AUJOURDHUI()+1;$B:$B;">="&AUJOURDHUI()-2;$C:$C;"Achat") (0j - <= 2j)
=NB.SI.ENS($B:$B;"<"&AUJOURDHUI()-2;$B:$B;">="&AUJOURDHUI()-5;$C:$C;"Achat") (>2j, - <= 5j)
=NB.SI.ENS($B:$B;"<"&AUJOURDHUI()-5;$B:$B;">="&AUJOURDHUI()-10;$C:$C;"Achat") (>5j - <= 10j)
=NB.SI.ENS($B:$B;"<"&AUJOURDHUI()-10;$B:$B;">="&AUJOURDHUI()-20;$C:$C;"Achat") (>10j - <= 20j)
=NB.SI.ENS($B:$B;"<"&AUJOURDHUI()-20;$C:$C;"Achat")

[arguitxu]

Bon et bien ce coup la c'est carrément parfait sa commence à prendre forme ;-) Merci catapoulpe

[catapoulpe]

Cool.
Tu peux marquer "Résolu", alors