Discussion :

[Hardgroove]

Bonjour à tous,

J'essaie par plusieurs moyens de faire un couper-coller mais en ne coupant que le contenu et en laissant la mise en forme intacte. A défaut de trouver, je pensais mettre une petite macro dans la feuille qui, lorsque je fais un copier coller, me supprime le contenu des cellules sources et ne copie que les valeurs. En cherchant un peu, j'ai trouvé un bout de code qui, je pensais, en l'adaptant un peu allait fonctionner. Mais je dois faire une erreur quelque part car le contenu de la source n'est pas supprimé. Voici mon code, est-ce que vous auriez une idée?
Je vous remercie par avance,
Maxime

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
 
Private Sub Worksheet_Change(ByVal Target As Range)
Dim tablo, sel As Range
If Application.CutCopyMode Then
  On Error Resume Next 'sécurité
  Application.EnableEvents = False 'désactive l'action des évènements
  tablo = Target 'mémorise les valeurs
  Target.ClearContents
  Set sel = Selection
  Application.Undo 'annule le collage
  Target = tablo 'rétablit uniquement les valeurs
  sel.Select
  Application.EnableEvents = True
End If
End Sub

[Philippe Tulliez]

Bonjour Maxime,
Voici un code qui fonctionne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub CutPast()
 Dim rngSource As Range, rngTarget As Range
 With ThisWorkbook
  Set rngSource = .Worksheets("Feuil3").Range("A4:C9")
  Set rngTarget = .Worksheets("Feuil3").Range("I2")
 End With
 With rngSource: .Copy rngTarget: .ClearContents: End With
End Sub

[Hardgroove]

Bonjour Philippe,

Merci pour ton retour. Ce qui me dérange dans ce code c'est que la source et la cible sont figées. Ce que j'aimerai c'est que ma source soit ma première sélection et ma cible la seconde. Ce qu'il faudrait presque c'est que lorsque je fais mon ctrl+c, mes valeurs soient stockées mais supprimées des cellules sources et que lors du ctrl+v seules les valeurs soient collées dans mes cellules cibles. Je ne sais pas si je suis suffisamment clair.

[Philippe Tulliez]

Bonjour Maxime,

Ce qui me dérange dans ce code c'est que la source et la cible sont figées

Il suffit de transformer la procédure en lui ajoutant des arguments.

Ce qu'il faudrait presque c'est que lorsque je fais mon ctrl+c, mes valeurs soient stockées mais supprimées des cellules sources et que lors du ctrl+v seules les valeurs soient collées dans mes cellules cibles

C'est un peut plus complexe. Pas le temps pour l'instant de me pencher là dessus.

seules les valeurs soient collées dans mes cellules cibles

J'avais cru comprendre dans ta demande que la source devait conserver le format mais que la cible était un coller normal.

[Hardgroove]

Philippe,

Je ne suis pas sur de pouvoir faire simplement avec des arguments car j'ai deux sélections, celle que je sélectionne pour la copie et celle qui est sélectionnée au moment du collage.
Pour la conservation de la mise en forme au moment du collage, peut importe finalement car normalement la mise en forme de mes cellules sources et cibles sont identiques.
Je vais essayer de m'expliquer à nouveau :
- Ma configuration de départ : un groupement de cellules A avec des valeurs et un groupement B de même taille avec la même mise en forme.
- Ce que je veux à l'arrivée : En une seule manip, mettre les valeurs de A dans B sans toucher à la mise en forme de A (couleur de fond, bordure etc..) mais en supprimant les valeurs contenues dans A.

Merci

[eriiic]

Bonjour,

et comment tu comptes déterminer source ET destination avec Sub Worksheet_Change(ByVal Target As Range) ?
Si tu copie-colles Target est la destination, si tu coupe-colles Target est la source.

Je te propose de faire une sélection multiple de 2 zones, source et destination, et un clic-droit dessus.
Comme tu es sensé sélectionner la destination en 2nd, c'est elle qui aura la cellule active. Je m'en sers pour différencier source de destination.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
    Dim source As Range, dest As Range
    If Target.Areas.Count = 2 Then
        Cancel = True
        Set source = Intersect(ActiveCell, Target.Areas(1))
        If source Is Nothing Then
            Set source = Target.Areas(1): Set dest = Target.Areas(2)
        Else
            Set source = Target.Areas(2): Set dest = Target.Areas(1)
        End If
        If dest.Count = 1 Then Set dest = dest.Resize(source.Rows.Count, source.Columns.Count)
        dest.Value = source.Value
        source.ClearContents
    End If
End Sub

J'ai amélioré le truc : pour simplifier la manip si la destination ne fait qu'une cellule je l'agrandi à la taille de la source. Ca doit donc être la cellule haut-gauche du collé.
C'est un collé valeur, on peut changer
eric