Discussion :

[GCX07]

Bonjour à tous !

Je suis nouveau (sur ce forum et en VBA) et après avoir chercher un peu partout sur les faq etc., je vous soumets mon problème.

J'ai 2 classeurs excel Classeur1.xlsx Classeur2.xlsm

Je tente de coder une macro qui me permettrait de remplir la colonne C du classeur 2 après un test par, soit "pas de correspondance" si test "faux", soit la cellule de la colonne B du classeur 1 si le test est "vrai". Le test est de prend chaque cellule de la colonne A du classeur 2 et de vérifier si la même valeur existe dans la colonne A du classeur 1.

En clair, comme exemples avec les fichiers joints, la colonne C de mon classeur 2 se remplirait comme suit : 2 / 3 / 6 / 10 / pas de correspondance.

Un grand merci d'avance à toutes celles et ceux qui voudront bien aider et corriger ma macro !!!

[Invité]

Bonjour,

A tester :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
 
Option Explicit
 
Sub MettreAJourClasseur2()
 
Dim FichierSource As Workbook
Dim AireSource As Range, CelluleSource As Range, AireCible As Range, CelluleCible As Range
Dim DerniereLigne As Long
Dim Repertoire As String
Dim CorrespondanceTrouvee As Boolean
 
 
       ' Repertoire = "C:\Users\Eric\Downloads\"
        Repertoire = "E:\Nounours\Maxwell_W\"
 
        Set ShCible = Sheets("Feuil1")
        With Sheets("Feuil1")
             DerniereLigne = .Cells(.Rows.Count, 1).End(xlUp).Row
             Set AireCible = .Range(.Cells(1, 1), .Cells(DerniereLigne, 1))
             AireCible.Offset(0, 1).ClearContents
        End With
 
        Set FichierSource = Workbooks.Open(Filename:=Repertoire & "Classeur1.xlsx")
        With FichierSource.Sheets("Feuil1")
             DerniereLigne = .Cells(.Rows.Count, 1).End(xlUp).Row
             Set AireSource = .Range(.Cells(1, 1), .Cells(DerniereLigne, 1))
        End With
 
        For Each CelluleCible In AireCible
            CorrespondanceTrouvee = False
            For Each CelluleSource In AireSource
                If CelluleCible = CelluleSource Then
                   CelluleCible.Offset(0, 1) = CelluleSource.Offset(0, 1)
                   CorrespondanceTrouvee = True
                   Exit For
                End If
            Next CelluleSource
            If CorrespondanceTrouvee = False Then
               CelluleCible.Offset(0, 1) = "Pas de correspondance"
            End If
        Next CelluleCible
 
        FichierSource.Close savechanges:=False
 
        Set AireCible = Nothing
        Set AireSource = Nothing
        Set FichierSource = Nothing
        Set ShCible = Nothing
 
End Sub

Nb : Mettez votre code entre balises #

[GCX07]

Merci beaucoup Eric ! Ca fonctionne parfaitement.

les lignes :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Set ShCible = Sheets("Feuil1")
Set ShCible = Nothing

ne sont pas utiles.

Qu'entendez-vous par mettre mon code entre balises ?

[Invité]

Dans le menu, # permet de présenter les lignes de code comme dans mon message.
Quant à ShCible, effectivement ces lignes de code ne sont pas utiles.