Discussion :

[julien terrier]

Bonjour,

j'ai du mal a comprendre la manière dont est traité un fichier texte par la commande awk.

Pour être plus précis je souhaiterais faire un traitement différent par ligne mais cela ne fonctionne pas...

Code bash :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
#!/bin/bash
#awk '{toto= $0; printf(" essai %20s\n",toto);}' $1
 
awk '{toto= $0; printf(" essai %20s\n",toto);}{xp1= $1; yp1= $2; xp2= $3; yp2= $4; largeur = xp2 - xp1; hauteur = yp2 - yp1; surface = largeur * hauteur; printf("\nTEG dimensions (in um):\n"); printf("	Width     : %10.6f\n",largeur); printf("	Length    : %10.6f\n",hauteur); printf("	Area      : %10.6f\n\n",surface);if (largeur != 80.000000){exit 1;}}' $1

J'injecte un fichier texte 2 lignes:
ligne 1 ==> BMW_x1
ligne 2 ==> -40 1320 40 78

Par rapport au script ci-dessus je souhaiterais effectuer la partie entre les premières accolades sur la ligne 1 et pas sur la ligne 2 et la deuxième partie entre accolade faire le traitement uniquement sur la ligne 2

Première partie entre accolade ==> {toto= $0; printf(" essai %20s\n",toto);},
Deuxième partie ==> {xp1= $1; yp1= $2; xp2= $3; yp2= $4; largeur = xp2 - xp1; hauteur = yp2 - yp1; surface = largeur * hauteur; printf("\nTEG dimensions (in um):\n"); printf(" Width : %10.6f\n",largeur); printf(" Length : %10.6f\n",hauteur); printf(" Area : %10.6f\n\n",surface);if (largeur != 80.000000){exit 1;}}' $1,

J'ai bien tenté des essais avec NR == 2 ou avec next, car next semblerait etre presque l'instruction idéal pour mon pb mais je n'arrive pas l'implémenter correctement.

L'instruction next interrompt le traitement de la ligne courante et déclenche la lecture de la ligne suivante, sur laquelle le traitement intégral sera appliqué. ( la fin me dérange car je ne veux pas effectuer le traitement intégral sur la ligne 2 )

Merci pour votre aide.

[julien terrier]

getline peut peut-etre me sauver, je lis...

ok pour getline, si j'ajoute getline a la fin de la première accolade le tour est joué:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
{toto= $0; printf(" essai %20s\n",toto);getline}
{
xp1= $1
yp1= $2
xp2= $3
yp2= $4
largeur = xp2 - xp1;
hauteur = yp2 - yp1;
surface = largeur * hauteur;
printf("\nTEG dimensions (in um):\n");
printf("	Width     : %10.6f\n",largeur);
printf("	Length    : %10.6f\n",hauteur);
printf("	Area      : %10.6f\n\n",surface);
if (largeur != 80.000000)
exit 1;
}

[N_BaH]

Bonjour,

tu pourrais tester que le reste de la division (modulo) par 2 retourne une valeur positive, ou pas, et effectuer, en fonction, le traitement souhaité.

edit: vous pouvez essayer en onction, mais il n'est pas dit que le traitement soit efficace.

[BufferBob]

salut,

je pense que tu as raison getline dans le cas présent est une bonne idée, du coup tu peux même faire la totalité du traitement dans un seul bloc

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
awk '
{
   printf(" essai %20s\n", $0);
   getline;
   largeur = $3 - $1;
   hauteur = $4 - $2;
   printf("\nTEG dimensions (in um):\n");
   printf("\tWidth     : %10.6f\n", largeur);
   printf("\tLength    : %10.6f\n", hauteur);
   printf("\tArea      : %10.6f\n\n", largeur * hauteur);
   if (largeur != 80.000000){
      exit 1;
   }
}' $1

[jack-ft]

J'ai bien tenté des essais avec NR == 2 ou avec next, car next semblerait etre presque l'instruction idéal pour mon pb mais je n'arrive pas l'implémenter correctement.

Avec test sur NR:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

awk 'NR == 1 {toto= $0; printf(" essai %20s\n",toto); next; } NR == 2 {xp1= $1; yp1= $2; xp2= $3; yp2= $4; largeur = xp2 - xp1; hauteur = yp2 - yp1; surface = largeur * hauteur; printf("\nTEG dimensions (in um):\n"); printf("	Width     : %10.6f\n",largeur); printf("	Length    : %10.6f\n",hauteur); printf("	Area      : %10.6f\n\n",surface);if (largeur != 80.000000){exit}}' plop

ou bien:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
awk 'NR == 1 {toto= $0; printf(" essai %20s\n",toto); next; }
NR == 2 {xp1= $1; yp1= $2; xp2= $3; yp2= $4; 
  largeur = xp2 - xp1; hauteur = yp2 - yp1; 
  surface = largeur * hauteur; printf("\nTEG dimensions (in um):\n"); 
  printf("	Width     : %10.6f\n",largeur); 
  printf("	Length    : %10.6f\n",hauteur); 
  printf("	Area      : %10.6f\n\n",surface);
  if (largeur != 80.000000){exit}}'

[julien terrier]

Merci pour vos retours toujours très instructif.

Je reviens la semaine prochaine avec de nouvelles aventures Field Separator qui ne fonctionne pas que je voudrais...

a la semaine prochaine

[N_BaH]

mais traiter un fichier de deux lignes avec awk, c'est pas un peu comme utiliser un marteau-pneumatique pour poser un crochet pour les clés ?

[julien terrier]

mais traiter un fichier de deux lignes avec awk, c'est pas un peu comme utiliser un marteau-pneumatique pour poser un crochet pour les clés ?

Un viaggo de mille millia inizia con sempre un singulo passo (lao tseu)

[N_BaH]

c'est le premier pas de l'homme sur la lune avant d'avant lu Jules Verne.

en shell, si tu n'as que quelques lignes à lire :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

{ read ligne1; read ligne2;} </chemin/fichier

après tu fais tes traitements sur chaque ligne...

EDIT:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
$ { read ligne1; read l1 h1 l2 h2;} </chemin/fichier
$ largeur=$(( l2 - l1 )) hauteur=$(( h2 - h1 ))
$ surface=$(( largeur * hauteur ))
$ (( largeur != 80 )) && echo "exit 1" || LC_NUMERIC=C printf 'essai: %s\n\nwidth: %10.6f\nlength: %10.6f\narea: %10.6f\n' "$ligne1" "$largeur" "$hauteur" "$surface"
essai: BMW_x1
 
width:  80.000000
length: -1242.000000
area: -99360.000000

à condition que les données soient toutes des entiers, car le shell ne sait pas effectuer de calculs sur les nombres réels.

[julien terrier]

Il y a quelque chose qui m'echappe avec le field seperator

Code awk :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
#!/bin/awk -f
{
   FS="_";
   printf(" essai %20s\n", $1);
   printf(" essai %20s\n", $2);
   getline;
   largeur = $3 - $1;
   hauteur = $4 - $2;
   printf("\nTEG dimensions (in um):\n");
   printf("\tWidth     : %10.6f\n", largeur);
   printf("\tLength    : %10.6f\n", hauteur);
   printf("\tArea      : %10.6f\n\n", largeur * hauteur);
   if (largeur != 80.000000){
      exit 1;
   }
}

je m'attendais a afficher BMW puis x1 mais pas du tout j'ai BMW_x1 et rien il y a quelque chose que je ne saisie pas, de plus cela impacte le traitement après getline la je comprends que je dois faire un traitement spécifique que pour la ligne 1 ou réinitialiser la variable FS?

Merci pour votre aide.

[N_BaH]

apparemment, l'endroit où est défini FS importe :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
$ awk '{FS="_"; print $1}' "$fichier"
BMW_x1
-40 1320 40 78
$ awk 'BEGIN{FS="_"}{print $1}' "$fichier"
BMW
-40 1320 40 78

dans le premier cas, la ligne est déjà lue, et la (re)définition du field separator est sans effet. (?)

[disedorgue]

Pour le FS, l'explication est que awk ne transforme pas $0 si on ne touche aucun des champs, par contre si tu modifies un des champs, alors oui, awk fera la modification:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
$ echo toto_titi | awk -F_ '{print}' #ici, on ne touche à rien
toto_titi
$ echo toto_titi | awk -F_ '{$1=$1;print}' #ici, on modifie le champs 1
toto titi

Pour le getline, il faut le voir un peu comme le next mais sans retourner en début de cycle, il charge une ligne et la repasse dans $0 comme une nouvelle ligne avec tout ce que cela comprends (incrément du compteur de ligne, changement de valeur des champs, du compteur de champs, etc...).

[ctac_]

Salut,
Ce n'est pas la bonne explication

$ echo toto_titi | awk -F_ '{print}' #ici, on n'affiche tout
toto_titi

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
$ echo toto_titi | awk -F_ '{print $1}' #ici c'est bon
toto
printf "toto_titi\ntata_tete" | awk '{FS="_";print $1}'
toto_titi
tata

Quand on passe FS en paramètre, il est dispo partout.
Quand on fixe FS dans le corps du programme awk, il n'est dispo qu'apres l'affectation.
Dans mon deuxième exemple :
awk lit la première ligne.
Il change la variable FS pour la suite.
Cordialement.

[disedorgue]

oui, c'est vrai, pas clair ce que j'ai dis .
en complément:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
$ printf "toto_titi\ntata_tete" | awk '{FS="_";$0=$0;print $1}'
toto
tata

Ici, en modifiant $0 par lui-même, ça le redéfini, on est juste un cran au dessus par rapport à mon exemple ou je le défini avant lecture de la première ligne.

[julien terrier]

Merci pour vos retours

Donc si j'utilise un script versus une ligne de commande la section BEGIN prend tout son sens.

CQFD:

La section BEGIN est exécutée avant traitement du premier enregistrement des données. Elles est utilisée essentiellement pour initialiser le contexte d’exécution.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
#!/bin/awk -f
BEGIN{FS="_"}
{
   printf(" essai %20s\n", $1);
   FS=" ";
   getline;
   largeur = $3 - $1;
   hauteur = $4 - $2;
   printf("\nTEG dimensions (in um):\n");
   printf("\tWidth     : %10.6f\n", largeur);
   printf("\tLength    : %10.6f\n", hauteur);
   printf("\tArea      : %10.6f\n\n", largeur * hauteur);
   if (largeur != 80.000000){
      exit 1;
   }
}