Discussion :

[yakalelo57]

Bonjour,

Je souhaite intégrer à un script une vérification du modèle de la machine l'exécutant afin de poursuivre avec des instructions différentes selon le modèle.

Mon exemple :

la commande suivante donne le modèle : wmic computersystem get modelJ'ai donc cherché pour passer son résultat en variable et ensuite me servir de cette variable pour faire par exemple if %modele% = HP Probook 450 G3 go to pb450g3J'ai trouvé des commandes du style : for /f "delims=" %%i in ('wmic computersystem get model') do Set VrTemp=%%iMais je ne m'en sors pas.

De plus ma commande wmic renvoie un tableau avec un titre :
model
HP Probook...

Pouvez-vous m'aider à rendre mon script fonctionnel ?

Merci par avance

[hackoofr]

Vous pouvez aussi nous poster votre exemple et
Voici une subroutine :GetModel <Model>

Code BAT :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
@echo off
Call :GetModel Model
echo Le model de ce PC est : "%Model%"
pause>nul
::*******************************************************************
:GetModel <Model>
Rem le paramètre %1 représente la variable qu'on va définir 
Rem (dans notre cas %1=Model)
FOR /F "tokens=2 delims==" %%I IN (
  'wmic computersystem get model /format:list 2^>^nul'
) DO FOR /F "delims=" %%A IN ("%%I") DO SET "%1=%%A"
Exit /b
::*******************************************************************

[yakalelo57]

bonsoir
désolé pour la balise j'avais oublié ^^

J'ai testé votre script (copié collé) mais MS DOS me renvoie "la syntaxe de la commande n'est pas correcte.
Dans la foulée écho %model% renvoie bien ce que je veux mais pourquoi ce message d'erreur ?

[hackoofr]

J'ai testé votre script (copié collé) mais MS DOS me renvoie "la syntaxe de la commande n'est pas correcte.
Dans la foulée écho %model% renvoie bien ce que je veux mais pourquoi ce message d'erreur ?

Copier et coller le code dans votre notepad et enregistrer le sous le nom par exemple test.bat puis exécuter le par un double clique

[yakalelo57]

c'est ce que j'ai fait ^^
je viens de retester et j'ai toujours le message.

ensuite j'ai modifié un peu pour adapter à mon besoin (et enlevé la pause au milieu) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
@echo off
Call :GetModel Model
echo Le model de ce PC est : "%Model%"

:GetModel <Model>
Rem le paramètre %1 représente la variable qu'on va définir 
Rem (dans notre cas %1=Model)
FOR /F "tokens=2 delims==" %%I IN (
  'wmic computersystem get model /format:list 2^>^nul'
) DO FOR /F "delims=" %%A IN ("%%I") DO SET "%1=%%A"

if %Model% == MS-7A71 goto :MS7A71

echo TOTO

:MS7A71
echo cool le modele MS-7A71
goto :eof

:MODELEBIDON
echo modele bidon

Celà fonctionne pour que seules les instructions de :MS7A71 soient lancées mais si j'exécute ce dernier il me traite 2 fois les commandes figurant dans :MS7A71 (voir screen)

[hackoofr]

Code BAT :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
@echo off
Call :GetModel Model
echo Le model de ce PC est : "%Model%"
if "%Model%"=="MS-7A71" ( 
    goto :MS7A71
) else (
    goto :MODELEBIDON
)
pause>nul
::**********************************************************
:MS7A71
echo cool le modele MS-7A71
rem ajouter pause pour voir le message
pause>nul
exit /b
::**********************************************************
:MODELEBIDON
echo modele bidon
rem ajouter pause pour voir le message
pause>nul
exit /b
::**********************************************************
:GetModel <Model>
Rem le paramètre %1 représente la variable qu'on va définir 
Rem (dans notre cas %1=Model)
FOR /F "tokens=2 delims==" %%I IN (
  'wmic computersystem get model /format:list 2^>^nul'
) DO FOR /F "delims=" %%A IN ("%%I") DO SET "%1=%%A"
exit /b
::***********************************************************

[yakalelo57]

je vais tester celà demain matin merci

l'idée serait aussi de ne pas faire de if + else comme pour deux choix mais plutôt 10 if sans else car j'aurais potentiellement 10 modèles de machines existants donc je veux tous les conditionner.

C'est possible ?
du genre

If %modele1% == MOD1 goto :mod1
If %modele2% == MOD2 goto :mod2
etc

[hackoofr]

Voici un autre moyen à tester chez vous

Code BAT :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
@echo off
Set "WMIC_COMMND=wmic computersystem get model"
Call :GetModel Model
findstr /I "%Model%" "%~f0">nul && ( goto :%Model% ) || ( goto :MODELEBIDON )
pause>nul & exit
::**********************************************************
:MODELEBIDON
echo modele bidon
rem ajouter pause pour voir le message
pause>nul
exit /b
::**********************************************************
:MS-7A71
echo cool le modele %Model%
rem ajouter pause pour voir le message
pause>nul
exit /b
::**********************************************************
:Aspire E1-571
echo cool le modele est %Model%
pause>nul
exit /b
::**********************************************************
:GetModel <Model>
Rem le paramètre %1 représente la variable qu'on va définir 
Rem (dans notre cas %1=Model)
FOR /F "tokens=2 delims==" %%I IN (
  '%WMIC_COMMND% /format:list 2^>^nul'
) DO FOR /F "delims=" %%A IN ("%%I") DO SET "%1=%%A"
exit /b
::***********************************************************

[yakalelo57]

ouais c'est mieux en effet

Par contre entre temps j'ai procédé autrement et j'ai passé en variable le modèle machine donc dans le script principal afin d'appeler un second script dans une arbo.
C'est un script différent par modèle de PC qui se trouve à l'intérieur d'un répertoire portant le nom du modèle de PC.

ainsi par la suite si problème sur un modèle j'irais éditer le fichier lui correspondant.

[hackoofr]

ouais c'est mieux en effet

Par contre entre temps j'ai procédé autrement et j'ai passé en variable le modèle machine donc dans le script principal afin d'appeler un second script dans une arbo.
C'est un script différent par modèle de PC qui se trouve à l'intérieur d'un répertoire portant le nom du modèle de PC.

ainsi par la suite si problème sur un modèle j'irais éditer le fichier lui correspondant.

Donc problème et sans aucun

[yakalelo57]

ah ? on fait comment ?
Désolé je ne suis pas très souvent ici ^^

edit : j'ai trouvé une main verte, dis moi ci c'est OK ^^