Discussion :

[infoclp81]

Bonjour,

à partir d'un fichier excel, je souhaiterais créer une macro exécutant les actions suivantes:

1. extraire une plage de données en fonction de deux dates (entre le JJ//MM/AAAA et le JJ/MM/AAAA).

2. créer un graphique en fonction de variables présentes dans cette plage de données.

3. Si possible,effectuer une régression linéaire ou non linéaire.

Merci pour vos réponses,

je reste à votre disposition si besoin,



PBa.

[mercatog]

1. Crée ton graphique à partir de la plage entière
2. Ajoute ta courbe de tendance
3. Faire un filtre automatique (chronologique) entre la date D1 et D2
4. C'est tout

A l'aide de l’enregistreur de macros tu auras un code que tu pourras épurer, optimiser et réaménager

[infoclp81]

Merci pour votre retour.

En revanche, j'ai un petit problème. en faisant l'enregistreur de macro, si je veux relancer cette macro sur un autre fichier de données, cela me sélectionnera toujours entre la date D1 et la date D2 enregistrées dans la macro. N'y a t-il pas une solution pour faire apparaitre une fenêtre pour saisir les nouvelles dates?

merci pour votre retour,

cdt,

PBa.

[mercatog]

Si, bien sûr

C'est pourquoi je t'avais conseillé ceci:

A l'aide de l’enregistreur de macros tu auras un code que tu pourras épurer , optimiser et réaménager

[infoclp81]

OK mais pourriez-vous me dire comment faire pour le filtre date s'il vous plait?

cdt,

PBA.

[mercatog]

Quel code tu as obtenu?

[infoclp81]

Le voici :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Sub test()
'
' test Macro
'
 
'
    Columns("B:C").Select
    ActiveSheet.Shapes.AddChart.Select
    ActiveChart.ChartType = xlXYScatter
    ActiveChart.SetSourceData Source:=Range("Feuil4!$B:$C")
    ActiveSheet.Shapes("Graphique 3").IncrementLeft -134.25
    ActiveSheet.Shapes("Graphique 3").IncrementTop -189
    ActiveSheet.Shapes("Graphique 3").ScaleWidth 2.3833333333, msoFalse, _
        msoScaleFromTopLeft
    ActiveSheet.Shapes("Graphique 3").ScaleHeight 2.4843751823, msoFalse, _
        msoScaleFromTopLeft
    ActiveChart.SeriesCollection(1).Select
    ActiveChart.SeriesCollection(1).Trendlines.Add
    ActiveChart.SeriesCollection(1).Trendlines(1).Select
    ActiveSheet.Range("$A$1:$C$4724").AutoFilter Field:=1, Criteria1:= _
        ">=01/01/2017", Operator:=xlAnd, Criteria2:="<=31/07/2017"
End Sub

Merci

[mercatog]

Code pédagogique à étudier (ne pas se suffire d'un copier coller)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Sub Test()
Dim LastLig As Long, D1 As Long, D2 As Long
Dim PlageX As Range
Dim Ch As Chart
 
'Les dates bornes
D1 = DateSerial(2017, 2, 4)
D2 = DateSerial(2017, 3, 1)
 
With Worksheets("Feuil4")
    'On supprime l'éventuel filtre
    .AutoFilterMode = False
    'Dernière ligne remplie de la colonne A
    LastLig = .Cells(.Rows.Count, "A").End(xlUp).Row
    'Filtre la colonne A entre les dates D1 et D2 définies ci-haut
    .Range("A1:A" & LastLig).AutoFilter Field:=1, Criteria1:=">=" & D1, Operator:=xlAnd, Criteria2:="<=" & D2
 
    'Plage des abscisses B2:Bxxx
    Set PlageX = .Range("B2:B" & LastLig)
 
    'Traçage du graphique
    Set Ch = .ChartObjects.Add(200, 50, 500, 200).Chart
    With Ch
        .ChartType = xlXYScatterSmooth
        With .SeriesCollection.NewSeries
            .XValues = PlageX
            .Values = PlageX.Offset(, 1)
            .Trendlines.Add
        End With
    End With
End With
'Libération des variables
Set PlageX = Nothing
Set Ch = Nothing
End Sub