Discussion :

[Cygnus50]

Bonjour à tous !

Je voudrais créer un userform avec des champ "Label". Mais le nombre de ces champ doit être variable (il dépendra du nombre de données "n" qui sera trouvé dans le classeur)
Par exemple, si n=3, je voudrais créer 3 labels dont les noms vont prendre la valeur de la cellule A1, A2 et A3.

Bonus de cogitation : si en plus quelqu'un savait comment faire pour éviter les doublons (ex:A1 et A2 ont la même valeur, donc on ne crée qu'un champ "Label" en plus du champ pour A3), ce serait vraiment génial !

Quelqu'un a t-il une idée ?

Merci d'avance.

[riaolle]

Bonjour et bienvenue au forum
Intéresse-toi à la propriété Caption du Label :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Label1.Caption = "toto"

Un tuto sur les contrôles des UserForm : http://silkyroad.developpez.com/VBA/ControlesUserForm/
En particulier les Label : http://silkyroad.developpez.com/VBA/...serForm/#LII-A

[Al__22]

Bonjour ,

Un exemple de SilkyRoad qui devrait t'aider :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Private Sub UserForm_Initialize()
    Dim Obj As Control
    Dim i As Integer
 
    For i = 1 To 3 'boucle pour la création des Labels
        Set Obj = Me.Controls.Add("forms.Label.1")
        With Obj
            .Name = "monLabel" & i
            .Object.Caption = "le texte" & i
            .Left = 140
            .Top = 30 * i + 10
            .Width = 50
            .Height = 20
        End With
    Next i
 
End Sub

Pour ce qui est de vérifier les doublons plein de solutions existes et ont déjà été discuté sur ce forum et d'autres. Pour ne citer que les plus connues :
- Menu validation directement dans Excel
- Filtre élaboré
- Dictionnaire/Collection

Un tuto concernant les doublons :
Celui de Silkyroad

[Sylvain DG]

Pour ma part je suis un adepte des collections.

Petite routine maison :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
' Ajoute un item dans une collection
' ne fait rien si l'item existe déjà
Public Sub EasyAddItemInCollection(ByRef Coll As Collection, ByRef Item As Variant, Optional ByVal Key As String = "")
On Error Resume Next
    If Key = "" Then
        Call Coll.Add(Item)
    Else
        Call Coll.Add(Item, Key)
    End If
End Sub

Puis le dédoublonnage fonctionne ainsi :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Private Sub dédoublonne()
Dim col As Collection
Dim v As Variant
 
    Set col = New Collection
    Call EasyAddItemInCollection(col, "titi", "titi")
    Call EasyAddItemInCollection(col, "titi", "titi")
    Call EasyAddItemInCollection(col, "tata", "tata")
    Call EasyAddItemInCollection(col, "titi", "titi")
    Call EasyAddItemInCollection(col, "toto", "toto")
 
    For Each v In col
        Debug.Print v
    Next v
End Sub

Résultat :
titi
tata
toto


En espérant que ça aide...
Sylvain

[Cygnus50]

Merci pour vos conseils. Je vais pouvoir avancer maintenant