Discussion :

[diego007]

Bonjour,

Merci de vous être arrêté sur ma discussion

Je cherche à mettre au point un indicateur apparemment simple (tableau 2 colonnes) mais sur lequel je butte.

J'ai mis un tableau exemple en fichier joint.

Je cherche une formule qui me donnerai ce que j'ai mis dans le deuxième tableau du fichier joint (résultat attendu)

Merci de votre aide

Diego

[EBRAG]

Bonjour,

J'ai hésité à me mettre sur le sujet, car l'exposé n'était pas clair, et en ouvrant le fichier, il m'a fallu du temps pour comprendre...

si le sujet est simple (dans l'esprit de certains), il n'est pas facile à résoudre ! (s'il l'était, il y a longtemps que la réponse aurait été apportée, par toi-même)

je propose une solution en 2 étapes :

Mettre en œuvre un Tableau Croisé dynamique avec une fonction Min
établir les formules sur ce TCD

[papouclo]

Bonjour,
Dans la proposition suivante, les plages A2:A15 et B2:B15 sont respectivement nommées salaries et motifs.
On peut répondre à l'aide d'un tableau intermédiaire construit par exemple en plaçant en G2:G6 la liste des salariés sans doublons, en H1:J1 la liste des motifs.
Ecrire en H2 la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MIN(SOMMEPROD((salaries=$G2)*(motifs=H$1));1)

à recopier sur toute la plage H2:J6
En K2 la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME(H2:J2)

à recopier vers le bas jusqu'en K6.

Le nombre de salariés avec un mixte de motifs s'obtient alors en E5 avec la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=NB.SI(K2:K6;">1")

Le nombre de salariés n'ayant qu'un seul motif A, B, C peut s'obtenir grace à la fonction NB.SI.ENS avec les formules :
en E2 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=NB.SI.ENS($H$2:$H$6;1;$I$2:$I$6;0;$J$2:$J$6;0)

en E3 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=NB.SI.ENS($H$2:$H$6;0;$I$2:$I$6;1;$J$2:$J$6;0)

en E4 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=NB.SI.ENS($H$2:$H$6;0;$I$2:$I$6;0;$J$2:$J$6;1)

La fonction NB.SI.ENS n'acceptant pratiquement pas d'autres fonctions comme paramètres, si l'on veut n'écrire qu'une seule formule qui se recopie sur la plage E2:E4 en s'incrémentant, on peut utiliser la fonction SOMMEPROD. On peut écrire en E2 la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD(($H$2:$H$6=1*(DROITE(D2;1)=$H$1))*($I$2:$I$6=1*(DROITE(D2;1)=$I$1))*($J$2:$J$6=1*(DROITE(D2;1)=$J$1)))

et la recopier vers le bas jusqu'en E4.
Cordialement
Claude