Discussion :

[bobovore]

Bonsoir,
je recherche un programme qui permettrait de convertir un groupe de chiffre en groupe de lettre (et vice versa). Par exemple j'aimerais convertir plusieurs groupes de 7 chiffres (10 millions de possibilité) en autant de groupe de 5 lettres (plus de 11 millions de possibilités). Le nombre de groupe étant variable.
Par exemple les groupes 0000000 0000001 0000002 correspondraient aux groupes AAAAA AAAAB AAAAC

Pensez-vous que cela réalisable en VBA? Je ne vois pas comment aborder le problème, le défi me paraît impossible...
Si c'est pas possible avez-vous connaissance d'un logiciel capable de réaliser cette opération?

Je vous remercie par avance pour vos réponses

[Jean-Philippe André]

Salut,

déjà avec 10 millions de possibilites, tu vas t'amuser sous Office (access serait un moindre mal)...

[kiki29]

Salut, Un échantillon de 2 fonctions qui servent à convertir un n° de colonne en lettre et inversement, peut-être que cela pourra t'aider ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Option Explicit
 
Function NumCol2Lettre(iNumCol As Long) As String
Dim i As Long, sStr As String
    i = iNumCol
    sStr = ""
    Do While i > 0
        sStr = Chr$(((i - 1) Mod 26) + 65) & sStr
        i = (i - 1) \ 26
    Loop
    NumCol2Lettre = sStr
End Function
 
Function Lettre2NumCol(sChaine As String) As Long
Dim i As Long, ValeurCh As Long, v As Long
Const sChaineAlpha As String = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
    For i = 1 To Len(sChaine)
        ValeurCh = InStr(1, sChaineAlpha, Mid$(UCase$(sChaine), i, 1))
        v = v * 26 + ValeurCh
    Next i
    Lettre2NumCol = v
End Function

[Patrice740]

Bonjour,

Il suffit, dans un premier temps, de convertir le nombre initial (en base 10 composé de chiffres arabes) vers le même nombre en base 26 (en utilisant comme chiffre les lettres de l'alphabet) avec la fonction suivante :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Function Base10versBase26(Nombre As Long) As String
Dim x As String
Dim r As Byte
  x = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
  r = Nombre Mod 26
  If Int(Nombre / 26) = 0 Then
    Base10versBase26 = Mid(x, r + 1, 1)
  Else
    Base10versBase26 = Base10versBase26(Int(Nombre / 26)) & Mid(x, r + 1, 1)
  End If
End Function

Et dans un second temps, d'ajouter devant, les zéros non significatifs (représentés par des A) avec la formule du type :
=DROITE("AAAAA" & Base10versbase26(A1);5)

[unparia]

Bonjour à tous,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Private Function rigolo(ch As String) As String
   Dim Q() As Byte
   Q = StrConv(ch, vbFromUnicode)
   For i = 0 To UBound(Q)
     Q(i) = Q(i) + 17
   Next
   rigolo = StrConv(Q, vbUnicode)
End Function

Preuve :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 MsgBox rigolo("0000001")
  MsgBox rigolo("0000002")
  MsgBox rigolo("0003002")

[Menhir]

Tu prends le modulo 26 du nombre que tu réserves dans une variable. Tu le convertis en lettre avec, par exemple, un Chr(). Ca donne la lettre la plus à droite.

Tu soustrais le modulo obtenu à ton nombre, tu divises par 26 et tu obtiens le nouveau nombre à traiter.

Tu mets tout ça dans une boucle qui tourne tant que le nombre à traiter n'est pas arrivé à 0, en concaténant la lettre résultat de chaque tour au résultat du tour précédent.

[Patrice740]

Bonjour,

Fonction améliorée :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Function Base10versBase26Alphabet(Nombre As Long, Optional Digits As Byte) As Variant
Dim x As String
Dim r As Byte
  If Digits > 0 And 26 ^ Digits <= Nombre Then Base10versBase26Alphabet = CVErr(xlErrNum): Exit Function
  x = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
  r = Nombre Mod 26
  If Int(Nombre / 26) = 0 Then
    Base10versBase26Alphabet = Mid(x, r + 1, 1)
    If Digits > 0 Then
      Base10versBase26Alphabet = Right(String(Digits, "A") & Base10versBase26Alphabet, Digits)
    End If
  Else
    Base10versBase26Alphabet = Base10versBase26Alphabet(Int(Nombre / 26), Digits) & Mid(x, r + 1, 1)
    If Digits > 0 Then
      Base10versBase26Alphabet = Right(String(Digits, "A") & Base10versBase26Alphabet, Digits)
    End If
  End If
End Function

Utilisation :
=Base10versBase26Alphabet(A1;5)

[bobovore]

bonjour à tous!
avant d'étudier de près toutes vos réponses, je tenais à vous remercier pour ces dernières!
je vais regarder tout ça de très près, un gros merci!