Discussion :

[CatDos]

Bonjour,

La macro que je suis en train de rédiger commence par un tri des lignes selon la colonne A (réf. d'étude). Les lignes contenant une même réf.d'étude en A sont donc regroupées. (Jusque-là, pas de souci).
Je voudrais ensuite, sélectionner toutes les lignes qui ont la même réf. d'étude (réf. saisie dans une InputBox). Ces lignes sélectionnées devraient être contigües puisque préalablement triées.
Ensuite, ma macro se poursuit à partir de cette plage constituée de ces lignes sélectionnées.

Je ne parviens pas à rédiger un code qui sélectionne, en même temps, l'ensemble des lignes qui ont la même réf. d'étude. Je n'arrive à sélectionner qu'une seule ligne (la première), ou l'une après l'autre.
Pourriez-vous, SVP, m'aider ?
Merci beaucoup

[parmi]

Bonjour,

As-tu essayé en utilisant un filtre ?
Ça me semblerait une bonne solution...

[Pierre Fauconnier]

Salut.

Voici une fonction qui isole la sous-plage de la plage de recherche qui correspond à la valeur recherchée, pour autant, comme tu l'annonces, que ta plage soit triée sur sa première colonne... Elle recherche dans la première colonne de ladite plage. Elle est générique et ta plage peut donc commencer ailleurs qu'en A2. En utilisant Excel dans ton code, tu évites la lourdeur et la lenteur d'une boucle (Voir ma signature: VBA pour Excel? Pensez d'abord en Excel... )

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Function getRowsByValue(Source As Range, Value As String) As Range
  Dim FirstRow As Variant
  Dim RowsCount As Long
 
  FirstRow = Application.Match(Value, Source.Columns(1).Cells, 0)
  RowsCount = Application.CountIfs(Source.Columns(1).Cells, Value)
  If Not IsError(FirstRow) Then
    Set getRowsByValue = Source.Rows(FirstRow).Resize(RowsCount)
  End If
End Function

Elle renvoie soit la plage trouvée, soit Nothing. Pour l'utiliser, il suffit de lui passer les bons arguments.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Sub SetRange()
  Dim rng As Range
 
  Set rng = getRowsByValue(Range("a2:b12"), "B")
  If Not rng Is Nothing Then MsgBox "Adresse de la plage trouvée: " & rng.Address
End Sub

Exemple avec la plage en A2:B12




Exemple avec la plage en D8:E18

[CatDos]

Merci beaucoup pour vos réponses très rapides !

Je réponds tout d'abord à "parmi": Je ne peux pas utiliser un filtre car ma feuille est protégée. De plus, cette sélection de lignes est incluse dans une procédure plus longue, avec d'autres actions.

Je réponds maintenant à Pierre Fauconnier:
Merci beaucoup pour vos deux codes que j'ai pu adapter à mon fichier. Le résultat est exactement celui que je souhaitais.
Mille mercis