Discussion :

[Gonteur]

Bonjour,

Je cherche à réinitialiser une feuille Excel à son ouverture

J'ai réussi à supprimer les filtres

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Private Sub Workbook_Open()
 With ThisWorkbook.Worksheets("Ma Feuille")
 If .FilterMode Then .ShowAllData
 End With
 End Sub

Mais je n'y arrive pas pour les colonnes et/ou lignes masquées

Merci de l'intérêt que vous y porterez

[Ben_L]

Bonjour,

Dans un nouveau classeur, masquez quelques colonnes.
Puis lancez l'enregistreur de macros, sélectionnez toute la feuille, faîtes un clic droit sur les entêtes de colonnes et cliquez sur "Afficher".
Arrêtez l'enregistreur de macros et allez voir le code qui a été créé.
Vous pourrez alors nettoyez ce code pour obtenir ce que vous voulez.

Réitérez avec les lignes si l'adaptation n'est pas évidente.

Cela devrait vous permettre de trouver la bonne syntaxe

[Gonteur]

Merci Ben_L de ton aide c'est très apprécié.

je ne suis vraiment pas expert mais je tente d'apprendre à chaque fois.

Le code qui ressort de la manipulation est

Selection.EntireColumn.Hidden = False

je ne sais pas trop comment l'appliquer dans le Workbook

[Gonteur]

Merci Ben_L, je ne connaissais pas l'outil enregistreur de macro, cela m'a dirigé vers une réponse fonctionnel

La voici

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Private Sub Workbook_Open()
With ThisWorkbook.Worksheets("Ma Feuille")
If .FilterMode Then .ShowAllData
    Columns("A:ZZ").Select
    Selection.EntireColumn.Hidden = False
End With
End Sub

[Gonteur]

Et plutôt

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Private Sub Workbook_Open()
With ThisWorkbook.Worksheets("Billets 17-18")
If .FilterMode Then .ShowAllData
    Columns("A:ZZ").Hidden = False
End With
End Sub

[Ben_L]

Il est souvent plus pratique et plus rapide d'utiliser l'enregistreur de macros...
Reste ensuite, effectivement, à apprendre à extraire la partie importante du code généré automatiquement.
De façon générale, on peut dire que le plus important pour nettoyer le code de l'enregistreur, c'est de supprimer toutes les actions de sélection ainsi que les références aux objets actifs.

Une autre remarque importante concernant le code que vous proposez ici : l'utilisation de Columns sans qualificateur (càd sans préciser la référence de l'objet auquel appartient cette méthode) est équivalente à l'appel ActiveSheet.Columns.
Dans la mesure où vous appelez la méthode Columns à l'intérieur d'un With qui fait référence à la feuille qui vous intéresse, il serait préférable d'écrire :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Private Sub Workbook_Open()
    With ThisWorkbook.Worksheets("Billets 17-18")
        If .FilterMode Then .ShowAllData
        .Columns.Hidden = False
        .Rows.Hidden = False
    End With
End Sub

[Gonteur]

Merci beaucoup Ben_L

Comment puis-je appliquer ce code à l'ensemble du classeur? Car tel quel si le classeur n'ouvre pas et donc n'a pas été sauvegardé sur l'onglet "Billet 17-18" la macro ne s'exécute pas.

[Gonteur]

Bonjour

Voici ce que j'essaie sans succès

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Private Sub Workbook_Open()
 
Dim Ws As Worksheet
 
For Each Ws In ThisWorkbook.Worksheets
         If .FilterMode Then .ShowAllData
            .Columns.Hidden = False
            .Rows.Hidden = False
 
Next Ws
End Sub

[unparia]

Bonjour
évite s'il te plait ce genre d'expression :

Voici ce que j'essaie sans succès

alors que tu as un message d'erreur. C'est le message reçu et la ligne en cause, qu'il faut rapporter, pas simplement que tu as "essayé sans succès" !

Les "." devraient correspondre à un bloc With que tu n'utilises pas !
Remplace-les par "Ws."

[Gonteur]

Merci unparia

Code utilisé

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Private Sub Workbook_Open()
 
Dim Ws As Worksheet
 
For Each Ws In ThisWorkbook.Worksheets
         If Ws.FilterMode Then Ws.ShowAllData
            Ws.Columns.Hidden = False
            Ws.Rows.Hidden = False
Next Ws
End Sub

Génère l'erreur

Erreur d'exécution '1004':
Impossible de définir la propriété Hidden de la classe Range

[Ben_L]

Bonjour Gonteur,

Impossible pour moi de reproduire cette erreur, qui est probablement liée au contenu de votre classeur.
Si j'en crois le post disponible à ce lien, le problème provient :

1. soit de la présence de commentaires dans certaines cellules,
2. soit de la présence d'objet dessinés qui ne sont pas redimensionnés avec les cellules,
3. soit d'une protection appliquée au classeur ou à l'une des feuilles.

La 3ème solution paraît peu probable (j'imagine que si votre classeur était protégé, vous seriez au courant...).

Dans l'idéal, commencez par identifier la cause réelle du problème.
Il sera ensuite possible d'envisager une solution de contournement.

[Marc-L]

La 3ème solution paraît peu probable (j'imagine que si votre classeur était protégé, vous seriez au courant...).

Salut Ben !

C'est souvent celle-ci à penser en premier !     Surtout avec l'erreur 1004 …

___________________________________________________________________________________________________________
Je suis Paris, Mogadicio, Barcelone, London, Manchester, Egypte, Stockholm, Istanbul, Berlin, Nice, Bruxelles, Charlie, …

[Gonteur]

Merci à vous,

Oui, effectivement certaines feuilles sont protégées et provoquait l'erreur..

Ce code est fonctionnel

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Private Sub Workbook_Open()
   Dim Sh As Worksheet
   For Each Sh In Sheets
        Sh.Unprotect
       If Sh.FilterMode Then Sh.ShowAllData
       Sh.Cells.Rows.Hidden = 0:  Sh.Cells.Columns.Hidden = 0
   Next
End Sub

Comment soustraire les feuilles protéger de cette vérification car je ne veux pas que leur contenu soit modifiés par le code? Soit qu'à l'ouverture le code s'applique à toutes les feuilles non protégées?

Merci!

[Ben_L]

La vérification que souhaitez faire peut s'effectuer comme suit :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Private Sub Workbook_Open()
    Dim Sh As Worksheet
    For Each Sh In Sheets
        If Not Sh.ProtectContents Then
            If Sh.FilterMode Then Sh.ShowAllData
            Sh.Cells.Rows.Hidden = 0:  Sh.Cells.Columns.Hidden = 0
        End If
    Next
End Sub

[Gonteur]

Merci beaucoup Ben_L, Marc-L & unparia

Tout est ok

Votre aide est très apprécié