Discussion :

[alexklond]

Bonjour à tous,

Je suscite votre aide car je suis bloqué avec mon code,

Le but de ce code est :
-Chaque cellule de la colonne A de la page DATABASE contiennent des catégories
-Ce code va chercher la catégorie de la cellule dans la page TRAITEMENT
-Faire la somme de toutes les cellules sur la meme ligne (Numero de colonne indéterminé) de la page Traitement
-Renvoyer le resultat de cette somme dans la colonne C de la page DATABASE à la ligne de cette même catégorie


J'ai 2 soucis avec ce code :
- Premier problème => il doit sommer toutes les cellules correspondant à la catégorie par exemple :
Si dans la page DATABASE la cellule A2 est "catégorie 1" il doit aller chercher dans la colonne A page TRAITEMENT la "Categorie 1" et ensuite faire la somme de toutes les celulles sur cette meme ligne jusqu'à la derniere cellule de la dernière colonne pleine.

- Deuxieme problème => dans le code ci dessous il fait toujours la meme somme, il ne prend pas en consideration le résultat de la recherche V pour aller faire la somme des cellules correspondantes à ce choix

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
 
Sub recherche()
 
'il va réaliser une recherche V à partir du nom des catégories et si il trouve, il va sommer toutes la ligne correspondante dans la page traitement, il devra afficher le résultat dans la page Database colonne 3 à la ligne correspondante à la catégorie testée
 
Dim P As Range, C As Range, Teste
 
 
With Sheets("DATABASE")
    Set P = .Range(.[A2], .Cells(.Rows.Count, 1).End(xlUp))
End With
 
With Sheets("Traitement")
L = Sheets("Traitement").Range("A" & Rows.Count).End(xlUp).Row
M = Sheets("Traitement").Cells(1, Cells.Columns.Count).End(xlToLeft).Column
 
 
    For Each C In P
        Teste = Application.VLookup(C.Value, .Range(.[A2], .Cells(.Rows.Count, 1).End(xlUp)), 1, 0)
 
        If IsError(Teste) Then
        C.Offset(, 3) = ""
        Else
    For i = 1 To L
 
      C.Offset(, 3).Formula = "=sum(Traitement!" & Cells(i, 1).Address & _
":" & Cells(i, M).Address & ")"
     Next
 
        End If
     Next C
End With
End Sub

[Invité]

Bonjour,

A tester :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
 
Sub Recherche()
 
Dim AireDataBase As Range, CelluleDataBase As Range
Dim LigneTitreDataBase As Long, DerniereLigneDataBase As Long
 
Dim AireTraitement As Range, CelluleTraitement As Range
Dim LigneTitreTraitement As Long, DerniereLigneTraitement As Long, DerniereColonneTraitement As Long, ColonneTraitement As Long
 
    With Sheets("DATABASE")
         LigneTitreDataBase = 1
         DerniereLigneDataBase = .Cells(.Rows.Count, 1).End(xlUp).Row
         Set AireDataBase = .Range(.Cells(LigneTitreDataBase + 1, 1), .Cells(DerniereLigneDataBase, 1))
    End With
 
    With Sheets("Traitement")
         LigneTitreTraitement = 1
         ColonneTraitement = 1
         DerniereLigneTraitement = .Cells(.Rows.Count, ColonneTraitement).End(xlUp).Row
         DerniereColonneTraitement = .Cells(LigneTitreTraitement, .Columns.Count).End(xlToLeft).Column
         Set AireTraitement = .Range(.Cells(LigneTitreTraitement, ColonneTraitement), .Cells(DerniereLigneTraitement, ColonneTraitement))
    End With
 
    For Each CelluleDataBase In AireDataBase
        For Each CelluleTraitement In AireTraitement
            If CelluleTraitement = CelluleDataBase Then
               ' Si la formule dans DATABASE doit être la dernière colonne de la ligne trouvée dans TRAITEMENT
               'With Sheets("Traitement")
               'DerniereColonneTraitement = .Cells(CelluleTraitement.Row, .Columns.Count).End(xlToLeft).Column
               'End With
               CelluleDataBase.Offset(0, 3).Formula = "=sum(Traitement!" & CelluleTraitement.Address & _
                 ":" & CelluleTraitement.Offset(0, DerniereColonneTraitement - ColonneTraitement).Address & ")"
               Exit For
            End If
        Next CelluleTraitement
    Next CelluleDataBase
 
    Set AireDataBase = Nothing
    Set AireTraitement = Nothing
 
End Sub

[alexklond]

Merci beaucoup Eric pour ton aide,

en analysant bien le code j'ai compris mon erreur, il faut que mon code soit plus structuré ... et ma façon d'organiser mon code également...

merci encore pour ton aide précieuse

[RyuAutodidacte]

Bonjour,

Je vois que ce nouveu post est la suite de ton précédent post, il aurait été plus judicieux de continuer sur le même post et pas le mettre en résolu.

[alexklond]

bonjour Ryu,

en effet, il m a paru plus judicieux de refaire un poste mieux expliqué avec un code que j'ai essayé de développer pour montrer que j'essaye de réaliser même si je ne suis pas un pro du vba.

merci pour ta critique constructive.