Discussion :

[Barth1309]

Bonjour,

Je me permets de solliciter votre aide car je suis coincé sur un code.
J'aimerais que la macro puisse supprimer toutes les colonnes sauf celles ayant une entête précise.

Je suis parvenu à trouver des exemples pour faire l'inverse de ce que je souhaite, cad supprimer les colonnes en fonction de leurs entêtes :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub SupprCol2()
 
Dim i As Long
Dim j As Long
 
For i = 2 To 2 'La deuxieme ligne
 
For j = 1 To 60 'les 60 premières colonnes
 
        If Cells(i, j) = "Adresse" Then
            Cells(i, j).EntireColumn.Delete
            j = j - 1
        End If
    Next
 Next
 
End Sub

En indiquant <> au lieu de =, ma boucle tourne à l'infini et je n'arrive pas à la faire stopper quand le but recherché est atteint.
Je vous remercie par avance pour votre aide.

Bien cordialement.
Barthélémy.

[Marc-L]

Bonjour,

commencer déjà logiquement la boucle de la dernière colonne utilisée en remontant vers la première
(voir UsedRange ou encore CurrentRegion dans l'aide VBA) …     Et une seule boucle est nécessaire ‼

___________________________________________________________________________________________________________

Je suis Paris, Egypte, Nigeria, New-York, Mogadicio, Barcelone, London, Manchester, Stockholm, Istanbul, Berlin, Nice, Bruxelles, Charlie, …

[Marc-L]

Allez pour le fun, contrôle de la plage A2:BH2 en dur :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Sub Demo1()
    V = Filter([IF(A2:BH2<>"Adresse",COLUMN(A2:BH2))], False, False)
    For N& = 0 To UBound(V):  V(N) = Cells(2, Val(V(N))).Address(False, False):  Next
    Range(Join(V, ",")).EntireColumn.Delete
End Sub

Edit :  sans boucle juste avec le B-A-BA d'Excel, la simple fonction de feuille de calculs EQUIV (Match en VBA) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Sub Demo2()
       V = [MATCH("Adresse",A2:BH2, 0)]
    If V < 60 Then Columns(V + 1).Resize(, 60 - V).EntireColumn.Delete
    If V > 1 Then Columns(1).Resize(, V - 1).EntireColumn.Delete
End Sub

     Penser Excel Avant VBA ! …

___________________________________________________________________________________________________________

     Merci de cliquer sur en bas à droite de chaque message ayant aidé puis sur pour clore cette discussion …

[Menhir]

En indiquant <> au lieu de =, ma boucle tourne à l'infini et je n'arrive pas à la faire stopper quand le but recherché est atteint.
Je vous remercie par avance pour votre aide.

Trois remarque liminaires sur ton code :

D'abord, un For i = 2 To 2, ça ne sert à rien. Du moins, ça peut s'écrire simplement i = 2.

Ensuite, comme l'a dit Marc ( ), une boucle de suppression de ligne ou de colonne doit toujours aller de la fin vers le début.
Sinon, chaque fois qu'il y aura deux éléments successifs à supprimer, tu louperas le second.

Normalement ton j = j - 1 est là pour compenser, mais (c'est ma troisième remarque) toucher à la variable d'une boucle For To est généralement une mauvaise idée.
Autant mettre un Step -1 à ta boucle pour aller de gauche à droite, c'est beaucoup moins risqué et plus propre.

Ton code donne donc :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Sub SupprCol2()
    Dim j As Long
    For j = 60 To 1 Step -1
        If Cells(2, j).Value <> "Adresse" Then Cells(2, j).EntireColumn.Delete
    Next j
End Sub

[Barth1309]

Merci à tous les deux pour votre grande réactivité,

Vos explications me permettront de me familiariser bien plus rapidement avec la notion de boucle.
Le code marche parfaitement.

Bonne journée à tous les deux.
Barthélémy.