Discussion :

[Erik0000]

Bonjour,
à partir d'une liste de PC style :

poste1
poste2
poste3
poste4

3 cas se présentent

le poste répond sur le réseau : mettre dans le fichier , nom du pc, ok, adresse IP
le poste ne répond pas et il a une adresse IP , mettre dans le fichier, nom du pc, ko, adresse IP
le poste ne répond et n'a pas d'adresse IP , mettre dans le fichier, nom du pc, ko, pas d'ip

j'aimerai obtenir dans un fichier

poste1 ping ok 10.10.10.10
poste2 ko 10.10.10.11
poste3 ko pas d'IP
poste4 ok 10.10.10.15

J'ai le script ci-dessous qui met dans fichier , nom du pc , ok/ko

Code bat :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
@echo off
 
rem parametrage de l'endroit ou se trouve la liste des pc
set nomPC=listePC.txt
 
rem parametrage du fichier de resultat
set result=resultping.txt
 
rem purge du fichier résultat
 If exist %result% Del %result%
 
Setlocal EnableDelayedExpansion
 
rem  ping avec option -n 1 pour ne pinguer qu'une fois
 
for /f "delims=" %%i in (%nomPC%) do    (  
ping %%i -n 1 | FIND "TTL=" > nul
if errorlevel 1 ( echo %%i ko >> %result%
) else (
echo %%i ok >> %result%
)
)
endlocal
 
pause

[ericlm128]

Merci de mettre correctement les balises de codes

Puisque tu a ouvert un post pour ton problème, voici une proposition.

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
@echo off
 
set nomPC=listePC.txt
set result=resultping.txt
 
If exist %result% Del %result%
 
Setlocal EnableDelayedExpansion
 
for /f "delims=" %%a in (%nomPC%) do (
set status=KO
set ip=pas d'IP
 
for /f "delims=[] tokens=1,2,3" %%b in ('ping "%%a" -n 1 -4') do (
IF NOT "%%b"=="" echo "%%b"|FIND "TTL=">nul 2>nul&&set status=OK
IF NOT "%%c"=="" set ip=%%c
)
 
echo %%a !status! !IP! >> %result%
)
endlocal
 
pause

[Erik0000]

bonjour,

la solution proposée fonctionne

j'ai modifié légèrement le .bat pour que le fichier résultat puisse être ouvert dans Excel directement en faisant double clique sur le nom du fichier qui contient les résultats

Code bat :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
@echo off
 
set nomPC=listePC.txt
set result=resultping.csv
 
If exist %result% Del %result%
 
Setlocal EnableDelayedExpansion
 
for /f "delims=" %%a in (%nomPC%) do (
										set status=KO
										set ip=pas_d'IP
 
										for /f "delims=[] tokens=1,2,3" %%b in ('ping "%%a" -n 1 -4') do (
																									IF NOT "%%b"=="" echo "%%b"|FIND "TTL=">nul 2>nul&&set status=OK
																									IF NOT "%%c"=="" set ip=%%c
																									)
 
									echo %%a ; !status! ; !IP! >> %result%
									)
endlocal
 
pause